Partition auslesen mit DeviceIoControl und IOCTL_DISK_GET_PARTITION_INFO_EX

[Captnemo]

Gibt es denn keinen hier, der das schon mal gemacht hat? Vielleicht muss ich in DRIVE_LAYOUT_INFORMATION_EX das Array anders initialisieren?

[p80286]

Zitat von Captnemo:

Gibt es denn keinen hier, der das schon mal gemacht hat? Vielleicht muss ich in DRIVE_LAYOUT_INFORMATION_EX das Array anders initialisieren?

Doch, doch aber das ist schon ewig lange her und da hat man die Platte noch mit den x13h ausgelesen. Ich glaube nicht das Dir das was bringt.
Liest Du denn die Adresse der FolgePartition richtig aus?
(so auf die schnelle hab' ich da nichts gefunden)

Gruß
K-H

[Captnemo]

Naja, die ich lese ja nicht die Partitionen direkt.

Rufe die Funktion DeviceIoControl auf und übergebe diese den CommandString IOCTL_DISK_GET_DRIVE_LAYOUT_EX.
Die Funktion soll dann alle im Record DRIVE_LAYOUT_INFORMATION_EX deklarierten Daten auslesen und im Array PartitionInfoEx eben alle PartitonInformationen ablegen, also ParitionStyle, StartOffset, Länge usw.
Dieses Array muss mindestens so groß sein, wie die Funktion Partitionen darin speichern will. Heißt, will sie 1 Partition speichern würde ein Array[0..0] reichen. Will sie 2 Speichern, dann muss es mindestens ein Array[0..1] sein. Größer darf das Array aber wohl immer sein.

Wenn ich im Interface
PartitionInfoEx: array[0..0] of _PARTITION_INFORMATION_EX; angebe, wie ich es schon auf einigen Seiten gelesen habe, dann bekomme ich von DeviceIoControl ein False zurück.
Mit
PartitionInfoEx: array[0..15] of _PARTITION_INFORMATION_EX; bekomme ich zumindest mal mehr zurück.
Aber es kommen nur für die 1. Partition die richtigen Daten. Die Inhalte von den dahinterliegenden Array-Elementen sind eher willkürlich.
Da aber die Funktion DeviceIoControl True zurückmeldet, gehe ich mal davon aus, dass sie grundsätzlich mit dem zur Verfügung stehenden Speicher zufrieden ist.
Vielleicht habe ich ja auch den Record falsch deklariert (Mit den Übersetzungen aus C in Delphi habe ich gar keine Erfahrung).
Oder vielleicht berechne ich bei GetMem den Speicher falsch.

Da MS da ganz sicher keine Fehler macht, muss er ja bei mir liegen.

Aber ich habe so gar keine Idee mehr (mangels Erfahrung), woran das liegen kann.

[Zacherl]

Deine Structs waren an einigen Stellen falsch, deshalb hast du bei den späteren Einträgen an den falschen Offsets gelesen. So funktioniert es:

Delphi-Quellcode:

type
  PARTITION_INFORMATION_MBR = record
    PartitionType: Byte;
    BootIndicator: Boolean;
    RecognizedPartition: Boolean;
    HiddenSectors: DWord;
  end;

  PARTITION_INFORMATION_GPT = record
    PartitionType: TGUID;
    PartitionId: TGUID;
    Attributes: DWORD64;
    Name: array[0..35] of WCHAR;
  end;

  PARTITION_STYLE = type DWord;

  PARTITION_INFORMATION_EX = record
    PartitionStyle: PARTITION_STYLE;
    StartingOffset: LARGE_INTEGER;
    PartitionLength: LARGE_INTEGER;
    PartitionNumber: DWord;
    RewritePartition: Boolean;
    case Integer of
      0: (Mbr: PARTITION_INFORMATION_MBR);
      1: (Gpt: PARTITION_INFORMATION_GPT);
  end;
  TPartitionInformationEx = PARTITION_INFORMATION_EX;
  PPartitionInformationEx = ^TPartitionInformationEx;

  DRIVE_LAYOUT_INFORMATION_MBR = record
    Signature: DWord;
  end;

  DRIVE_LAYOUT_INFORMATION_GPT = record
    DiskId: TGUID;
    StartingUsableOffset: LARGE_INTEGER;
    UsableLength: LARGE_INTEGER;
    MaxPartitionCount: DWord;
  end;

  DRIVE_LAYOUT_INFORMATION_UNION = record
  case Integer of
    0: (Mbr: DRIVE_LAYOUT_INFORMATION_MBR);
    1: (Gpt: DRIVE_LAYOUT_INFORMATION_GPT);
  end;

  DRIVE_LAYOUT_INFORMATION_EX = record
    PartitionStyle: DWord;
    PartitionCount: DWord;
    DriveLayoutInformation: DRIVE_LAYOUT_INFORMATION_UNION;
    PartitionEntry: array[0..0] of PARTITION_INFORMATION_EX;
  end;
  TDriveLayoutInformationEx = DRIVE_LAYOUT_INFORMATION_EX;
  PDriveLayoutInformationEx = ^TDriveLayoutInformationEx;

procedure PrintVolumeInformation(PhysicalDriveId: Integer);
var
  hDevice: THandle;
  LayoutInfo: PDriveLayoutInformationEx;
  LayoutInfoSize,
  BytesReturned: DWord;
  I: Integer;
begin
  hDevice := CreateFile(PChar('\\.\PhysicalDrive' + IntToStr(PhysicalDriveId)), 0,
    FILE_SHARE_READ or FILE_SHARE_WRITE, nil, OPEN_EXISTING, 0, 0);
  if (hDevice = INVALID_HANDLE_VALUE) then RaiseLastOSError;
  try
    LayoutInfoSize := SizeOf(TDriveLayoutInformationEx) + SizeOf(TPartitionInformationEx) * 3;
    GetMem(LayoutInfo, LayoutInfoSize);
    try
      while (not DeviceIoControl(hDevice, IOCTL_DISK_GET_DRIVE_LAYOUT_EX, nil, 0, LayoutInfo,
        LayoutInfoSize, BytesReturned, nil)) do
      begin
        if (GetLastError <> ERROR_INSUFFICIENT_BUFFER) then RaiseLastOSError;
        LayoutInfoSize := LayoutInfoSize + SizeOf(TPartitionInformationEx) * 4;
        ReallocMem(LayoutInfo, LayoutInfoSize);
      end;
      for I := 0 to LayoutInfo^.PartitionCount - 1 do
      begin
        WriteLn(LayoutInfo^.PartitionEntry[I].PartitionNumber);
        // ..
      end;
    finally
      FreeMem(LayoutInfo);
    end;
  finally
    CloseHandle(hDevice);
  end;
end;

[HolgerX]

Delphi-Quellcode:

begin
  for h := 1 to 9 do
  begin
    Device:='\\.\Harddisk1'+IntToStr(h);
    hdevice:=CreateFile(PChar(Device), 0, FILE_SHARE_READ or FILE_SHARE_WRITE, nil, OPEN_EXISTING, 0, 0);
    if hDevice <> INVALID_HANDLE_VALUE then
    begin

müsste das nicht so sein:

Delphi-Quellcode:

begin
  for h := 1 to 9 do
  begin
    Device:='\\.\Harddisk'+IntToStr(h);  // ohne die 1
    hdevice:=CreateFile(PChar(Device), 0, FILE_SHARE_READ or FILE_SHARE_WRITE, nil, OPEN_EXISTING, 0, 0);
    if hDevice <> INVALID_HANDLE_VALUE then
    begin

[Captnemo]

Hi Zacherl,

Dank dir erst mal für die GROSSE Hilfe.

Ein paar Fragen hätte ich noch, damit ich das auch verstehe:

1.
In dem Teil:

Delphi-Quellcode:

DRIVE_LAYOUT_INFORMATION_EX = record
    PartitionStyle: DWord;
    PartitionCount: DWord;
    DriveLayoutInformation: DRIVE_LAYOUT_INFORMATION_UNION;
    PartitionEntry: array[0..0] of PARTITION_INFORMATION_EX;
  end;
  TDriveLayoutInformationEx = DRIVE_LAYOUT_INFORMATION_EX;
  PDriveLayoutInformationEx = ^TDriveLayoutInformationEx;

PDriveLayoutInformationEx ist klar, das ist der Pointer.
Aber warum macht man noch mal TDriveLayoutInformationEx = DRIVE_LAYOUT_INFORMATION_EX; ?
PDriveLayoutInformationEx = ^DRIVE_LAYOUT_INFORMATION_EX; hätt's doch auch getan, oder geht das nicht?

2.

Warum benötigt man das ReallocMem ? Ist das deshalb, weil DeciveIoControl das Array verändert und sich deshalb die Größe des Speichers von TDriveLayoutInformationEx verändert hat? Oder welchem Zweck dient das?

3.
Du berechnest die Größe vom LayoutInfo so
 LayoutInfoSize:=SizeOf(TDriveLayoutInformationEx) + (SizeOf(TPartitionInformationEx)*3); Warum * 3?

Und wenn DeviceIoControl erfolgreich war, dann
        LayoutInfoSize:=LayoutInfoSize + (SizeOf(TPartitionInformationEx) *4); Okay, das * 4 könnte ich darauf zurückführe, dass PartitionCount immer ein vielfaches von 4 sein soll.


Mit deinem Code funktioniert es jetzt auch bei mir.
Ich habe mir mal noch eine Festplatte eingebaut. Wenn ich auf der 3 Partitionen erzeugen werden diese auch gefunden.
Wenn ich jetzt eine 4. Partition anlege, so wird die als Logische Partition in einer erweiterten Partition angelegt, weil das bei MBR nicht anders geht.
Dann jedoch liefert DeviceIoControl False zurück und kann das PhysicalDrive gar nicht mehr abfrage. Gibt es dafür eine Erklärung?

[Zacherl]

1. Ja das wäre auch so gegangen. Zusätzlich zum eigentlichen Struct nochtmal TStructName zu definieren habe ich lediglich gemacht, um der Delphi Namenskonvention gerecht zu werden. Ist aber prinzipiell nicht notwendig.
2. ReallocMem wird aufgerufen, wenn die API signalisiert, dass der übergebene Speicherbereich zu klein ist, um alle Informationen zu empfangen. Initial setze ich die Größe auf SizeOf(TDriveLayoutInformationEx) + SizeOf(TPartitionInformationEx) * 3. Dieser Speicher würde für 4 Partitionen ausreichen. Hat die Platte aber mehr Partitionen, muss der Speicherbereich solange vergrößert werden, bis alle Informationen reinpassen würden.
3. SizeOf(TDriveLayoutInformationEx) + SizeOf(TPartitionInformationEx) * 3 nehme ich deshalb als initialen Startwert, da hiermit genau Platz für 4 Partitionen zur Verfügung gestellt wird. DRIVE_LAYOUT_INFORMATION_EX enthält ja am Ende das array[0..0] of TPartitionInformationEx, weshalb in SizeOf(TDriveLayoutInformationEx) schon Platz für eine Partition eingeschlossen ist. SizeOf(TPartitionInformationEx) * 3 addiere ich dann noch, um auf die geforderten 4 Partitionen zu kommen.

Zum letzten Problem kann ich leider nichts sagen. Was sagt denn RaiseLastOSError() in diesem Falle?

[Captnemo]

EOSError: "Systemfehler. Code: 5. Zugriff verweigert"

Komisch, denn mit 3 Partition ist's kein Problem. Möglicherweise hängt es damit zusammen, dass die 4 Partition als Logische Partition in einer erweiterten Partition liegt. Aber warum das einen "Zugriff verweigert" nach sich zieht, erklärt sich mir nicht.