Datentypen von String zu Byte und wieder zurück

[Uwe Raabe]

Ich verstehe das so, daß du die beiden Hex-Strings bitweise verschachtelst. Folgende Funktion sollte das leisten:

Delphi-Quellcode:

function Convert(const A, B: string): string;

  function Merge(CA, CB: Char): string;
  type
    TByteSet = set of 0..3;
  var
    BS: TByteSet;
    b1: Byte;
    b2: Byte;
    I: Integer;
  begin
    b1 := StrToInt('$' + CA);
    b2 := StrToInt('$' + CB);
    BS := [];
    for I := 0 to 3 do begin
      if I in TByteSet(b1) then begin
        Include(BS, 2*I);
      end;
      if I in TByteSet(b2) then begin
        Include(BS, 2*I + 1);
      end;
    end;
    Result := IntToHex(Byte(BS), 2);
  end;

var
  I: Integer;
begin
  Assert(Length(A) = Length(B), 'Strings müssen gleich lang sein!');
  Result := '';
  for I := 1 to Length(A) do begin
    Result := Result + Merge(A[I], B[I]);
  end;
end;

[Graw]

Hallo Uwe,

deine Funktion ist genau das was ich gebraucht habe.
Vielen Dank!!!

Wenn ich zwei feste Strings in die Funktion eintrage kommt genau das Ergebniss welches ich mir erhofft habe.

Die Strings die von der Schnittstelle kommen will er leider noch nicht verarbeiten...
Da hab ich irgendwo noch nen Fehler...

Aber den soll ich wohl noch finden.

Nochmal vielen Dank!!

[himitsu]

BS hat offiziell nur 4 Bit, aber irgendwer tut da 8 Bits rein .... so ganz Richtig kann das nicht sein.


Deine Beschreibung war in #1 nicht so gut.
Für mich klang das auch so, als wenn du jeweils "ein Hex-Zeichen" mischen willst und nicht die einzelnen Bits.

[Olli73]

Zitat von himitsu:

BS hat offiziell nur 4 Bit, aber irgendwer tut da 8 Bits rein .... so ganz Richtig kann das nicht sein.

Kam mir auch komisch vor. Aber habe es gerade mal im Debugger gecheckt: Der tut da anstandslos mehr rein als deklariert ist.

Also wenn ich doppelt so viele Bit trinke, wie ich eigentlich vertrage, dann kommt es bei mir zu einem Überlauf...

[Michael II]

Ja, immer wieder spannend was man so alles in eine einfache Menge packen kann .

Ich nehm mal an, dass das viele Delphianer nicht wissen und UR uns allen damit wieder einmal zeigen wollte, was Delphi so alles kann .

Schnell ist das aber nicht.

Wenn viele Daten anfallen / Tempo eine Rolle spielt, dann kann man es auch so machen:

Delphi-Quellcode:

var merger : array[0..15,0..15] of string;
    hti : array[ '0'..'F' ] of integer;

function ConvertA(const A, B: string): string;
var i : integer;
begin
  Assert(Length(A) = Length(B), 'Strings müssen gleich lang sein!');
  Result := '';
  for i := 1 to length(A) do Result := Result + merger[hti[A[i]],hti[B[i]]];
end;

Das ist auf meiner Kiste über 16 Mal schneller und da die beiden Algos O(n) sind, ist das wohl auch auf langsameren und schnelleren Kisten so.

[Uwe Raabe]

Zitat von himitsu:

BS hat offiziell nur 4 Bit, aber irgendwer tut da 8 Bits rein .... so ganz Richtig kann das nicht sein.

Gut erkannt! TByteSet muss natürlich so deklariert sein:

Delphi-Quellcode:

  type
    TByteSet = set of 0..7;

Übrigens: Das funktioniert deshalb, weil Delphi immer ganze Bytes für Sets reserviert.

Zitat von Michael II:

Schnell ist das aber nicht.

Klar, daß man das mit einer Lookup-Tabelle deutlich schneller laufen lassen kann (deren Aufbau hast du ja auch weg optimiert - alternativ als const deklarieren). Es ging mir hier aber im Wesentlichen darum, den beschriebenen Algorithmus möglichst exakt nachzubilden.

[himitsu]

Ja, Natürlich kann man nur auf ganze Bytes zugreifen und Delphi rundet immer auf.
Ein Boolean kennt auch 1x False und 255x True

Aber blöd wird es, wenn man die Bereichsprüfung mal aktiviert und dann der Typ zu klein deklariert ist.

[Uwe Raabe]

Das ist sogar noch witziger:

Delphi-Quellcode:

type
  TSet = set of 0..3;

procedure Main;
var
  s: TSet;
  I: 0..3;
begin
  s := [1,3];
  for I in s do 
  begin          // <== BreakPoint 1
    Writeln(I);  // <== BreakPoint 2
  end;
end;             // <== BreakPoint 3

BreakPoint 1 wird 8x durchlaufen! BreakPoint 2 erwartungsgemäß nur 2x.

Bei den Durchläufen vor dem ersten Writeln hat I nicht mal einen definierten Wert.

[Graw]

Leider bekomm ich es doch nicht ans laufen...

Wenn ich der Funktion feste Werte übergebe funktioniert sie wunderbar.

Code:

PBuf := Convert('00003FFFC000','00003FFFC000');

Wenn ich aber meine Buffer der Funktion übergebe kommt nichts aus ihr raus.

Code:

BEGIN

          PBuf1 := Copy(PBuf10,13,Length(PBuf10)-3);
          PBuf2 := Copy(PBuf20,13,Length(PBuf20)-3);


          if (length(PBuf1) = length(PBuf2)) then
          begin
           PBuf := Convert(PBuf1,PBuf2);
           PBufSend := PBuf;          
          end;
         
END;

Könnt ihr mir sagen was ich da falsch mache?