Hallo,

ich möchte Bilder via TResourceStream laden, doch leider bekomme ich immer die
Fehlermeldung

Zitat:

Resource xxx nicht gefunden

.

zusammenfalten · markieren

Delphi-Quellcode:

...
{$R resources.res}
...

const
  IDB_0E00A = 100; // PNG-Resource

...

procedure TForm1.LoadPNG(ID : Integer);
var
  ResStream : TResourceStream;
  Png : TPngImage;
begin
  try
    try
      ResStream := TResourceStream.CreateFromID(0, ID, RT_RCDATA);
      Png := TPngImage.Create;
      try
        Png.LoadFromStream(ResStream);
        Image1.Picture.Graphic := Png;
      finally
        Png.Free;
      end;
    except
      on E : Exception do
        ShowMessage(E.Message);
    end;
  finally
    if Assigned(ResStream) then
      ResStream.Free; [COLOR="Lime"]<- Warum führt ein Free zu einem Fehler !!!?[/COLOR]
  end;
end;

...

LoadPNG(IDB_0E00A);
...

Die resources.res wird via brcc32 -32 resources.rc erzeugt und sind auch in der
Anwendung vorhanden.

Die Suche in der DP hat mich bisher nicht weiter geführt, daher:
Hat jemand einen Tipp/Hinweis?

Danke

Hast Du es mal mit hInstance statt der 0 als Instanzhandle versucht?
ResStream := TResourceStream.CreateFromID(hInstance, ID, RT_RCDATA); Zur AV: wenn Du schon das Create hinter das try setzt, solltest Du die Instanzvariable mit nil initialisieren.

hInstance bringt es auch nicht, damit hatte ich angefangen.
Bin dann aber bei FindResource auf diesen Hinweis gestoßen:

Zitat:

hModule [in, optional]
Type: HMODULE

A handle to the module whose portable executable file or an accompanying MUI file contains the resource.
If this parameter is NULL, the function searches the module used to create the current process.

Was die AV angeht: Der TResourcestream wird ja erstellt, er ist ja <> nil und trotzdem knallt es.

• Die Instanz wird nicht erzeugt, wenn im constructor eine Exception kommt.
• Die Instanzvariable ist eine lokale Variable und somit nicht initialisiert => da steht irgendwas drin.
• Assigned liefert true wenn in der Instanzvariable irgendwas drin ist <> nil
• TObject.Free prüft selber auch noch mal ob <> nil
• Es kann nicht festgestellt werden, ob die Instanzreferenz auf irgendeine Grütze oder eine intakte Instanz zeigt
• Zeigt die Referenz auf Grütze, dann knallt es

Darum lautet das Pattern auch so

zusammenfalten · markieren

Delphi-Quellcode:

procedure bar;
var
  foo: TObject;
begin
  foo := TObject.Create;
  try
    ...
  finally
    foo.Free;
  end;
end;

oder

zusammenfalten · markieren

Delphi-Quellcode:

procedure bar;
var
  foo: TObject;
begin
  foo := nil;
  try
    foo := TObject.Create;

    ...
  finally
    foo.Free;
  end;
end;

@Sir Rufo

Nicht die Av ist das Problem.
Du liegst zwar grundsätzlich Richtig, aber im speziellem Fall wohl nicht(siehe Source-Code von TResurcestrem).

markieren

Delphi-Quellcode:

constructor TResourceStream.Create(Instance: THandle; const ResName: string; ResType: PChar);
begin
  inherited Create;
  Initialize(Instance, PChar(ResName), ResType, False);
end;

Ich vermute mal das es hier knallt(ungeprüft):

markieren

Delphi-Quellcode:

destructor TResourceStream.Destroy;
begin
  UnlockResource(HGlobal); [COLOR="MediumTurquoise"]<-[/COLOR]
  FreeResource(HGlobal); [COLOR="MediumTurquoise"]<-[/COLOR]
  inherited Destroy;
end;

Nein, tut mir leid, aber ich habe dein Projekt gerade mal mit dem Debugger durchgesteppt und die erste Exception wird hier geworfen:

markieren

Delphi-Quellcode:

constructor TResourceStream.CreateFromID(Instance: THandle; ResID: Integer;
  ResType: PChar);
begin
  inherited Create;
  Initialize(Instance, PChar(ResID), ResType, True); // <- da kommt die Exception
end;

dann wird im gleichen Atemzug TResourceStream.Destroy ganz brav und ohne weitere Exception durchlaufen, dann kommt die Ausgabe der MessageBox mit der Exception.

Der lokalen Variablen ResStream wird kein Wert zugewiesen!

Den Rest der Begründung findest du in meinem Post vorher.

Wenn du mit Resourcen arbeiten möchtest, dann kannst du dir auch einmal diesen Post von mir anschauen
http://www.delphipraxis.net/1330587-post3.html

Um meine Aussage zu überprüfen brauchst du lediglich eine Zeile einfügen:

zusammenfalten · markieren

Delphi-Quellcode:

procedure TForm1.LoadPNG(ID : Integer);
var
  ResStream : TResourceStream;
  Png : TPngImage;
begin
  ResStream := nil; // eine Zeile, die tut auch nix, die will nur spielen!
  try
    try
      ResStream := TResourceStream.CreateFromID(0, ID, RT_RCDATA);
      Png := TPngImage.Create;
      try
        Png.LoadFromStream(ResStream);
        Image1.Picture.Graphic := Png;
      finally
        Png.Free;
      end;
    except
      on E : Exception do
        ShowMessage(E.Message);
    end;
  finally
    // kann ersatzlos entfallen
    // if Assigned(ResStream) then
      ResStream.Free; // <- Warum ein Free zu einem Fehler !!!? <- Kommt ja jetzt nicht mehr
  end;
end;

Und noch etwas zum Thema Resource-Dateien

Wenn du die *.RC Datei in dein Projekt aufnimmst, dann wird diese Datei automatisch beim Erzeugen des Projekts erstellt und eingebunden. Das umständliche und manuelle Erzeugen der *.res Datei entfällt.

So sieht das dann in der dpr aus

zusammenfalten · markieren

Delphi-Quellcode:

program ResTest;

{$R 'Resources.res' '..\Rescource\Resources.rc'} // <- diese Zeile wird automatisch von Delphi erstellt

uses
  Forms,
  frmMain in 'frmMain.pas' {Form1};

{$R *.res}

begin
  Application.Initialize;
  Application.MainFormOnTaskbar := True;
  Application.CreateForm(TForm1, Form1);
  Application.Run;
end.