Fragen zu Generic TList

[norwegen60]

Hallo,

ich habe mich etwas mit Generic TList beschäftigt und hänge nun bei ein paar Punkten. Hier zunächst Code-Auszüge (im Anhang das ganze Projekt).

Delphi-Quellcode:

  TMyClass = class
  private
    FCounter, FValue: Integer;
  public
    property Counter: Integer read FCounter write FCounter;
    property Value:   Integer read FValue write FValue;
  end;

  TMyList = class(TList<TMyClass>)
  private
    FFreeOnDelete: Boolean;
    procedure Notify(Ptr: Pointer; Action: TListNotification); virtual;
  public
    constructor Create(bValue: Boolean = true);
  end;

var
  MyList:     TMyList;
  MyCopyList: TMyList;


  MyList := TMyList.Create;
  MyCopyList := TMyList.Create(false);  // In Copyliste bei Delete Daten nicht löschen

  // Datenliste erzeugen
  for i := 0 to 50 do
  begin
    Values := TMyClass.Create;
    Values.Counter := i;
    Values.Value := random(200);
    MyList.Add(Values);
  end;

  // Datenliste in Memofeld anzeigen
  for i := 0 to MyList.Count - 1 do
  begin
    Values := MyList.Items[i];
    Memo1.Lines.Add(format('%d: %d, %d', [i, Values.Counter, Values.Value]));
  end;

  // Datenliste kopieren  
  for i := 0 to MyList.Count - 1 do
  begin
    Values := MyList.Items[i];
    MyCopyList.Add(Values);
  end;

  // Jeden 10 Datensatz in kopierter Liste löschen
  MyCopyList.Delete(40);
  MyCopyList.Delete(30);
  MyCopyList.Delete(20);
  MyCopyList.Delete(10);            // gelöscht werden aber die letzten 4 Datensätze

procedure TForm1.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  MyCopyList.Free;
  MyList.Free;
end;

{ TMyList }

constructor TMyList.Create(bValue: Boolean = true);
begin
  inherited Create;
  FFreeOnDelete := bValue;
end;

procedure TMyList.Notify(Ptr: Pointer; Action: TListNotification);
begin
  if (FFreeOnDelete) and (Action = lnDeleted) then
    TObject(Ptr).Free;
  // inherited Notify(Ptr, Action);
end;

Folgende Fragen:

1. Gibt es grundsätzliche Fehler bei der Behandlung
2. In der Originalliste funktioniert MyList.Delete(30); einwandfrei, in der kopierten Liste wird mit jedem Aufruf der letzte Satz gelöscht. Warum?
3. Notify zum löschen des Speicherplatz funktioniert nicht und inherited führt gleich zu Fehler. Irgendwie scheint der Header in XE10 nicht dem in der Hilfe zu entsprechen. Aber wie geht es richtig?

Danke für eure Unterstützung
Gerd

[SProske]

Hat es einen bestimmten Grund, dass du nicht TObjectList<TMyClass> verwendest?

[ensaron]

Deine Funktion wird korrekt ausgeführt, aber deine Ausgabefunktion hat einen Fehler:

Delphi-Quellcode:

Memo2.Clear;
for i := 0 to MyCopyList.Count - 1 do
begin
  Values := MyList.Items[i];
  Memo2.Lines.Add(format('%d: %d, %d', [i, Values.Counter, Values.Value]));
end;

Du zeigst die Einträge der originalen Liste an, benutzt aber die Anzahl der kopierten Liste als Maximum.

[haentschman]

Moin...
Du macht es dir schwerer als es in Wirklichkeit ist. Bei deinen 2 Listen gibt es einiges zu beachten.
1. Eine Masterlist die die Werte hällt und die Werte freigibt. (TObjectList)
2. Die Liste mit den kopierten Werten hällt. (TList) Diese Liste hällt nur die Pointer der Values aus der Masterliste.
3. Die Einträge können direkt mit TList.Delete aus der Liste entfernt werden. Das Original bleibt davon unberührt.

Delphi-Quellcode:

for i := 0 to 50 do
  begin
    Values := TMyClass.Create; // ein Pointer wird erzeugt
    Values.Counter := i;
    Values.Value := random(200);
    MyList.Add(Values); // ein Pointer liegt in der Liste und wird mit TList [B]nicht[/B] freigegeben 
  end;

...wie ich auch in dem anderen Thread sagte, du solltest die TObjectList benutzen.

Delphi-Quellcode:

for i := 0 to MyList.Count - 1 do
  begin
    Values := MyList.Items[i];
    MyCopyList.Add(Values);
  end;

...das Legen in die MyCopyList legt nur den Pointer der Instanz aus der MasterList in die MyCopyList.

Delphi-Quellcode:

TMyList = class(TList<TMyClass>)
  private
    FFreeOnDelete: Boolean; // nicht notwendig da die Pointer in dieser Liste nicht freigegeben werden müssen
    procedure Notify(Ptr: Pointer; Action: TListNotification); virtual; // nicht notwendig da die Pointer in dieser Liste nicht freigegeben werden müssen
  public
    constructor Create(bValue: Boolean = true);
  end;

... die Freigabe der Values braucht hier nicht erfolgen. Das erledigt die MasterList über OwnsObjects.

[DeddyH]

Die Kopie-Liste kann doch auch eine TObjectList sein, nur eben mit OwnsObjects auf false, oder mache ich gerade einen Denkfehler?

[haentschman]

Zitat:

Die Kopie-Liste kann doch auch eine TObjectList sein, nur eben mit OwnsObjects auf false, oder mache ich gerade einen Denkfehler?

...nö. Es ging auch darum die Unterschiede von TObjectList und TList gegenüberzustellen...

[norwegen60]

Das mit den TObjectList hatte ich schon verstanden und will es mir auch noch anschauen. Zuerst wollte ich aber mal die TList verstehen da eine für mich wichtige Anwendung mit TList<> arbeitet und ich noch nicht abschätzen kann welche Auswirkungen ein Wechsel auf TObjectList hat.

Zweifel an meinem Verständnis hatte ich aufgrund der vermeintlich falsch gelöschten Daten in der Kopierliste. Deshalb Dank an Ensaron's Hinweis, dass es sich um einen typischen Paste&Copy Fehler handelt.

Jetzt würde ichnur noch gerne verstehen, wie ich das Notify korrekt implementiere.

Danach stürze ich mich auf TObjectList. Versprochen.

[Der schöne Günther]

Zitat von norwegen60:

Jetzt würde ichnur noch gerne verstehen, wie ich das Notify korrekt implementiere.

Schau mal in die WARNUNG-Meldungen des Compilers. Da steht's eigentlich

[Fritzew]

Zitat:

Schau mal in die WARNUNG-Meldungen des Compilers. Da steht's eigentlich

[dcc32 Warnung] fo_Tlist.pas(56): W1010 Methode 'Notify' verbirgt virtuelle Methode vom Basistyp 'System.Generics.Collections.TList<fo_Tlist.TMyCla ss>'

Du erzeugst eine neue Notify Procedure

mach es so:

Delphi-Quellcode:

 TMyList = class(TList<TMyClass>)
  private
    FFreeOnDelete: Boolean;
// Die Notify ist protected
   protected
    procedure Notify(const Ptr: tMyclass; Action: TCollectionNotification); override; // Überschreiben nicht virtual
  public
    constructor Create(bValue: Boolean = true);
  end;

[norwegen60]

Die Warnmedlung hatte ich gesehen, nur wusste ich nichts damit anzufangen. Auch nachdem ich noch mal in Netz gesucht habe. Gut dass du mich direkt darauf gelüpft hast.

Viel weiter gekommen bin ich aber noch nicht, denn jetzt bin ich wieder bei

Zitat:

[dcc32 Fehler] fo_Tlist.pas(67): E2037 Deklaration von 'Notify' unterscheidet sich von vorheriger Deklaration

und wenn ich es auf procedure Notify(const Item: T; Action: TCollectionNotification); override; ändere mag er den Typ T nicht.