FMX.DialogServices... wie benutzen?

[Sherlock]

Ich bekomme seit meinem Umstieg nach Berlin eine Warnung:

Zitat:

[DCC Warnung] UCTGReader.pas(1369): W1000 Symbol 'MessageDlg' ist veraltet: 'Use FMX.DialogService methods'

Hat einer von Euch das bereits in Verwendung? So 1:1 kann man es leider nicht umsetzen. Anonyme Methoden habe ich bisher nie verwendet, und lese mich jetzt ein, aber eventuell gibts hier bereits praktikable Beispiele?

Sherlock

[stalkingwolf]

Ich ignoriere die Meldung aktuell noch

[milos]

Hi,

ich besitze leider kein Berlin (wie doof das klingt ) jedoch findet sich bei Emba doch genügend Infos dazu, oder etwa nicht?

http://docwiki.embarcadero.com/Libra....DialogService
http://docwiki.embarcadero.com/Libra....MessageDialog
http://docwiki.embarcadero.com/Libra...ce.ShowMessage
http://docwiki.embarcadero.com/Libra...ice.InputQuery

Gib uns doch sonst ein Beispiel welches wir versuchen können so ähnlich wie möglich über FMX.DialogServices nachzubauen, sieht laut Dokumentation gar nicht allzu anders aus.

Freundliche Grüsse

Edit: Das könnte dir vielleicht am nützlichsten sein falls du kein async brauchst (da brauchst du dich auch nicht mit anonymen mehtoden rumschlagen ):
http://docwiki.embarcadero.com/Libra...sageDialogSync
Achtung: "To call MessageDialogSync without the need of an instance of IFMXDialogServiceSync, use TDialogServiceSync.MessageDialog instead."

[Sir Rufo]

Und noch ein Achtung: Das Sync-Gedöns ist NICHT für Android!

[Sherlock]

Eventuell zur Verdeutlichung.
Mir ist klar, daß ich das hier zu verwenden habe: http://docwiki.embarcadero.com/Libra....MessageDialog
Mir ist jedoch nicht klar wie. Die Achtungs habe ich auch bereits gelesen, weshalb ja TDialogService zu bevorzugen ist, da wird dann eben Plattformabhängig entschieden was zu tun ist. Ich weiß nur nicht wie ich es benutzen soll... (Wiederholung ist meine Stärke )

Konkret habe ich nur eine Stelle wo ich das brauche. Hier der bisherige Code:

Delphi-Quellcode:

procedure TFDeviceReader.AusRebootBtnClick(Sender: TObject);
var
  Command: Integer;
  Frage: string;
begin
  if Sender = AusBtn then
  begin
    Command := 0;
    Frage := rsReallyShutDown;
  end
  else
  begin
    Command := 1;
    Frage := rsReallyReboot;
  end;
  if MessageDlg(Frage, TMsgDlgType.mtConfirmation, mbYesNo, 0) = mrYes then   // <-- Wie verwende ich hier TDialogService?
  begin
    case Command of
      0:
        begin
          ShowMessage(rsShutdown);
          fDevice.SendShutDown(Command);
          fDevice.Connected := False;
          Halt(0);
        end;
      1:
        begin
          ShowMessage(rsReboot);
          fDevice.SendShutDown(Command);
          fDevice.Connected := False;
          repeat
            Sleep(10000);
          until fDevice.ConnectionTest;
        end;
    end;
  end;
end;

Wie ersetze ich an der markierten Stelle MessageDlg durch TDialogService.MessageDialog?

Sherlock

[bra]

So in der Art (schnell hingeschrieben, ungetestet):

Delphi-Quellcode:

TDialogService.MessageDialog(Frage, TMsgDlgType.mtConfirmation, mbYesNo, 0,
  procedure(const AResult: TModalResult)
  begin
   if AResult = mrYes then begin
    case Command of
      0:
        begin
          ShowMessage(rsShutdown);
          fDevice.SendShutDown(Command);
          fDevice.Connected := False;
          Halt(0);
        end;
      1:
        begin
          ShowMessage(rsReboot);
          fDevice.SendShutDown(Command);
          fDevice.Connected := False;
          repeat
            Sleep(10000);
          until fDevice.ConnectionTest;
        end;
    end;
   end;
  end


);

[Sherlock]

Aha, Danke. Kleinere Korrektur, und so geht es dann auch:

Delphi-Quellcode:

procedure TFDeviceReader.AusRebootBtnClick(Sender: TObject);
var
  Command: Integer;
  Frage: string;
begin
  if Sender = AusBtn then
  begin
    Command := 0;
    Frage := rsReallyShutDown;
  end
  else
  begin
    Command := 1;
    Frage := rsReallyReboot;
  end;
  TDialogService.MessageDialog(Frage, TMsgDlgType.mtConfirmation, mbYesNo, TMsgDlgBtn.mbNo, 0,
    procedure(const aResult: TModalResult)
    begin
      if aResult = mrYes then
        case Command of
          0:
            begin
              ShowMessage(rsShutdown);
              fDevice.SendShutDown(Command);
              fDevice.Connected := False;
              Halt(0);
            end;
          1:
            begin
              ShowMessage(rsReboot);
              fDevice.SendShutDown(Command);
              fDevice.Connected := False;
              repeat
                Sleep(10000);
              until fDevice.ConnectionTest;
            end;
        end;
    end);
end;

Es fehlte noch der DefaultButton.

Insgesamt etwas holprig, und IMHO schlechter lesbar, als die alte Variante. Ich habe nicht übel Lust einen Wrapper zu bauen, der folgendes tut, und damit wieder die schlichte Eleganz der alten Implementierung herstellt:

Delphi-Quellcode:

function myMessageDlg(const AMessage:string; const ADialogType: TMsgDlgType; const AButtons: TMsgDlgButtons; const AHelpContext:integer; const ADefaultButton: TMsgDlgBtn):TModalResult;
begin
  // Alle Parameter auf Gültigkeit prüfen, yada yada yada

  // Jetzt die neue Methode verwenden
  TDialogService.MessageDialog(AMessage, ADialogType, AButtons, ADefaultButton, AHelpContext,
    procedure(const aResult: TModalResult)
    begin
      Result := aResult;
    end);
end;

Mag mir einer der fachkundigeren Mitforisten erläutern, was an der neuen Variante besser ist?

Sherlock

[milos]

Die anonyme prozedur ist sehr wahrscheinlich dazu da um das ganze bei bedarf auch Asynchron auszuführen ohne das du dich um das Threading-Gedöns im Hintergrund kümmern musst, weswegen du das bei der Synchronen Variante nicht finden kannst. Ist aber nur eine Vermutung.

Freundliche Grüsse

[bra]

Zitat von Sherlock:

Mag mir einer der fachkundigeren Mitforisten erläutern, was an der neuen Variante besser ist?

Die neue Variante wird benötigt, weil es auf den mobilen Plattformen (v.a. Android) keine blockierenden Dialoge gibt. Das führt bei der alten Variante dazu, dass der Code nach dem MessageDlg sofort ausgeführt wird, nachdem der Dialog angezeigt wird, also nie eine sinnvolle Auswertung der gedrückten Buttons stattfinden kann.

[Sherlock]

Zitat von bra:

Zitat von Sherlock:

Mag mir einer der fachkundigeren Mitforisten erläutern, was an der neuen Variante besser ist?

Die neue Variante wird benötigt, weil es auf den mobilen Plattformen (v.a. Android) keine blockierenden Dialoge gibt. Das führt bei der alten Variante dazu, dass der Code nach dem MessageDlg sofort ausgeführt wird, nachdem der Dialog angezeigt wird, also nie eine sinnvolle Auswertung der gedrückten Buttons stattfinden kann.

Wenn ich die Hilfe richtig gelesen habe gilt das ausschließlich für Android. Das bedeutet aber auch, daß mein "toller" Wrapper auch nicht funktionieren würde. Hrmpf

Was passiert denn bei Android, wenn man den Dialog ignoriert, und etwas anderes in der Applikation anstellt? Geht das wirklich, so daß dieses Verhalten halbwegs Sinn ergibt?

Sherlock