E2232 Interface 'x' besitzt keine Interface-Identifikation?

[Whookie]

Hänge gerade an einem Interface - Problem und verstehe nicht wieso ich den E2232 Fehler (oder im Alternativfall kein Interface bekomme)!

Folgendes leeres Delphi VCL Projekt (leere Form):

Delphi-Quellcode:

unit Unit2;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs;

type
  TForm2 = class(TForm)
    procedure FormCreate(Sender: TObject);
  private
    { Private-Deklarationen }
  public
    { Public-Deklarationen }
  end;

var
  Form2: TForm2;

implementation

{$R *.dfm}


Const
  MyIntfAGuid: TGuid = '{23D5751F-8368-4672-ACFC-3BF667F1F544}';

Type
  IMyIntfA = Interface
    [MyIntfAGuid]
    procedure foo;
  End;


  TMyClass = Class(TInterfacedObject, IMyIntfA)
    procedure foo;
  End;



{ TMyClass }

procedure TMyClass.foo;
begin
end;

procedure TForm2.FormCreate(Sender: TObject);
var
  LMy: TMyClass;
  LIMyA: IMyIntfA;
  x: Integer;
begin
  LMy := TMyClass.Create;

  // so gibts E2232
  if Supports(LMy, IMyIntfA) then
  begin
    x := 3;
  end;

  // so gibts kein Interface
  if LMy.QueryInterface(MyIntfAGuid, LIMyA) = S_OK then
  begin
    x := 3;
  end;


  LMy.Free;
end;

end.

Irgendwas mache ich offensichtlich falsch....?

[stahli]

Ob´s das ist, weiß ich nicht, aber ich kenne die Deklaration so:

Delphi-Quellcode:

Const
   MyIntfAGuid = '{23D5751F-8368-4672-ACFC-3BF667F1F544}';

[Whookie]

Zitat von stahli:

Ob´s das ist, weiß ich nicht, aber ich kenne die Deklaration so:

Delphi-Quellcode:

Const
   MyIntfAGuid = '{23D5751F-8368-4672-ACFC-3BF667F1F544}';

Hatte ich auch schon probiert aber dann mäkelt der Compiler bei:

if LMy.QueryInterface(MyIntfAGuid, LIMyA) = S_OK then mit E2010 Inkompatible Typen: 'TGUID' und 'string' rum

[Bambini]

Zitat von Whookie:

Irgendwas mache ich offensichtlich falsch....?

Vermutlich kannst du die GUID für das Interface nur so angeben:

Delphi-Quellcode:

  IMyIntfA = Interface
    ['{23D5751F-8368-4672-ACFC-3BF667F1F544}']
    procedure foo;
  End;

[Union]

Nein, Du brauchst 2:

Delphi-Quellcode:

const

  MyStringIntfAGuid = '{23D5751F-8368-4672-ACFC-3BF667F1F544}';
  MyGuidIntfAGuid : TGUID = MyStringIntfAGuid;

Type
  IMyIntfA = Interface(IUnknown)
    [MyStringIntfAGuid]  // Hier den Stringtyp verwenden, wird vom Compiler umgewandelt in Recordtypen
    procedure foo;
  End;
  ...
  // so gibts ein Interface
  if LMy.QueryInterface(MyGuidIntfAGuid, LIMyA) = S_OK then

Und das Free unterläßt Du besser

[jaenicke]

Warum eigentlich so kompliziert? Warum nicht einfach so:

Delphi-Quellcode:

type
  IMyIntfA = Interface(IUnknown)
  ['{23D5751F-8368-4672-ACFC-3BF667F1F544}']
    procedure foo;
  end;

  // so gibts ein Interface
  if LMy.QueryInterface(IMyIntfA, LIMyA) = S_OK then

// oder
  if Supports(LMy, IMyIntfA, LIMyA) then

[Whookie]

Danke, wieder was dazugelernt!