Progressbar färben?

[AlexII]

Hallo,

ich möchte die ProgressBar (oder ähnliche Komponente) wie im Screenshot färben. Wie macht man das? Von rot bis grün.

Danke!

[DeddyH]

Die Standard-Progressbar wird von Windows gezeichnet, da würde ich nicht einschreiten wollen. Aber Du kannst Dir doch selbst was von TGraphicControl oder TCustomControl ableiten, da kannst Du dann nach Herzenslust drauf herummalen.

[AlexII]

Ok... und wenn ich ein TPanel nehme, wie kann ich das färben?

[Redeemer]

Der Farbverlauf ist einfach. Progressbar nehmen, Panel drüber, TImage vom Farbverkauf mit alClient ins Panel, Panel nach Fortschritt skalieren.

Was nicht klappt, ist Text über der Progressbar. TProgressBar erbt von TWinControl, TLabel aber von TGraphicControl, sprich TWinControl ist immer oben. Die TWinControl-Labels TStaticText und TLinkLabel sowie das immer gern zur Hilfe genommene TPanel haben keine Transparenz-Eigenschaft, zumindest keine die funktioniert.

Also: Erstelle eine TProgressBar auf TForm, kopier dir den Inhalt von TForm.Canvas an der Stelle in ein TImage. Auf das Bild dann ein TImage mit dem Farbverlauf und ein zentriertes TLabel und fertig ist es.

[AlexII]

Zitat von Redeemer:

Also: Erstelle eine TProgressBar auf TForm, kopier dir den Inhalt von TForm.Canvas an der Stelle in ein TImage. Auf das Bild dann ein TImage mit dem Farbverlauf und ein zentriertes TLabel und fertig ist es.

Ach du meine Güte... was heißt "kopier dir den Inhalt von TForm.Canvas an der Stelle in ein TImage"?

[DeddyH]

Mal eine ganz simple Komponente ohne irgendwelche Panels oder Images:

Delphi-Quellcode:

type
  TMyProgress = class(TGraphicControl)
  private
    FBitmap: TBitmap;
    FPosition: integer;
    procedure SetPosition(const Value: integer);
  protected
    procedure Paint; override;
  public
    procedure SetBounds(ALeft, ATop, AWidth, AHeight: integer); override;
    constructor Create(AOwner: TComponent); override;
    destructor Destroy; override;
    property Position: integer read FPosition write SetPosition;
  end;

...

//Code von delphi.about.com kopiert und leicht angepasst, ist ja nur ein Beispiel
procedure GradHorizontal(Canvas: TCanvas; Rect: TRect;
  FromColor, ToColor: TColor);
var
  X: integer;
  dr, dg, db: Extended;
  C1, C2: TColor;
  r1, r2, g1, g2, b1, b2: Byte;
  R, G, B: Byte;
  cnt: integer;
begin
  C1 := FromColor;
  r1 := GetRValue(C1);
  g1 := GetGValue(C1);
  b1 := GetBValue(C1);
  C2 := ToColor;
  r2 := GetRValue(C2);
  g2 := GetGValue(C2);
  b2 := GetBValue(C2);
  dr := (r2 - r1) / Rect.Right - Rect.Left;
  dg := (g2 - g1) / Rect.Right - Rect.Left;
  db := (b2 - b1) / Rect.Right - Rect.Left;
  cnt := 0;
  for X := Rect.Left to Rect.Right - 1 do
    begin
      R := r1 + round(dr * cnt);
      G := g1 + round(dg * cnt);
      B := b1 + round(db * cnt);
      Canvas.Pen.Color := RGB(R, G, B);
      Canvas.MoveTo(X, Rect.Top);
      Canvas.LineTo(X, Rect.Bottom);
      inc(cnt);
    end;
end;

constructor TMyProgress.Create(AOwner: TComponent);
begin
  inherited;
  FBitmap := TBitmap.Create;
  Width := 200;
  Height := 20;
end;

destructor TMyProgress.Destroy;
begin
  FBitmap.Free;
  inherited;
end;

procedure TMyProgress.Paint;
var
  AWidth: integer;
begin
  inherited;
  AWidth := MulDiv(FPosition, Width, 100);
  Canvas.CopyRect(Rect(0, 0, AWidth, Height), FBitmap.Canvas,
    Rect(0, 0, AWidth, Height));
end;

procedure TMyProgress.SetBounds(ALeft, ATop, AWidth, AHeight: integer);
begin
  inherited;
  FBitmap.Width := AWidth;
  FBitmap.Height := AHeight;
  GradHorizontal(FBitmap.Canvas, Rect(0, 0, FBitmap.Width, FBitmap.Height),
    RGB(255, 50, 50), RGB(50, 255, 50));
  Invalidate;
end;

procedure TMyProgress.SetPosition(const Value: integer);
begin
  FPosition := Value;
  Invalidate;
end;

Im Gegensatz zum Original gibt Position hier den Fortschritt in % an, aber das lässt sich ja umschreiben.

[hathor]

Hier ist eine schöne Komponente:
http://mapage.noos.fr/qnno/pages/delphi_en.htm

http://mapage.noos.fr/qnno/files/TQProgressBar.zip

[jaenicke]

Nebenbei sehen die Design Guidelines vor die Progressbar nur zu färben um einen bestimmten Zustand anzuzeigen. Das halte ich auch für sehr viel sinnvoller...
Kurzgefasst:
- Der Vorgang ist pausiert (z.B. für eine Rückfrage): gelb
- Es ist ein Problem aufgetreten, eine Benutzereingabe ist erforderlich: rot

[AlexII]

Wow... danke euch!!!