Daten abholen von einem CakePHP Server

[MartinK]

Ich würde gerne folgendes mit Indy realsieren, stehe aber auf dem Schlauch und bräuchte hierzu Denkanstöße

- Ein CakePHP Server soll eine (json) Antwort liefern
- Übergeben werden muss dem Server ein Json-String der angibt welche Funktion ausgeführt werdenmuss, und vor allem auch
- ein String für die Authorisierung als Kompbination von Username + ':' + Passwort in Base64Encoded
(ich weiß wie das Encodieren geht)

Delphi-Quellcode:

Function Encode64(const S: string; const ByteEncoding: IIdTextEncoding = nil): string;
begin
  Result := TIdEncoderMIME.EncodeString(S, ByteEncoding);
end;
....
UsernamePW_base64 := Encode64(aUsername + ':' + aPassword, IndyTextEncoding_UTF8);

dieser Spaß muss dann in ein HTTPHeaderField namens „Authorization“ geschrieben werden.
Dieses Feld soll den Text "Basic " + den base63Encoded String bekommen
Und ich denke genau hier habe ich meinen Hänger denn ich bekomme trotz korrekter Daten immer einen Error 401 / Incorrect Authorisation)
vermutlich liegt es daran wie ich die Authorisation mache

Delphi-Quellcode:

Var
  data: TStringList;

begin
  data := TStringList.Create;
  data.Values['authorization'] := 'Basic '+ UsernamePW_base64;
  //
...
  Response := IdHttp.Post(aURL, data);
....
end;

Help Please!

LG Martin

[Valle]

Hi,

ich glaube du wirfst HTTP-Header und POST-Daten durcheinander.

Eine HTTP-Anfrage besteht immer (egal ob POST, GET, oder anderes) auch aus Headern. Einer davon ist der Authorization-Header in dem von dir beschriebenen Format.

Der Unterschied zwischen POST und GET besteht darin, dass POST nach diesen Headern noch weitere Daten überträgt. Die Länge dieser Daten in Zeichen wird übrigens auch als Header ("Content-Length") übermittelt.

Hier ein Beispiel wie es sein sollte (so sieht die HTTP-Anfrage dann tatsächlich aus, falls du das noch nicht kennst):

Code:

POST /my/path HTTP/1.0
Content-Type: application/x-www-form-urlencoded
Authorization: Basic base64string
Content-Length: 8

ex=ample

Mit Delphi habe ich nichts mehr zutun, aber du hast glaube ich folgendes gemacht:

Code:

POST /my/path HTTP/1.0
Content-Type: application/x-www-form-urlencoded
Content-Length: keinelustzuzählen

Authorization=Basic base64string

Du musst diese Daten also in den Header verfrachten. (Google meint, du suchst IdHttp.Request.CustomHeaders.AddValue) Außerdem wirst du für eine POST-Anfrage auch weitere Daten zum übertragen brauchen, aber ich vermute, diese hast du in deinem Codebeispiel weggelassen.

[MartinK]

Danke für Deinen Hinweis Valetin!

Ich habe durch etwas "rumprobieren" nun die Lösung einer erfolgreichen Anmeldung bei CakePHP mit INDY Bordmittel herausgefunden.
Wenn jemand anders das mal braucht -> voila

Delphi-Quellcode:

Var
  iDHTTP: TIdHttp;
  jsonData, Response: String;
  aUsername,aPassword : String;

begin

  aUsername := '[e-mail]';
  aPassword := 'FictivePW0123455678';

  IdHttp := TIdHttp.Create(nil);

  iDHTTP.Request.BasicAuthentication := True;
  iDHTTP.Request.Authentication := TIdBasicAuthentication.Create;
  iDHTTP.Request.Authentication.Username := aUsername;
  iDHTTP.Request.Authentication.Password := aPassword;
  IdHTTP.Request.ContentType  := 'application/json';
  jsonData := 'http://myhomepage.de/somecommand/changed.json?date=1970-01-01 00:00:00';
  Response := IdHttp.Get(jsonData);

  IdHTTP.Free;    
end;

LG Martin

[mjustin]

Kleine Verbesserungsmöglichkeiten:

* iDHTTP.Request.Authentication := TIdBasicAuthentication.Create;

Diese Zeile ist nicht notwendig

* try ... finally

Da die Methode eventuell (je nach Tagesform des Servers oder der Internetverbindung) mit einer Exception abbricht, sollte das Free über einen finally Block abgesichert werden.

* TidHTTP.Create anstatt TidHTTP.Create(nil)

Das (nil) kann weggelassen werden. Das spart fünf Tastenanschläge ein und ist funktionell gleichwertig.

[MartinK]

Danke nochmal, Michael!

-> iDHTTP.Request.Authentication := TIdBasicAuthentication.Create;
ist bei CakePHP bei mir notwendig, ansonsten gibt's eine EAccessViolation (000000000)

hier nochmal die finale version als "function"

LG Martin

Delphi-Quellcode:

Function Ask4aCloudResponse(aUsername, aPassword, aServerURL, aBody : String ):String;
Var
  iDHTTP: TIdHttp;
begin
  IdHttp := TIdHttp.Create;

  try
    iDHTTP.HandleRedirects := True;
    iDHTTP.Request.BasicAuthentication := True;
    iDHTTP.Request.Authentication := TIdBasicAuthentication.Create;
    iDHTTP.Request.Authentication.Username := aUsername;
    iDHTTP.Request.Authentication.Password := aPassword;
    IdHTTP.Request.ContentType  := 'application/json';
    Result   := IdHttp.Get(aServerURL + aBody);
  finally
    IdHTTP.Free;
  end;
end;

[Sir Rufo]

try bitte nach dem Create !

[MartinK]

Zwecks Vollständigekit halber hier ein weiteres CodeFragment, da ich denke das es evtl. weiteren Personen hilft die mal etwas ähnliches machen wollen

Ziel: Ein FileUpload auf den Server mittels eines sog "Multipart Form DataStreams". So etwas wird zB zum Uploaden von Bildern eingesetzt

lG Martin

Delphi-Quellcode:

Function  TForm1.ACloud_UploadPicture(_PictureID, _OriPictureFPathAndName:String) : String;
Var
  POSTData: TIdMultipartFormDataStream;
  JSON: ISuperObject;
begin
  Result := '';
  try
    //generate a so called Multipart Object with
    //- the picture File itself. it is loaded as Stream form the path specified
    //- identifiers  needed for the Cake server routines 'picture' , 'image/jpg'
    POSTData := TIdMultiPartFormDataStream.Create;
    POSTData .AddFile('picture', _OriPictureFPathAndName, 'image/jpg');

    IDHTTP.HandleRedirects := True;
    IDHTTP.Request.BasicAuthentication := false;
    IDHTTP.Request.Authentication := TIdBasicAuthentication.Create;
    IDHTTP.Request.Authentication.Username := aCloudLogin.Username;
    IDHTTP.Request.Authentication.Password := aCloudLogin.Password;
    //although we handle the Multipart message, servers answers are again JSON for easier interpretation
    IdHTTP.Request.ContentType  := 'application/json';

    aCloudURL  := URLEncode(aCloudServer + 'pictures/uplpic.json?PictureID=' + _PictureID+'.jpg');
    JSONResponse := IDHTTP.Post(aCloudURL, POSTData);
  except
    on E : Exception do
      Result := Result + 'Exception uploading an image to aCloud: "' + E.ClassName + '" "' + E.Message +'"';
  end;
  POSTData.Free;
  //---------------------------
  if Result <> '' then exit;
  //---------------------------
  //Now let's check if everythimng worked correctly. ...we interprte the Response returend from the Server
  //This is specific to your servers specifications and just an example on how it could be done
  JSON := SO();
  JSON := SO(JSONResponse);  // Interprete the response to the JSON Super-Object (SO)
  If (Uppercase(JSON.S['response'])   <> Uppercase('OK') ) OR
     (Uppercase(JSON.S['entityID'])   <> Uppercase(_PictureID+'.jpg')) OR
     (Uppercase(JSON.S['entityType']) <> Uppercase('picturedata') ) OR
     (Uppercase(JSON.S['type'])       <> Uppercase('u') )
     then Result := Result + 'Error responded updating an aCloud-picture: ' + JSONResponse;
end;