AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
• Registrieren
Zurück Delphi-PRAXiS Programmierung allgemein Datenbanken MySQL Query Update funktioniert nicht
Thema durchsuchen
Ansicht
Themen-Optionen

MySQL Query Update funktioniert nicht

Ein Thema von akio87 · begonnen am 28. Okt 2015 · letzter Beitrag vom 2. Nov 2015
Antwort Antwort
Seite 1 von 2  1 2      
akio87

Registriert seit: 18. Mär 2010
44 Beiträge
 
Delphi XE8 Architect
 
#1

MySQL Query Update funktioniert nicht

  Alt 28. Okt 2015, 17:27
Datenbank: MySQL • Version: 5 • Zugriff über: ??
Hallo,

ich habe festgestellt, dass meine alte Update Funktion, siehe 2. Code, in der BDGrid mit einem Leerem String nicht funktioniert. In der neuen Variante, wo ich dachte, das es dort geht, funktioniert der leere String ebenfalls nicht + Update generell nicht, mit folgender Fehlermeldung:
Error: SQL Syntax...

Habt ihr eine Idee?

NEU:
markieren
Code:
  MainModule.UniMainModule.mySQLUpdateSQL1.ModifySQL.Clear;
  MainModule.UniMainModule.mySQLUpdateSQL1.ModifySQL.Add('update `' + Tabelle + '`');
  MainModule.UniMainModule.mySQLUpdateSQL1.ModifySQL.Add('set ');
  MainModule.UniMainModule.mySQLUpdateSQL1.ModifySQL.Add('Firma = :Firma, ');
  MainModule.UniMainModule.mySQLUpdateSQL1.ModifySQL.Add('Adress1 = :Adress1, ');
  MainModule.UniMainModule.mySQLUpdateSQL1.ModifySQL.Add('Adress2 = :Adress2, ');
  MainModule.UniMainModule.mySQLUpdateSQL1.ModifySQL.Add('Straße = :Straße, ');
  MainModule.UniMainModule.mySQLUpdateSQL1.ModifySQL.Add('PLZ = :PLZ, ');
  MainModule.UniMainModule.mySQLUpdateSQL1.ModifySQL.Add('Ort = :Ort, ');
  MainModule.UniMainModule.mySQLUpdateSQL1.ModifySQL.Add('Land = :Land, ');
  MainModule.UniMainModule.mySQLUpdateSQL1.ModifySQL.Add('Such1 = :Such1 ');
  MainModule.UniMainModule.mySQLUpdateSQL1.ModifySQL.Add('Such2 = :Such2 ');
  MainModule.UniMainModule.mySQLUpdateSQL1.ModifySQL.Add('where ');
  MainModule.UniMainModule.mySQLUpdateSQL1.ModifySQL.Add('Firma = :OLD_Firma and ');
  MainModule.UniMainModule.mySQLUpdateSQL1.ModifySQL.Add('Adress1 = :OLD_Adress1 and ');
  MainModule.UniMainModule.mySQLUpdateSQL1.ModifySQL.Add('Adress2 = :OLD_Adress2 and ');
  MainModule.UniMainModule.mySQLUpdateSQL1.ModifySQL.Add('Straße = :OLD_Straße and ');
  MainModule.UniMainModule.mySQLUpdateSQL1.ModifySQL.Add('PLZ = :OLD_PLZ and ');
  MainModule.UniMainModule.mySQLUpdateSQL1.ModifySQL.Add('Ort = :OLD_Ort and ');
  MainModule.UniMainModule.mySQLUpdateSQL1.ModifySQL.Add('Land = :OLD_Land and ');
  MainModule.UniMainModule.mySQLUpdateSQL1.ModifySQL.Add('Such1 = :OLD_Such1 and ');
  MainModule.UniMainModule.mySQLUpdateSQL1.ModifySQL.Add('Such2 = :OLD_Such2;');

Mein Alter Code: Da ging die Update Funktion. Bis auf einem Leeren String....
markieren
Code:
{MainModule.UniMainModule.mySQLUpdateSQL1.ModifySQL.Text := 'update ' + Tabelle + #10 +
                                                            'set' + #10 +
                                                            ' Firma = :Firma,'+ #10 +
                                                            ' Adress1 = :Adress1,'+ #10 +
                                                            ' Adress2 = :Adress2,'+ #10 +
                                                            ' Straße = :Straße,'+ #10 +
                                                            ' PLZ = :PLZ,'+ #10 +
                                                            ' Ort = :Ort,'+ #10 +
                                                            ' Land = :Land,'+ #10 +
                                                            ' Such1 = :Such1,'+ #10 +
                                                            ' Such2 = :Such2'+ #10 +
                                                            'where'+ #10 +
                                                            ' Firma = :OLD_Firma and'+ #10 +
                                                            ' Adress1 = :OLD_Adress1 and'+ #10 +
                                                            ' Adress2 = :OLD_Adress2 and'+ #10 +
                                                            ' Straße = :OLD_Straße and'+ #10 +
                                                            ' PLZ = :OLD_PLZ and'+ #10 +
                                                            ' Ort = :OLD_Ort and'+ #10 +
                                                            ' Land = :OLD_Land and'+ #10 +
                                                            ' Such1 = :OLD_Such1 and'+ #10 +
                                                            ' Such2 = :OLD_Such2';
 }
  Mit Zitat antworten Zitat
nahpets
(Gast)

n/a Beiträge
 
#2

AW: MySQL Query Update funktioniert nicht

  Alt 28. Okt 2015, 17:39
fehlt da ein Komma?   MainModule.UniMainModule.mySQLUpdateSQL1.ModifySQL.Add('Such1 = :Such1 '); Wie befüllst Du denn die Parameter? (Quellcode dazu?)

Was meinst Du mit 'leere String'?

Wo ist der im geposteten Quelltext zu suchen?
  Mit Zitat antworten Zitat
akio87

Registriert seit: 18. Mär 2010
44 Beiträge
 
Delphi XE8 Architect
 
#3

AW: MySQL Query Update funktioniert nicht

  Alt 28. Okt 2015, 17:48
Hallo,

mein Gott hast Du scharfsinnige Augen

Das Updaten der Zeilen funktioniert jetzt, Danke deiner Hilfe.

Leider noch keine Leeren Datensätze, also "" Zellen... Mal Angenommen, ich möchte das Adressfeld1 leeren und speichern in der DBGrid. Das wird nicht übernommen.

DBGrid.Datasource -> UniMainModule.DataSource3.Dataset -> mySQLQuery3.UpdateObject -> mySQLUpdateSQL1

Code komplett:
markieren
Code:
procedure TfmAdressverwaltung.UniFormShow(Sender: TObject);
begin
  UniButton1.Click;
end;

procedure TfmAdressverwaltung.UniButton1Click(Sender: TObject);
var
  search, Tabelle: String;
begin

  if UniMainModule.RRSuche = True then
   begin
     Tabelle := 'Rechnungsadressen';
   end else
   begin
     Tabelle := 'Lieferadressen';
   end;

  MainModule.UniMainModule.mySQLUpdateSQL1.ModifySQL.Clear;
  MainModule.UniMainModule.mySQLUpdateSQL1.ModifySQL.Add('update `' + Tabelle + '`');
  MainModule.UniMainModule.mySQLUpdateSQL1.ModifySQL.Add('set');
  MainModule.UniMainModule.mySQLUpdateSQL1.ModifySQL.Add('Firma = :Firma,');
  MainModule.UniMainModule.mySQLUpdateSQL1.ModifySQL.Add('Adress1 = :Adress1,');
  MainModule.UniMainModule.mySQLUpdateSQL1.ModifySQL.Add('Adress2 = :Adress2,');
  MainModule.UniMainModule.mySQLUpdateSQL1.ModifySQL.Add('Straße = :Straße,');
  MainModule.UniMainModule.mySQLUpdateSQL1.ModifySQL.Add('PLZ = :PLZ,');
  MainModule.UniMainModule.mySQLUpdateSQL1.ModifySQL.Add('Ort = :Ort,');
  MainModule.UniMainModule.mySQLUpdateSQL1.ModifySQL.Add('Land = :Land,');
  MainModule.UniMainModule.mySQLUpdateSQL1.ModifySQL.Add('Such1 = :Such1,');
  MainModule.UniMainModule.mySQLUpdateSQL1.ModifySQL.Add('Such2 = :Such2');
  MainModule.UniMainModule.mySQLUpdateSQL1.ModifySQL.Add('where');
  MainModule.UniMainModule.mySQLUpdateSQL1.ModifySQL.Add('Firma = :OLD_Firma and');
  MainModule.UniMainModule.mySQLUpdateSQL1.ModifySQL.Add('Adress1 = :OLD_Adress1 and');
  MainModule.UniMainModule.mySQLUpdateSQL1.ModifySQL.Add('Adress2 = :OLD_Adress2 and');
  MainModule.UniMainModule.mySQLUpdateSQL1.ModifySQL.Add('Straße = :OLD_Straße and');
  MainModule.UniMainModule.mySQLUpdateSQL1.ModifySQL.Add('PLZ = :OLD_PLZ and');
  MainModule.UniMainModule.mySQLUpdateSQL1.ModifySQL.Add('Ort = :OLD_Ort and');
  MainModule.UniMainModule.mySQLUpdateSQL1.ModifySQL.Add('Land = :OLD_Land and');
  MainModule.UniMainModule.mySQLUpdateSQL1.ModifySQL.Add('Such1 = :OLD_Such1 and');
  MainModule.UniMainModule.mySQLUpdateSQL1.ModifySQL.Add('Such2 = :OLD_Such2');


  search := '%' + UniEdit1.Text + '%';

  fmstart1.UniMemo1.Lines.Clear;
  fmstart1.UniMemo1.Lines.Text := 'select Firma, Adress1, Adress2, Straße, PLZ, Ort, Land, Such1, Such2 from ' + Tabelle + #10 +
                         'where Ident = ' + IntToStr(UniMainModule.Ident) + #10 +
                         'AND (Firma like '+QuotedStr(search)+' OR Adress1 like '+ QuotedStr(search)+' OR Adress2 like '+ QuotedStr(search)+' OR Straße like '+ QuotedStr(search)+ 'OR PLZ like '+ QuotedStr(search)+ 'OR Ort like '+ QuotedStr(search)+ 'OR Land like '+ QuotedStr(search)+ 'OR Such1 like '+ QuotedStr(search)+ 'OR Such2 like '+ QuotedStr(search)+')';

  UniMainModule.mySQLQuery3.SQL.Text := fmstart1.UniMemo1.Lines.Text;
  UniMainModule.mySQLQuery3.Open;

  UniDBGrid1.Columns[0].Width := 250;
  UniDBGrid1.Columns[1].Width := 100;
  UniDBGrid1.Columns[2].Width := 70;
  UniDBGrid1.Columns[3].Width := 150;
  UniDBGrid1.Columns[4].Width := 50;
  UniDBGrid1.Columns[5].Width := 100;
  UniDBGrid1.Columns[6].Width := 100;
  UniDBGrid1.Columns[7].Width := 100;
  UniDBGrid1.Columns[8].Width := 100;
end;
Geändert von akio87 (28. Okt 2015 um 17:56 Uhr)
  Mit Zitat antworten Zitat
nahpets
(Gast)

n/a Beiträge
 
#4

AW: MySQL Query Update funktioniert nicht

  Alt 28. Okt 2015, 17:53
Vielleicht, weil leere Datenbankfelder nicht = "" sind sondern Null?

Also müsstest Du ggfls. überall auch noch auf or spalte is Null abfragen?
  Mit Zitat antworten Zitat
akio87

Registriert seit: 18. Mär 2010
44 Beiträge
 
Delphi XE8 Architect
 
#5

AW: MySQL Query Update funktioniert nicht

  Alt 28. Okt 2015, 18:08
Ändert sich etwas, wenn ich in der Datenbank die Spalten "Standard" -> "Kein(e)" anpasse und bei "NULL" den haken entferne?

Hab es zwar gerade getestet, scheint so ohne weiteres nicht zu funktionieren...

Spalten auf Null abfragen? Dies bräuchte ich eigentlich dann nur für "Adress1, Adress2, Such1, Such2"...

Wie baut man sowas jetzt da mit ein? So in etwa:

markieren
Code:
  MainModule.UniMainModule.mySQLUpdateSQL1.ModifySQL.Add('Adress1 = :Adress1 or spalte is Null');
  Mit Zitat antworten Zitat
nahpets
(Gast)

n/a Beiträge
 
#6

AW: MySQL Query Update funktioniert nicht

  Alt 28. Okt 2015, 18:11
jo, genau so, wie in Deinem Beispiel.
  MainModule.UniMainModule.mySQLUpdateSQL1.ModifySQL.Add('Adress1 = :Adress1 or Adress1 is Null');
  Mit Zitat antworten Zitat
BadenPower

Registriert seit: 17. Jun 2009
616 Beiträge
 
#7

AW: MySQL Query Update funktioniert nicht

  Alt 31. Okt 2015, 13:08
ich habe festgestellt, dass meine alte Update Funktion, siehe 2. Code, in der BDGrid mit einem Leerem String nicht funktioniert. In der neuen Variante, wo ich dachte, das es dort geht, funktioniert der leere String ebenfalls nicht + Update generell nicht, mit folgender Fehlermeldung:
Error: SQL Syntax...

Habt ihr eine Idee?
Für diese Problem habe ich mir spezielle Funktionen geschrieben, welche die Statements automatisch und unabhängig von der jeweils verwendeten Tabelle erstellen.

Die Funktionen berücksichtigen auch, dass in den Komponenten enthaltenen NULL-Wert des Feldes, welcher dann wahlweise als NULL oder als Leerstring übergeben werden kann.

zusammenfalten · markieren
Delphi-Quellcode:
unit uDataModuleDB;

interface

uses
  SysUtils, Classes, Forms, Dialogs, Variants, DB,
  ZConnection, ZAbstractTable, ZDataset, ZAbstractRODataset,
  ZAbstractDataset, ZSqlProcessor, ZSqlMonitor;

type
  TDMDb = class(TDataModule)
  public
    function GenerateZUpdateSQLInsert(ATable: TZTable): String; overload;
    function GenerateZUpdateSQLInsert(ATable: TZTable; ANullAsString: Boolean): String; overload;
    function GenerateZUpdateSQLModify(ATable: TZTable): String; overload;
    function GenerateZUpdateSQLModify(ATable: TZTable; ANullAsString: Boolean): String; overload;
    function GenerateZUpdateSQLDelete(ATable: TZTable): String; overload;
    function GenerateZUpdateSQLDelete(ATable: TZTable; ANullAsString: Boolean): String; overload;
    function GenerateZTableSQLSelectOldValues(ATable: TZTable): String;
    function GenerateZTableSQLSelectCountOldValues(ATable: TZTable): String;
    function GenerateZTableSQLWhereOldValues(ATable: TZTable): String;


  end;

var
  DMDb: TDMDb;

implementation

function TDMDb.GenerateZTableSQLWhereOldValues(ATable: TZTable): string;
var
  liZ1: integer;
  lSQLWhere: String;
begin
  lSQLWhere := '';

  for liZ1 := 0 to ATable.FieldCount - 1 do
   begin
    if (liZ1 > 0) then
     begin
      lSQLWhere := lSQLWhere + ' AND ';
     end;
    lSQLWhere := lSQLWhere + '(';
    if(VarIsNull(ATable.Fields[liZ1].OldValue)) then
     begin
      lSQLWhere := lSQLWhere + '(';
     end;
    lSQLWhere := lSQLWhere + ATable.Fields[liZ1].FieldName + ' = ' + ':OLD_' + ATable.Fields[liZ1].FieldName;
    if(VarIsNull(ATable.Fields[liZ1].OldValue)) then
     begin
      lSQLWhere := lSQLWhere + ')';
      lSQLWhere := lSQLWhere + ' OR (' + ATable.Fields[liZ1].FieldName + ' IS NULL )';
      lSQLWhere := lSQLWhere + ' OR (' + ATable.Fields[liZ1].FieldName + ' = 0 )';
     end;
    lSQLWhere := lSQLWhere + ')';
   end;

  if (lSQLWhere <> '') then
   begin
    lSQLWhere := ' WHERE ' + lSQLWhere;
   end;

  Result := lSQLWhere;
end;

function TDMDb.GenerateZUpdateSQLInsert(ATable: TZTable): string;
begin
  Result := GenerateZUpdateSQLInsert(ATable,true);
end;

function TDMDb.GenerateZUpdateSQLInsert(ATable: TZTable; ANullAsString: boolean): string;
var
  liZ1: integer;
  lSQL: String;
  lSQLFields: String;
  lSQLValues: String;
begin
  lSQLFields := '';
  lSQLValues := '';
  lSQL := 'INSERT INTO ' + ATable.TableName;
  for liZ1 := 0 to ATable.FieldCount - 1 do
   begin
    if (liZ1 > 0) then
     begin
      lSQLFields := lSQLFields + ' , ';
      lSQLValues := lSQLValues + ' , ';
     end;
    lSQLFields := lSQLFields + ATable.Fields[liZ1].FieldName;
    if ( (ANullAsString)
         and (ATable.Fields[liZ1].DataType in [ftString,ftMemo,ftFmtMemo,ftFixedChar,ftWideString,ftFixedWideChar,ftWideMemo])
         and (VarToStr(ATable.Fields[liZ1].Value) = '')
       ) then
     begin
      lSQLValues := lSQLValues + '''' + '''';
     end
    else
     begin
      lSQLValues := lSQLValues + ':' + ATable.Fields[liZ1].FieldName;
     end;
   end;
  lSQL := lSQL + ' (' + lSQLFields + ') VALUES (' + lSQLValues + ')';
  Result := lSQL + ';';

end;

function TDMDb.GenerateZUpdateSQLModify(ATable: TZTable): string;
begin
  Result := GenerateZUpdateSQLModify(ATable,true);
end;

function TDMDb.GenerateZUpdateSQLModify(ATable: TZTable; ANullAsString: boolean): string;
var
  liZ1: integer;
  lSQL: String;
  lSQLWhere: String;
begin

  lSQL := 'UPDATE ' + ATable.TableName + ' SET ';
  for liZ1 := 0 to ATable.FieldCount - 1 do
   begin
    if (liZ1 > 0) then
     begin
      lSQL := lSQL + ' , ';
     end;

    lSQL := lSQL + ATable.Fields[liZ1].FieldName + ' = ';
    if ( (ANullAsString)
         and (ATable.Fields[liZ1].DataType in [ftString,ftMemo,ftFmtMemo,ftFixedChar,ftWideString,ftFixedWideChar,ftWideMemo])
         and (VarToStr(ATable.Fields[liZ1].Value) = '')
       ) then
     begin
      lSQL := lSQL + '''' + '''';
     end
    else
     begin
      lSQL := lSQL + ':' + ATable.Fields[liZ1].FieldName;
     end;

   end;
  lSQLWhere := GenerateZTableSQLWhereOldValues(ATable);
  Result := lSQL + lSQLWhere + ';';

end;

function TDMDb.GenerateZUpdateSQLDelete(ATable: TZTable): string;
begin
  Result := GenerateZUpdateSQLDelete(ATable,true);
end;

function TDMDb.GenerateZUpdateSQLDelete(ATable: TZTable; ANullAsString: boolean): string;
var
  lSQL: String;
  lSQLWhere: String;
begin
  lSQL := 'DELETE FROM ' + ATable.TableName;
  lSQLWhere := GenerateZTableSQLWhereOldValues(ATable);
  Result := lSQL + lSQLWhere + ';';
end;

end;
Der Aufruf und das Generieren der Statements erfolgt dann in der Update-Komponente in den jeweiligen Events OnBeforeDelete, OnBeforeInsert und OnBeforeModify:

zusammenfalten · markieren
Delphi-Quellcode:
procedure TF_Data.ZUPS_TableBeforeDeleteSQL(Sender: TObject);
begin
  ZUPS_Table.DeleteSQL.Text := DMDb.GenerateZUpdateSQLDelete(ZT_Table);
end;

procedure TF_Data.ZUPS_TableBeforeInsertSQL(Sender: TObject);
begin
  ZUPS_Table.InsertSQL.Text := DMDb.GenerateZUpdateSQLInsert(ZT_Table);
end;

procedure TF_Data.ZUPS_TableBeforeModifySQL(Sender: TObject);
begin
  ZUPS_Table.ModifySQL.Text := DMDb.GenerateZUpdateSQLModify(ZT_Table);
end;
Ich hoffe das hilft Dir weiter.
Programmieren ist die Kunst aus Nullen und Einsen etwas sinnvollen zu gestalten.
Der bessere Künstler ist allerdings der Anwender, denn dieser findet Fehler, welche sich der Programmierer nicht vorstellen konnte.
  Mit Zitat antworten Zitat
Dejan Vu
(Gast)

n/a Beiträge
 
#8

AW: MySQL Query Update funktioniert nicht

  Alt 2. Nov 2015, 07:05
Sehr schön, das Du die 'hässliche' Generierung der SQL-Befehle so versteckst. Das schafft Übersicht.

Zwei Anmerkungen:
1. Wieso deklarierst du nicht einfach ein Feld als 'PK', dann kannst Du dir das 'WhereOldValues' sparen?
2. Deine NULL-Behandlung sieht (auf den ersten Blick beim Frühstück) etwas wackelig aus. Du behandelst '0' als NULL-Äquivalent, aber den leeren String nicht?
  Mit Zitat antworten Zitat
BadenPower

Registriert seit: 17. Jun 2009
616 Beiträge
 
#9

AW: MySQL Query Update funktioniert nicht

  Alt 2. Nov 2015, 10:00
Sehr schön, das Du die 'hässliche' Generierung der SQL-Befehle so versteckst. Das schafft Übersicht.
Wieso verstecken?
Das sind Grundfunktionen und für jede Tabelle ausführbar und gehören daher zur Übersichtlichkeit des Quellcodes in separate Funktionen.

1. Wieso deklarierst du nicht einfach ein Feld als 'PK', dann kannst Du dir das 'WhereOldValues' sparen?
Man sollte etwas über den Tellerrand hinausschauen und dann würde man feststellen, dass ein PK nicht das leistet, was die Generierung dieses SQL-Statements leistet.

Durch das SQL-Statement ist gewährleistet, dass der Datensatz nur geändert wird, wenn zwischenzeitlich keine Änderungen des Datensatzes durch z.B einen anderen User durchgeführt wurden.

Der PK "erkennt" dies ja nicht.

2. Deine NULL-Behandlung sieht (auf den ersten Blick beim Frühstück) etwas wackelig aus. Du behandelst '0' als NULL-Äquivalent, aber den leeren String nicht?
Weil dies nicht notwendig ist.
Programmieren ist die Kunst aus Nullen und Einsen etwas sinnvollen zu gestalten.
Der bessere Künstler ist allerdings der Anwender, denn dieser findet Fehler, welche sich der Programmierer nicht vorstellen konnte.
Geändert von BadenPower ( 2. Nov 2015 um 10:11 Uhr)
  Mit Zitat antworten Zitat
Benutzerbild von Sir Rufo
Sir Rufo

Registriert seit: 5. Jan 2005
Ort: Stadthagen
9.454 Beiträge
 
Delphi 10 Seattle Enterprise
 
#10

AW: MySQL Query Update funktioniert nicht

  Alt 2. Nov 2015, 15:35
Um Concurrent Conflicts zu erkennen würde auch ein Feld mit der RowVersion reichen.
Kaum macht man's richtig - schon funktioniert's
Zertifikat: Sir Rufo (Fingerprint: ‎ea 0a 4c 14 0d b6 3a a4 c1 c5 b9 dc 90 9d f0 e9 de 13 da 60)
  Mit Zitat antworten Zitat
Antwort Antwort
Seite 1 von 2  1 2      

« Vorheriges Thema | Nächstes Thema »

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.
BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus
Gehe zu:

• Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 11:14 Uhr.
Powered by vBulletin® Copyright ©2000 - 2025, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024-2025 by Thomas Breitkreuz