Stringtyp, der meine Vorraussetzungen erfüllt

[Cubysoft]

Hallo,

in meinem Programm speichere ich Daten mit einem Filestream ab. Mein Konstrukt (muss) 2 dynamische Strings enthalten, allerdings möchte ich bei einem nun den Speicherverbrauch auf der Platte senken.

Der erste String ist ein String vom Type "String" (XE8), müsste also ein Unicodestring sein, wenn ich mich nicht täusche. Dies soll so sein, weil es den Namen des Datensatzes wiederspiegelt. Abspeichern tue ich diesen wie folgt:

Delphi-Quellcode:

name := data[i].name;
      str_size := Length(name);
      f.Write(str_size, SizeOf(str_size));
      f.Write(name[1],str_size*sizeof(char));
//Mit name: String; str_size: Integer;

Für den 2. String (data[i].sync), brauche ich im Grunde nur einen Zeichensatz, der die Zahlen 0-9 und das Zeichen ";" beinhaltet. Das es einen so komischen Stringtyp sicherlich nicht gibt, suche ich nach dem minimalsten. Ich meine mich dunkel zu erinnern, dass es in Delphi damals einen Stringtyp gab, bei dem die Chars nur 1Byte groß waren (statt wie hier 4).

Ich wäre euch unglaublich dankbar, wenn ihr mir den Typ nennen könnt und das zugehörige "Char", damit ich das schnell umsetzen kann. Im Internet finde ich nur AnsiStrings, aber ich weiß nicht, ob das das ist, was ich suche..


Vielen Dank!

[frankyboy1974]

hallo,

also 1 Byte für einen shortstring wird knapp, aber wenn du 2 Byte übrig hättest?? Auch beim Unicode wird ein zeichen maximal mit 2 bis 3 Byte repräsentiert.

Zitat:

brauche ich im Grunde nur einen Zeichensatz, der die Zahlen 0-9 und das Zeichen ";" beinhaltet.Das es einen so komischen Stringtyp sicherlich nicht gibt, suche ich nach dem minimalsten.

Wenn es einen solchen komischen Datentyp nicht gibt, warum programmierst du diesen den nicht selbst?


mfg

[Cubysoft]

Das wäre für den Anwendungsfall dann wohl doch etwas zu viel Aufwand. Dann belasse ich es eben doch bei dem Unicodestring


Trotzdem Danke!

[Der schöne Günther]

Wenn es dir nur um den Plattenplatz geht dann brauchst du doch keinen speziellen Stringtypen, du speicherst doch im Endeffekt nur Bytes. Kennst du TEncoding ? Damit kannst du doch einfach einen String sparsam als ASCII-Bytes kodieren.

Beispiel:

Delphi-Quellcode:

uses System.SysUtils, System.Classes;

function writeStringThings(): TStream;
var
   data: TBytes;
begin
   Result := TMemoryStream.Create();
   try
      data := TEncoding.Unicode.GetBytes('Name des Datensatzes');
      Result.WriteData( Length(data) );
      Result.Write(data, Length(data));

      data := TEncoding.ASCII.GetBytes('12345;67890');
      Result.WriteData( Length(data) );
      Result.Write(data, Length(data));
   except
      Result.Destroy(); raise;
   end;
end;

procedure readStringThings(const fromStream: TStream);
var
   content: String;
   buffer: TBytes;
   dataLength: Integer;
begin
   fromStream.Seek(0, TSeekOrigin.soBeginning);

   // Datensatz Name
   fromStream.Read(dataLength, Integer.Size);
   SetLength(buffer, dataLength);
   fromStream.Read(buffer, dataLength);
   content := TEncoding.Unicode.GetString(buffer);
   WriteLn( content.QuotedString() );

   // Sparsamer String
   fromStream.Read(dataLength, Integer.Size);
   SetLength(buffer, dataLength);
   fromStream.Read(buffer, dataLength);
   content := TEncoding.ASCII.GetString(buffer);
   WriteLn( content.QuotedString() );
end;

var
   stream: TStream;
begin
  try
   stream := writeStringThings();
   try
      readStringThings(stream);
    finally
        stream.Destroy();
    end;
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
  writeln('end.'); readln;
end.

Du siehst ja wieviel da gedoppelt ist, ich würde TStream per Helfer-Klasse eine Überladung für die Write-Methode verpassen die einen String und das Encoding entgegennimmt.

PS: Es gibt noch TStringStream, aber mit dem habe ich noch nie etwas gemacht. Wahrscheinlich wird der fix immer das gleiche Encoding haben.

[Cubysoft]

Hallo,

danke, das sieht nach einer sehr guten Lösung aus! Werde das gleich genauso umsetzen! Vielen Dank!

[Sir Rufo]

Oder man nimmt TBinaryWriter/TBinaryReader und verpasst denen noch die fehlenden Methoden.

[nahpets]

Gibts den ShortString nicht mehr?

Zitat von http://www.delphibasics.co.uk/RTL.asp?Name=ShortString":

Description
The ShortString type holds sequences of characters up to 255 in length.

Strings can be assigned from other strings, from functions that return a string, and with concatenations as in the sample code.

[stahli]

Doch gibt es noch.
Hatten wir hier schon mal: http://www.delphipraxis.net/185886-m...inimieren.html (insbesondere unter #13)

[idefix2]

Ansistring gibt auch in den Unicode-Versionen von Delphi. Brauchen nur ein Byte pro Zeichen plus den Zeiger.