An welcher Position war/ist die Variable im Template

[RWarnecke]

Ich habe ein Problem. Ich verstehe die Diskussion um die Herkunft der Werte für die Variablen %year% und %counter% nicht. Ich möchte doch nur eine einfache String Bearbeitung haben, die mir aus dem Ergebnis den Wert einer Variable vom Template zurückgibt.

Warum muss man jetzt wissen, woher die Variablen Ihre Werte bekommen ?

Nach meiner Meinung, ist das doch völlig irrelevant oder übersehe ich hier etwas ?

[stahli]

Es ist halt nicht klar, was zum Zeitpunkt der benötigten Funktion vorliegt und was nicht und ob Du an den Gegebenheiten noch etwas optimieren kannst.

Beantworte doch mal meine 5 Fragen. Vielleicht hilft das weiter...

Wenn Du NUR die Ergebnisstrings hast ohne irgendwelche Infos zu den zu Grunde liegenden Templates, dann wird es schwierig.

Die Frage ist, wozu diese Strings dann gespeichert werden, wenn man diese nachher eh nicht mehr vernünftig interpretieren kann.

[nahpets]

Hallo,

ich versuche mal ein bisserl "rumzuspinnen".

Dazu mache ich folgende Annahmen:

1. Dir sind alle Templates bekannt.
2. Dir sind für alle Variabeln die möglichen Maximalwerte bekannt.
3. Alle aus den Templates erstellten Werte sind rein nummerische Werte.

Stimmt eine der Annahmen nicht, dann vergiss den Rest.

Für jedes Template werden folgende Schritte ausgeführt:

1. Das Template wird mit den Maximalwerten befüllt.

2. Per SQL suchst Du nun in der Datenbank den höchsten Wert, der kleiner als der soeben erstellte Wert ist.

Code:

Select max(Spalte) from tabelle where Spalte < "Ergebnis von 1."

3. Da Dir zu diesem Zeitpunkt der Aufbau des Templates und der deraus erstelle Wert bekannt sind, müsstest Du nun durch entfernen aller der Teile, die nicht durch %counter% in den Wert "hineingekommen" sind, den von Dir gesuchten %counter%-Wert erhalten.

Sollte ich um zu viele (und vor allem fehlerhafte) Ecken gedacht haben, dann vergiss das Geschreibsel von mir bitte.

[RWarnecke]

Das bringt mir doch alles nichts. Es geht doch nur lediglich um den Importvorgang und nach diesem den Counter entsprechend hochzusetzen. Die ganzen Spekulationen und Fragen habe ich in meinen Beiträge beantwortet oder bestätigt.

Ich formuliere es nochmal als letzten Versuch:

Ich möchte aus einem Ergebniswert (kann alle Zeichen enthalten) mit Hilfe des Templates den Wert des Counters bestimmen. Alles andere muss und soll so bleiben. Welche Möglichkeiten habe ich ?

[Sir Rufo]

Zitat von RWarnecke:

Ich habe ein Problem. Ich verstehe die Diskussion um die Herkunft der Werte für die Variablen %year% und %counter% nicht. Ich möchte doch nur eine einfache String Bearbeitung haben, die mir aus dem Ergebnis den Wert einer Variable vom Template zurückgibt.

Warum muss man jetzt wissen, woher die Variablen Ihre Werte bekommen ?

Nach meiner Meinung, ist das doch völlig irrelevant oder übersehe ich hier etwas ?

Nein

[RWarnecke]

@Sir Ruf: Auf welche Frage antwortest Du jetzt ?

[Sir Rufo]

Ich versuche dann mal etwas konstruktives (nur die Theorie):

Wir haben das Template, was irgendwo die Zeichenfolge '%counter%' enthält.
Oder anders betrachtet besteht das Template aus 3 Abschnitten:

1. Eine Zeichenfolge
2. %counter%
3. Eine Zeichenfolge

Wenn man diese Zeichenfolgen hat, dann kann man (vereinfacht) aus dem eigentlichen String vorne und hinten die Längen der Zeichenfolgen wegnehmen und schon bleibt nur der String für den Counter übrig.

Code:

100%counter%3081%year%

Vorne 100 => 3 Zeichen
Hinten 3081%year% (year immer 4 Ziffern) => 30810000 => 8 Zeichen

Code:

100217830812016

3 Zeichen vorne entfernen => 217830812016
8 Zeichen hinten entfernen => 2178
heureka!

[nahpets]

Also noch ein Versuch einer Lösung:

Du musst für jedes Template den entsprechenden höchsten Wert aus Deinen Daten ermitteln, alles aus diesem Wert entfernen, was nicht durch den Platzhalter %counter% in den Wert eingeflossen ist und schon hast Du den Wert für %counter%.

Da wir keine konkreteren Informationen über den Ursprung der Daten und den Aufbau der Templates haben als: "kann so P%counter%%year% oder so ähnlich aussehen", können wir auch keine konkretere Lösung entwickeln, als es könnte so oder so ähnlich gehen.

Und Vorschläge für so oder so ähnlich gibt es jetzt schon einige.

Sir Rufo beschrieb in seinem letzten Beitrag das, was ich mit meinem Vorschlag meinte.

Man nehme aus dem größten vorhandenen Wert alles heraus, was "fest" im Template enthalten ist, entferne das Jahr und schon hat man den Counter.

Da es unterschiedliche Templates gibt, muss für jedes Template eine eigene Counterextrahiermethode her. Die bisherigen Informationen lassen nicht erkennen, dass es eine allgemeingültige Lösung für beliebige Templates geben könnte.

[Uwe Raabe]

Eigentlich bin ich ja der Letzte, der sowas vorschlagen würde, aber nach dem Vortrag von Daniel bei der CodeRage DE:

Delphi-Quellcode:

uses
  System.RegularExpressions;

function ExtractCounter(const Template, Value: string): Integer;
var
  pattern: string;
begin
  pattern := Template.Replace('%counter%', '([\d]+)', [rfIgnoreCase]).Replace('%year%', '(?:[\d]{4})', [rfIgnoreCase]);
  result := TRegEx.Match(Value, pattern).Groups[1].Value.ToInteger;
end;

[Sir Rufo]

Oder eben nach alter Väter Sitte:

Delphi-Quellcode:

program Project4;

{$APPTYPE CONSOLE}
{$R *.res}

uses
  System.SysUtils;

function GetCounterFromTemplatedString( const Str, Template: string ): Integer;
const
  CCounter     = '%counter%';
  CYear        = '%year%';
  CYearDefault = '0000';
var
  tmp                   : string;
  lFirst, lTail, lLength: Integer;
begin
  tmp    := Template.Replace( CYear, CYearDefault );
  lFirst := tmp.IndexOf( CCounter );
  if lFirst = -1
  then
    raise Exception.Create( 'Fehlermeldung' );

  lTail   := tmp.Length - lFirst - CCounter.Length;
  lLength := Str.Length - lFirst - lTail;

  tmp    := Str.Substring( lFirst, lLength );
  Result := Integer.Parse( tmp );
end;

procedure Check( const Str, Template: string; expected: Integer );
begin
  if GetCounterFromTemplatedString(str,template) <> expected then
    raise Exception.Create('Fehlermeldung');
end;

procedure Test;
begin
  Check( '1001030812016', '100%counter%3081%year%', 10 );
  Check( '10012530812016', '100%counter%3081%year%', 125 );
  Check( '100217830812016', '100%counter%3081%year%', 2178 );
  Check( '10047930812016', '100%counter%3081%year%', 479 );

  Check( 'P12016', 'P%counter%%year%', 1 );
  Check( 'P1002016', 'P%counter%%year%', 100 );
end;

begin
  try
    Test;
  except
    on E: Exception do
      Writeln( E.ClassName, ': ', E.Message );
  end;
  ReadLn;

end.

PS: leider allgemeingültig