Leeres Eingabefeld mit Standardwert füllen

[frankyboy1974]

hallo,

also wenn es wirklich erforderlich ist, das der Hint bis zur ersten Zeicheingabe stehen bleibt, würde ich dem Edit-Feld einfach den Standardwert zuweisen und im onEnter ggf. selectall aufrufen.

Kann es gerade nicht testen, müsste aber funktionieren.

mfg

[Sir Rufo]

Nun ja, es braucht da keine Stunden an Entwicklungszeit

Delphi-Quellcode:

unit Unit1;

interface

uses
  System.Classes,
  Winapi.Windows, Winapi.Messages,
  Vcl.Controls, Vcl.StdCtrls, Vcl.Graphics;

type
  TEdit = class( Vcl.StdCtrls.TEdit )
  private
    FCanvas    : TCanvas;
    FMyTextHint: string;
    procedure WMPaint( var Message: TWMPaint ); message WM_PAINT;
    procedure SetMyTextHint( const Value: string );
  protected
    procedure WndProc( var Message: TMessage ); override;
    procedure Paint; virtual;
    procedure PaintWindow( DC: HDC ); override;
    property Canvas: TCanvas read FCanvas;
  public
    constructor Create( AOwner: TComponent ); override;
    destructor Destroy; override;

    property MyTextHint: string read FMyTextHint write SetMyTextHint;
  end;

implementation

{ TEdit }

constructor TEdit.Create( AOwner: TComponent );
begin
  inherited Create( AOwner );
  FCanvas                           := TControlCanvas.Create;
  TControlCanvas( FCanvas ).Control := Self;
end;

destructor TEdit.Destroy;
begin
  FCanvas.Free;
  inherited;
end;

procedure TEdit.Paint;
var
  R: TRect;
begin
  R := ClientRect;
  Inc( R.Left, 1 );
  Inc( R.Top, 1 );
  Canvas.Brush.Assign( Self.Brush );
  Canvas.Font.Assign( Self.Font );

  Canvas.Font.Color := clGray;
  DrawText( Canvas.Handle, PChar( FMyTextHint ), -1, R, DT_LEFT or DT_NOPREFIX or DT_WORDBREAK or DrawTextBiDiModeFlagsReadingOnly );
end;

procedure TEdit.PaintWindow( DC: HDC );
begin
  FCanvas.Lock;
  try
    FCanvas.Handle := DC;
    try
      TControlCanvas( FCanvas ).UpdateTextFlags;
      Paint;
    finally
      FCanvas.Handle := 0;
    end;
  finally
    FCanvas.Unlock;
  end;
end;

procedure TEdit.SetMyTextHint( const Value: string );
begin
  if FMyTextHint <> Value
  then
    begin
      FMyTextHint := Value;
      Invalidate;
    end;
end;

procedure TEdit.WMPaint( var Message: TWMPaint );
begin
  if Text = ''
  then
    begin
      ControlState := ControlState + [ csCustomPaint ];
      inherited;
      ControlState := ControlState - [ csCustomPaint ];
    end
  else
    inherited;
end;

procedure TEdit.WndProc( var Message: TMessage );
begin
  inherited WndProc( message );
  with message do
    case Msg of
      CM_MOUSEENTER, CM_MOUSELEAVE, WM_LBUTTONUP, WM_LBUTTONDOWN, WM_KEYDOWN, WM_KEYUP, WM_SETFOCUS, WM_KILLFOCUS, CM_FONTCHANGED, CM_TEXTCHANGED:
        begin
          Invalidate;
        end;
    end; // case
end;

end.

[Jean312]

Hallo,

danke euch allen.
Die Sache mit dem "TextHint" kannte ich nicht. Habe es in den Eigenschaften nicht gefunden. Aber wie ich gerade gelesen habe, kommt es vom OS. Ich werde es ausprobieren.
@Sir Rufo: Danke für das Beispiel

@Bernhard Geyer: War von mir anscheinend wohl blöd formuliert. Es reicht wirklich, dass der Hint kommt, wenn das Feld leer ist und sobald es gefüllt wird oder ist, dass er verschwindet.

@Perlsau: Vielen Dank für die Linksammlung.
Ich muss mich eh mit dieser Sache mal beschäftigen. Brauche noch andere Sachen, die dann mit einer "eigenen Komponente" umgesetzt werden können. Lernen schadet nicht, kostet nur Zeit.

[Jean312]

Euch allen ein schönes Fest.

[Bernhard Geyer]

Zitat von Sir Rufo:

Nun ja, es braucht da keine Stunden an Entwicklungszeit

Er hat glück das er diese x Stunden (x: Float) von dir kostenlos zur Verfügung gestellt wurde.

[Jean312]

@Bernhard Geyer:Stimmt. Danke nochmal an Sir Rufo.

[Sir Rufo]

Zitat von Bernhard Geyer:

Zitat von Sir Rufo:

Nun ja, es braucht da keine Stunden an Entwicklungszeit

Er hat glück das er diese x Stunden (x: Float) von dir kostenlos zur Verfügung gestellt wurde.

Um ehrlich zu sein, war x = 0,167

(Man muss nur wissen, wonach man suchen muss http://stackoverflow.com/questions/9...t-control-text)

[haentschman]

Zitat:

Ich vermute ganz einfach, dass die Property weder dem TE noch den ersten Antwortenden bekannt war.

...allerdings. Solange man die Handbremse am Auto nicht braucht, weiß man auch nicht wo sie ist...
[OT]
Die Property allerdings ...Hint zu nennen ist irgendwie dämlich. Da soll man beim drüberstolpern drauf kommen.
[/OT]

Zitat:

Man muss nur wissen, wonach man suchen muss

Mein Lehrmeister hatte mal gesagt: Man muß nicht alles wissen, man muß wissen wo es steht. Ein weiser Mann...

[Sir Rufo]

Zitat von haentschman:

Zitat:

Ich vermute ganz einfach, dass die Property weder dem TE noch den ersten Antwortenden bekannt war.

...allerdings. Solange man die Handbremse am Auto nicht braucht, weiß man auch nicht wo sie ist...
[OT]
Die Property allerdings ...Hint zu nennen ist irgendwie dämlich. Da soll man beim drüberstolpern drauf kommen.
[/OT]

Die Namensgebung kommt wohl daher, dass es eine Eigenschaft Text gibt. Und durch die alphabetische Sortierung kommt TextHint direkt darunter ... so dass man es nicht übersehen kann, wenn man an der Text Eigenschaft herumfummelt

[haentschman]

Ja sicher... Nur ein Hint schwebt für mich über dem Edit in quietsch gelb und nicht als leerer Text drin. Ich würde die Property nicht näher anschauen weil ich davon ausginge das das meinem Zweck nicht entspricht.

PS: Wenn ich jede Property nachlesen würde käme ich nicht mehr zum arbeiten...