Abbrevia Unzipper extract from Stream to Stream - Gelöst

[Perlsau]

Moin allerseits,

von meinem Webspace (1&1) lade ich mir die Log-Dateien herunter, um sie zu analysieren. Ältere Log-Dateien liegen als Gzip-Files vor, was man ja locker mit Abbrevia entpacken kann. Zwar ist es mir gelungen, die Dateien auf Platte zu speichern und dann mit Abbrevia Unzipper wieder zu laden und in einen Stream zur Weiterverarbeitung zu entpacken. Den Umweg über die Dateien möchte ich aber gerne vermeiden, da die Dateien nach dem Download ja bereits als Stream vorliegen:

Delphi-Quellcode:

...
Try
  IndyFTP.Connect;
  IndyFTP.ChangeDir(OrdnerAktuell);
  Strm.Clear;
  IndyFTP.Get(Liste[i],Strm,True);
  IndyFTP.Disconnect;
  If Strm.Size > 0 Then
  Begin
  If Check_Datei.Checked Then
     Strm.SaveToFile(Ziel);
  If Not ExtractLogFile(Liste[i],Strm) Then
     ShowMessage(GLD.Fehlertext) Else
  Begin
  ...

Nun habe ich Probleme damit, den ursprünglichen Stream zu entpacken, ohne zuvor auf die gespeicherten Dateien zurückzugreifen:

Delphi-Quellcode:

Function TFormDown.ExtractLogFile(Const FileName : String; Const Stream : TMemoryStream) : Boolean;
Var
  UnZip : TAbUnZipper;
  S     : TStream;
begin
  Result := False;
  If Stream.Size = 0 Then
     GLD.Fehlertext := 'Fehler beim Entpacken der Log-Datei: "' + FileName + '": Stream ist leer!'
  Else
  Begin
    UnZip             := TAbUnZipper.Create(Self);
    S                 := TMemoryStream.Create;
    Unzip.ArchiveType := atGzip;
    Try
      Stream.Position := 0;
      If S.CopyFrom(Stream,Stream.Size) > 0 Then // übergebener Stream wird temporär in S gespeichert
      Begin
        Stream.Clear; // übergebener Stream wird geleert
        S.Position := 0;
        Try
          Unzip.Stream := S; // hier entsteht die Zugriffsverletzung
          Unzip.ExtractToStream(FileName,Stream);
          Result := True;
        Except
          On E:Exception Do
             GLD.Fehlertext := 'Fehler beim Entpacken des Streams "' + FileName + '": ' + e.Message;
        End;
      End Else
        GLD.Fehlertext := 'Fehler beim Koperen des Streams "' + FileName + '": Stream ist leer!';
    Finally
      S.Free;
      Unzip.Free;
    End;
  End;
end;

Beim Versuch, dem dem Unzipper-Objekt über sein Property Stream den übergebenen Stream zuzuweisen, erhalte ich eine Zugriffsverletzung:
Im Projekt PchWebLogDB.exe ist eine Exception der Klasse EAbPartSizedInflate mit der Meldung '' aufgetreten.

Klicke ich dann auf Fortsetzen, kommt diese Fehlermeldung:
Im Projekt PchWebLogDB.exe ist eine Exception der Klasse EAccessViolation mit der Meldung 'Zugriffsverletzung bei Adresse 00404370 in Modul 'PchWebLogDB.exe'. Lesen von Adresse FFFFFFD0' aufgetreten.

Der nächste Fehler nach Klick auf Fortsetzen lautet:
Im Projekt PchWebLogDB.exe ist eine Exception der Klasse EAccessViolation mit der Meldung 'Zugriffsverletzung bei Adresse 004040F8 in Modul 'PchWebLogDB.exe'. Lesen von Adresse FFFFFFFC' aufgetreten.

Danach breche ich mit Strg-F2 ab.

Auch dieser Versuch scheiterte: Unzip.Stream.CopyFrom(S,S.Size); löst Schutzverletzungen aus:
Im Projekt PchWebLogDB.exe ist eine Exception der Klasse EAccessViolation mit der Meldung 'Zugriffsverletzung bei Adresse 0042B437 in Modul 'PchWebLogDB.exe'. Lesen von Adresse 00000000' aufgetreten.

Ebenso der Versuch, den Stream der Unzipper.Komponente erst zu erzeugen, was logisch ist, denn im Abbrecia-Quellcode (unit AbZBrows) steht im Setter:

Delphi-Quellcode:

procedure TAbCustomZipBrowser.SetStream(aValue: TStream);
...
    atGZip, atGZippedTar : begin
      FArchive := TAbGzipArchive.CreateFromStream(aValue, '');
      TAbGzipArchive(FArchive).TarAutoHandle := FTarAutoHandle;
      TAbGzipArchive(FArchive).IsGzippedTar := (ArcType = atGZippedTar);
    end;
...

Was mache ich falsch?

Nachtrag:

Diverse Probleme haben es in sich, mir den Schlaf zu rauben. Also hab ich im Netz weiter recherchiert und bin auf diese SourceForge-Seite gestoßen. Dort beschrieb ein User dasselbe Problem, wobei sich herausstellte, daß es sich um einen Bug handelte, der inzwischen angeblich behoben wurde: Thanks for the bug report. I've fixed this in Subversion. Danach hab ich mir die Version 5.2 heruntergeladen und meine v5.0 damit ersetzt. Doch tritt noch immer exakt derselbe Fehler auf.

Nachtrag 2:

Na endlich! Das Problem ist gelöst

Offenbar ist es notwendig, das Property ForceType der Unzipper-Komponente auf True zu setzen, wenn man einen speziellen Archivtyp angibt. Zumindest nehme ich das an; da ich in meiner Abbrevia-Dokumentation (PDF-Datei) den Begriff nicht finden konnte, bin ich nicht wirklich sicher, was ForceType tatsächlich bewirkt. Nun funktioniert das Entpacken von Stream to Stream auf jeden Fall fehlerfrei und ich kann das Projekt fortsetzen (nachdem ich ein wenig an der Matraze gehorcht habe).

Auch wenn jetzt keiner an diesem Problem teilhatte ... vielleicht hilft es ja dem einen oder anderen, der auf dasselbe Problem stößt.

[Daniel]

Danke, dass Du Dir die Zeit genommen hast, die Lösung hier auch gleich zu schildern.

[Perlsau]

Das ist für mich selbstverständlich, habe ich doch selbst des öfteren User kritisiert, die genau das nicht tun, sondern sich mit einem lapidaren "ist gelöst" verabschieden und auf Anfragen, wie denn nun die Lösung aussieht, nicht mehr antworten.

Falls deine Antwort ironisch gemeint war, weil ich den korrigierten Code heute morgen nicht mehr gepostet hatte (ich hatte einen dringenden Termin mit meinem Bett), hole ich das jetzt sofort gerne nach:

Delphi-Quellcode:

Function TFormDown.ExtractLogFile(Const FileName : String; Const Stream : TMemoryStream) : Boolean;
Var
  UnZip : TAbUnZipper;
  S     : TStream;
begin
  Result := False;
  If Stream.Size = 0 Then
     GLD.Fehlertext := 'Fehler beim Entpacken der Log-Datei: "' + FileName + '": Stream ist leer!'
  Else
  Begin
    UnZip             := TAbUnZipper.Create(Self);
    S                 := TMemoryStream.Create;
    Unzip.ForceType   := True; // Diese Zeile hat das Problem gelöst
    Unzip.ArchiveType := atGzip;
    Try
      Stream.Position := 0;
      If S.CopyFrom(Stream,Stream.Size) > 0 Then
      Begin
        Stream.Clear;
        S.Position := 0;
        Try
          Unzip.Stream := S;
          Unzip.ExtractToStream(Unzip.Items[0].FileName,Stream);
          Result := True;
        Except
          On E:Exception Do
             GLD.Fehlertext := 'Fehler beim Entpacken des Streams "' + FileName + '": ' + e.Message;
        End;
      End Else
        GLD.Fehlertext := 'Fehler beim Koperen des Streams "' + FileName + '": Stream ist leer!';
    Finally
      S.Free;
      Unzip.Free;
    End;
  End;
end;

Man könnte hier auch die Funktion den Stream zurückliefern lassen, aber ich wollte unbedingt eine Meldung darüber, ob die Methode erfolgreich war.

Das war's jetzt von meiner Seite ...