Suche "echte" Screenshot Funktion

[tofse]

Hallo,

ich verwende diese Funktion, um einen Screenshot zu erzeugen

Delphi-Quellcode:

procedure ScreenShot(Bild: TBitMap);
var
  c: TCanvas;
  r: TRect;
begin
  c := TCanvas.Create;
  c.Handle := GetWindowDC(GetDesktopWindow);
  try
    r := Rect(0, 0, Screen.Width, Screen.Height);
    Bild.Width := Screen.Width;
    Bild.Height := Screen.Height;
    Bild.Canvas.CopyRect(r, c, r);
  finally
    ReleaseDC(0, c.Handle);
    c.Free;
  end;
end;

Jetzt ist mir aufgefallen, dass dies kein "echter" Screenshot ist. Ich hänge zwei Beispiele an
Beim einen Screenshot habe ich die "Druck" Taste verwendet, um einen Screenshot zu erzeugen. Da ist dann alles dabei, was auch zu sehen ist.
Den anderen Screenshot habe ich mit dem Delphi Code erzeugt. Da fehlen die Fenster im Paint Programm, es ist also kein "echter" Screenshot

Hat da jemand einen Tipp/ eine Idee?

Danke
Christof

[Namenloser]

Hatte in einem Screenshot-Programm von mir folgenden Code erfolgreich im Einsatz:

Delphi-Quellcode:

var
  DesktopDC: HDC;

const
  CAPTUREBLT = $4000000;

procedure TakeScreenshot(Dest: TBitmap; const CaptureRect: TRect);
begin
  Dest.SetSize(CaptureRect.Right-CaptureRect.Left,
    CaptureRect.Bottom-CaptureRect.Top);
  BitBlt(Dest.Canvas.Handle,
    0, 0,
    Dest.Width, Dest.Height,
    DesktopDC,
    CaptureRect.Left, CaptureRect.Top,
    SRCCOPY or CAPTUREBLT);
end;

initialization
  DesktopDC := CreateDC('DISPLAY', nil, nil, nil);

finalization
  DeleteDC(DesktopDC)

[zagota]

Ich verwende folgendes:

Delphi-Quellcode:

procedure TRTLCommon.WriteScreenshot;
const
  CAPTUREBLT = $40000000;
var
  hdcScreen: HDC;
  hdcCompatible: HDC;
  bmp: TBitmap;
  hbmScreen: HBITMAP;
  DeskHeight,
    DeskWidth: Integer;
begin
  hdcScreen := CreateDC('DISPLAY', nil, nil, nil);
  hdcCompatible := CreateCompatibleDC(hdcScreen);
  try
    DeskHeight:= Screen.DesktopHeight;
    DeskWidth:= Screen.DesktopWidth;
    hbmScreen := CreateCompatibleBitmap(hdcScreen, DeskWidth, DeskHeight);
    try
      SelectObject(hdcCompatible, hbmScreen);
      bmp := TBitmap.Create;
      try
        bmp.Handle := hbmScreen;
        BitBlt(hdcCompatible, 0, 0, bmp.Width, bmp.Height, hdcScreen, 0, 0, SRCCOPY or CAPTUREBLT);
        bmp.Save....
      finally
        bmp.Free;
      end;
    finally
      DeleteObject(hbmScreen);
    end;
  finally
    DeleteDC(hdcScreen);
    DeleteDC(hdcCompatible);
  end;
end;

[Namenloser]

Interessant ist, dass wir unterschiedliche CAPTUREBLT-Konstanten haben. Allerdings ist es wohl meine, die falsch ist. Ist mir wahrscheinlich nicht aufgefallen, weil ich immer Aero aktiviert hatte, wo es meines Wissens nach keinen Unterschied macht.

[tofse]

Danke

[Insider2004]

GetFormImage ?

[Bernhard Geyer]

Zitat von Insider2004:

GetFormImage ?

Und wie bekommt man damit alle Formulare des Desktops?

[Helmi]

Hallo,

ich hatte vor ein paar Wochen ein ähnliches Problem