XE7: Mobile App und TStringGrid

[Sir Rufo]

Zitat von Kralle:

Hallo,

Zitat von himitsu:

Hast du auch genügend Zeilen erstellt?

Ja. Lösung siehe oben.

Gruß Heiko

Also bei mir funktioniert

Delphi-Quellcode:

StringGrid1.RowCount := 20;
StringGrid1.Cells[2,2] := 'Test';

ganz hervorragend ... so wie erwartet.

[Kralle]

Guten Abend Sir Rufo;

Zitat von Sir Rufo:

Also bei mir funktioniert

Delphi-Quellcode:

StringGrid1.RowCount := 20;
StringGrid1.Cells[2,2] := 'Test';

ganz hervorragend ... so wie erwartet.

Und bei mir wie erwartet nicht auf Anhieb und nur mit einem Refresh.
Aber, langsam gewöhne ich mich daran das bei mir egal in welcher Version auf welchem OS nichts so funktioniert wie es bei allen anderen funktioniert

Gruß HEiko

[himitsu]

Hatte ich dann auch schon gesehn

Ich will ja nicht sagen diese Komponente ist Schrott, aber
http://www.delphipraxis.net/181829-l...bjectlist.html


Hab mal nachgesehn:
* Im Gegensatz zum VCL-StringGrid erweitert das FMX-StringGrid die Zeilen von selber, wenn man auf Nichtexistierende zugreift.
* Es wird nur der Text in FCells: array of string; (TStringColumn) eingetragen, und kein Refresh ausgelöst ... das mußt du halt selber machen. (oder warten, bis das irgendwann von "alleine" passiert)

[Sir Rufo]

Wenn ich den RowCount nicht setze, dann habe ich das gleiche Verhalten, wie du es hier beschreibst.

Ach ja, völlig korrekt (so wie man es machen sollte) ist das hier

Delphi-Quellcode:

  StringGrid1.BeginUpdate;
  try
    StringGrid1.RowCount := 20;
    StringGrid1.Cells[2, 2] := 'Test';
  finally
    StringGrid1.EndUpdate;
  end;

Ok, klappt auch nur beim ersten Mal, weil sich der RowCount von 100 auf 20 ändert. Ein Eintragen von Werten löst einfach nicht den benötigten Refresh aus

[Sir Rufo]

Ok, zur generellen Abhilfe hier ein netter Helper

Delphi-Quellcode:

unit FMX.Helper.Controls;

interface

uses
  FMX.Controls;

type
  IControlUpdater = interface
    ['{D90FA99C-F9EC-4A55-9E99-95A54D1E30F8}']
  end;

  TControlUpdater = class( TInterfacedObject, IControlUpdater )
  private
    FControl: TControl;
    constructor Create( AControl: TControl );
  public
    destructor Destroy; override;
  end;

  TControlHelper = class helper for TControl
    function BeginAutoUpdate: IControlUpdater;
  end;

implementation

uses
  System.SysUtils;

{ TControlUpdater }

constructor TControlUpdater.Create( AControl: TControl );
begin
  inherited Create;
  FControl := AControl;
  // BeginUpdate
  FControl.BeginUpdate;
end;

destructor TControlUpdater.Destroy;
begin
  // EndUpdate
  FControl.EndUpdate;
  // Refresh auf dem sichtbaren Bereich anmelden
  // das ist schonender als ein hartes Repaint
  FControl.InvalidateRect( FControl.ClipRect );
  inherited;
end;

{ TControlHelper }

function TControlHelper.BeginAutoUpdate: IControlUpdater;
begin
  Result := TControlUpdater.Create( Self );
end;

end.

Und so verwenden (geht jetzt bei jedem Control)

Delphi-Quellcode:

uses
  FMX.Helpers.Controls;

procedure TSomeForm.SomeMethod;
begin
  StringGrid1.BeginAutoUpdate;

  StringGrid1.Cells[2,2] := 'Test';
end;

Sobald die Methode verlassen wird, wird auch das erzeugte Interface IControlUpdater wieder freigegeben (RefCount geht auf 0)