RestServer Antwort Json ohne "[" Klammern

[ScharfeMietze]

Ich muss euch nochmal stören.

Ich habe eine Serverantwort in Json von einem Rest server

Code:

{"result":["Test<\u00F6\u00E4\u00FC\u00F6\u00E4\u00FC>7"]}
1["Test<öäüöäü>7"]

Serverseite zum Üben

Delphi-Quellcode:

function TServerMethods1.updateEchoAttribute1(Key, Obj: string): String;
begin
Result:= Key + '<öäüöäü>' + Obj;
end;

Nun möchte ich die "reine" Antwort. Bisher habe ich das mit RegEx erschlagen und möchte es nun aber gerne über den Json way probieren.

Delphi-Quellcode:

var
  LJSONObject: TJSONObject;
  RestResponse: string;
begin
RestResponse:=  '{"result":["Test<\u00F6\u00E4\u00FC\u00F6\u00E4\u00FC>7"]}';
LJSONObject := TJSONObject.ParseJSONValue(TEncoding.ASCII.GetBytes(RestResponse), 0) as TJSONObject;
mmo1.Lines.Add(LJSONObject.Values['result'].ToString);
end;

Die schlichte Frage ist wie bekomme ich die -->[" und "]<-- Klammern/Gänsefüßchen entfernt.

Ich hoffe ihr könnt helfen.

lieben Gruß
SM

[himitsu]

Kann es sein, dass es dazu vor Kurzem schonmal einen Thread gab?


ToString wird das JSON-"Objekt" als Text zurück geben.

Es gibt aber bestimmt ein Value oder AsString, das den Wert liefert.

[ScharfeMietze]

Genau das ist ja mein problemchen
mmo1.Lines.Add(LJSONObject.Values['result'].ToString); liefert MIT besagten Zeichen

Code:

["Test<öäüöäü>7"]

[Sir Rufo]

ToString ist von der Definition her dafür da, die Instanz als String darzustellen.

Das willst du aber nicht, du willst den Wert.

TJSONObject.Values[...] liefert ein TJSONValue und wenn das vom Type ein TJSONString ist, dann bekommt man bei TJSONString.Value auch den gesuchten String-Wert.

EDIT Stop, Kommando zurück, du hast dort ein TJSONArray und der erste Wert ist dann ein TJSONString

[ScharfeMietze]

Magst mich gerade noch Aufklären wie ich mit einem solchen Array umzugehen habe?
Da bin ich noch Jungfräulich

Gruß
SM

[himitsu]

Und jetzt nochmal meine Antwort lesen.

Zitat:

Delphi-Quellcode:

function Value: string; virtual;
function ToJSON: string;
function ToString: string; override;
//uvm.

[Sir Rufo]

Und wenn du von der gleichen Faulheit befallen bist wie ich, dann sparst du dir diesen gesamten Fuddelkram mit

Delphi-Quellcode:

unit Unit2;

interface

uses
  REST.Json.Types; // <- da sind die Json-Attribute definiert

type
  TResponseJSON = class
  private
    [ JsonName( 'result' ) ]
    FResultArray: TArray<string>;
  public
    property ResultArray: TArray<string> read FResultArray;
  end;

implementation

end.

und verarbeitest das ganz gemütlich mit

Delphi-Quellcode:

program foo;

uses
  System.SysUtils,
  REST.Json, // <- da ist TJson definiert
  Unit2 in 'Unit2.pas';

procedure Test;
var
  lResponse: TResponseJSON;
begin
  lResponse := TJson.JsonToObject<TResponseJSON>( '{"result":["Test<\u00F6\u00E4\u00FC\u00F6\u00E4\u00FC>7"]}' );
  try
    WriteLn( lResponse.ResultArray[ 0 ] );
  finally
    lResponse.Free;
  end;
end;

begin
  try
    Test;
  except
    on E: Exception do
      WriteLn( E.ClassName, ': ', E.Message );
  end;
  ReadLn;
end.

Weil einfach einfach einfach ist

[Sir Rufo]

TsTsTs ... muss man immer alles dreimal sagen
http://www.delphipraxis.net/1328714-post6.html

[himitsu]

Nur zum Test.
S := (LJSONObject.Values['result'] as TJSONArray).Items[0].Value; ?

[ScharfeMietze]

@himitsu

Doch gelesen habe ich es aber meine Versuche mit
mmo1.Lines.Add('2' + LJSONObject.Values['result'].Value); scheitern. Ich bekomme '' als Antwort.

Wenn ich probiere dort gerade alles durch

edit: gerade den Post gesehen ... probier ich gleich


SirRufo das seh ich mir gleich mal an ^^ ))))

Gruß
SM