EnumPrinterDrivers = Zugriffsverletzung (Anfängerfrage)

[Andreas2k]

SizeOf(TDriverInfo2);

Hatte ich auch schon probiert ergibt bei mir aber 24 byte

pcbNeeded / 24 ergibt aber ( 10112 / 24 = 421 ) obwohl es halt nur 18 Treiber sind. Funktioniert also auch net.

Da ich bei mir ja weiß das ich 18 Treiber installiert habe ergibt sich bei mir ein Teiler von 10112 / 18 = 561 aber der Wert ist nicht überall gleich auf nem anderen Rechner muss der z.B. 429 sein.

Das andere mit GetMem muss ich mir nochmal in Ruhe anschauen..

[Zacherl]

Ok, das bestätigt dann auf jeden Fall meine Vermutung, dass im Buffer auch noch die dazugehörigen Strings abgelegt werden und nicht nur die DRIVER_INFO_2 Strukturen. Mit dem GetMem Beispiel sollte es aber funktionieren. Zur Erklärung:
Buf ist hier als Zeiger deklariert, welcher nach dem Aufruf der API dann auf die erste DRIVER_INFO_2 Struktur zeigt. Mit dem Inc wird der Zeiger um SizeOf(TDriverInfo2) erhöht, zeigt also danach auf das 2./3./n-te Element.

Hier fällt mir grade auf, dass in meinem Beisüiel das FreeMem am Ende so natürlich nicht funktioniert, da sich der Zeiger ja geändert hat. Den initialen Buffer-Pointer (direkt nach dem GetMem Aufruf) müsstest du dir also sichern, bevor du anfängst zu iterieren.

[Der schöne Günther]

Zitat von Zacherl:

Vermutung, dass im Buffer auch noch die dazugehörigen Strings abgelegt werden

Wow, das ist aber echt fies. Das erklärt die Rückgabewerte wieviel BYTES man den Puffer bitte groß machen soll. Ich glaube das ist definitiv keine Anfängerfrage mehr

Dann war mein Geschwafel ("kein Puffer, nimm einfach ein Array") definitiv falsch.

[himitsu]

Man kann ja dennoch das Array verwenden, aber dann eben nicht auf alle, sondern nur auf die richige Anzahl der Einträge zugreifen.

[Zacherl]

Kann man dann aber nicht so schön inkrementieren

[himitsu]

0 bis daswasdieapisagt-1

BOOL EnumPrinterDrivers(
_In_ LPTSTR pName,
_In_ LPTSTR pEnvironment,
_In_ DWORD Level,
_Out_ LPBYTE pDriverInfo,
_In_ DWORD cbBuf,
_Out_ LPDWORD pcbNeeded,
_Out_ LPDWORD pcReturned
);

[Andreas2k]

Dumme Frage aber kann ich es nicht auch einfach so machen:
statt 2x EnumPrinterDrivers aufzurufen rufe ich es 3x auf (1x um die nötige Buffersize zu ermitteln, 1x mit dem pBuffer in der Größe von BytesNeeded um den ItemsCount zu erhalten, 1x der finale aufruf mit dem @array[0] (=SetLength(array, ItemsReturned))

Delphi-Quellcode:

function GetPrinterDrivers(): boolean;
var
     aDriverList     : array of TDriverInfo2;
     pBuffer         : Pointer;
     BytesNeeded     : DWORD;
     ItemsReturned   : DWORD;
     ErrorTxt        : array [0..500] of char;
     i               : integer;
begin

// BufferSize ermitteln
if not EnumPrinterDrivers(nil, nil, 2, nil, 0, BytesNeeded, ItemsReturned) then
    begin
      if GetLastError = ERROR_INSUFFICIENT_BUFFER then
         begin
           try
            // pBuffer Speicher reservieren
            pBuffer := System.AllocMem(BytesNeeded);
            // Anz. Items des Arrays ermitteln
            if EnumPrinterDrivers(nil, nil, 2, pBuffer, BytesNeeded, BytesNeeded, ItemsReturned) then
                begin
                  // Array Länge setzen
                  SetLength(aDriverList, ItemsReturned);
                  result := EnumPrinterDrivers(nil, nil, 2, @aDriverList[0], BytesNeeded, BytesNeeded, ItemsReturned);
                end;
           finally
            // Speicher freigeben
            FreeMem(pBuffer);
           end;
         end;
    end;

Kann man das so machen oder ist das zu gefährlich / dümmlich ?

[Zacherl]

Zitat von himitsu:

Man kann ja dennoch das Array verwenden, aber dann eben nicht auf alle, sondern nur auf die richige Anzahl der Einträge zugreifen.

Zitat von himitsu:

0 bis daswasdieapisagt-1

BOOL EnumPrinterDrivers(
_In_ LPTSTR pName,
_In_ LPTSTR pEnvironment,
_In_ DWORD Level,
_Out_ LPBYTE pDriverInfo,
_In_ DWORD cbBuf,
_Out_ LPDWORD pcbNeeded,
_Out_ LPDWORD pcReturned
);

Aber das Problem ist ja, dass pcbNeeded in Bytes angegeben ist und ausdrücklich nicht pcReturned * SizeOf(DRIVER_INFO_2) ist. Nichtmal ein Vielfaches von SizeOf(DRIVER_INFO_2) ist garantiert. Mit einem Array of DRIVER_INFO_2 zu arbeiten, macht doch rein von der Logik her einfach keinen Sinn.

Zitat von Andreas2k:

Kann man das so machen oder ist das zu gefährlich / dümmlich ?

Macht wenig Sinn. Der 3. Aufruf der API wird fehlschlagen (bzw. noch schlimmer: zufälligen Speicher überschreiben), da dein Array nach wie vor die falsche Größe hat. Siehe oben: pcbNeeded ist kein Vielfaches von SizeOf(DRIVER_INFO_2) . Der Array Ansatz kann nicht funktionieren - du hast enweder zu wenig Platz = Buffer Overflow oder du reservierst zu viel = Logisch fragwürdig. Arrays sollte man wirklich nur dann verwenden, wenn man homogene Strukturen zusammenfassen will.

Delphi-Quellcode:

function EnumPrinterDriversW(pName: LPSTR; pEnvironment: LPSTR; Level: DWord; pDriverInfo: LPBYTE;
  cbBuf: DWord; var pcbNeeded: DWord; var cbReturned: DWord): BOOL; stdcall;
  external 'winspool.drv';

type
  DRIVER_INFO_2 = packed record
    cVersion: DWord;
    pName: LPTSTR;
    pEnvironment: LPTSTR;
    pDriverPath: LPTSTR;
    pDataFile: LPTSTR;
    pConfigFile: LPTSTR;
  end;
  PDriverInfo2 = ^TDriverInfo2;
  TDriverInfo2 = DRIVER_INFO_2;

procedure TForm6.FormCreate(Sender: TObject);
var
  Buf: Pointer;
  ErrorCode,
  pcbNeeded,
  cbReturned,
  I: DWord;
  Driver: PDriverInfo2;
begin
  EnumPrinterDriversW(nil, nil, 2, nil, 0, pcbNeeded, cbReturned);
  ErrorCode := GetLastError;
  if (ErrorCode <> ERROR_INSUFFICIENT_BUFFER) then
  begin
    RaiseLastOsError(ErrorCode);
  end;
  GetMem(Buf, pcbNeeded);
  try
    if (not EnumPrinterDriversW(nil, nil, 2, Buf, pcbNeeded, pcbNeeded, cbReturned)) then
    begin
      RaiseLastOsError;
    end;
    Driver := Buf;
    for I := 1 to cbReturned do
    begin
      ShowMessage(Driver^.pName);
      Inc(Driver);
    end;
  finally
    FreeMem(Buf);
  end;
end;

Wenn der Zugriff umbedingt über ein Array erfolgen soll, dann geht auch folgende Variante:

Delphi-Quellcode:

procedure TForm6.FormCreate(Sender: TObject);
type
  PDriverInfo2Array = ^TDriverInfo2Array;
  TDriverInfo2Array = array[0..0] of TDriverInfo2;
var
  Buf: Pointer;
  ...
  I: DWord;
  Drivers: PDriverInfo2Array;
begin
  ...
  try
    ...
    Drivers := Buf;
    for I := 0 to cbReturned - 1 do
    begin
      ShowMessage(Drivers^[I].pName);
    end;
  finally
    ...
  end;
end;

[Andreas2k]

Ok, ich hab es jetzt wie in deinem ersten Beispiel gemacht.
Ist das mit pStart und FreeMem so in Ordnung?

Delphi-Quellcode:

function GetPrinterDrivers(): boolean;
var
     Buffer          : PDriverInfo2;
     pStart          : Pointer;
     i               : Integer;
     BytesNeeded     : DWORD;
     ItemsReturned   : DWORD;

begin

if not EnumPrinterDrivers(nil, nil, 2, nil, 0, BytesNeeded, ItemsReturned) then
    begin
      if GetLastError = ERROR_INSUFFICIENT_BUFFER then
        begin
          GetMem(Buffer, BytesNeeded);
          pStart := Buffer;
          try
            if  EnumPrinterDrivers(nil, nil, 2, Buffer, BytesNeeded, BytesNeeded, ItemsReturned) then
               begin
                 for i := 1 to ItemsReturned  do
                     begin
                       Form1.Memo1.Lines.Add(i.ToString +' :: '+Buffer.pName);
                       inc(Buffer);
                     end;
               end;

          finally

            Buffer := pStart;
            FreeMem(Buffer);
          end;
        end;
    end;

[Der schöne Günther]

Auch wenn ich schon einmal Quark erzählt habe traue ich mich trotzdem noch:

Sieht gut aus, allerdings
- Könnte man pStart auch vom Typ PDriverInfo2 sein lassen.
- Mach in der Doku unbedingt fest was deine Methode denn angeblich zurückgibt
- Denn momentan ist der Rückgabewert uU nicht definiert