Bilddatei aus dem MySQL Blobdfeld laden geht nicht

[sammynrw]

Hallo Freunde,

ich versuche gerade aus einem Blobfeld ein Bild zu laden und einem Image anzuzeigen zu lassen.

Mein Code:

Delphi-Quellcode:

memStream := TMemoryStream.Create;
  memStream.LoadFromStream(MyQuery2.FieldByName('fahrzeugbild1').AsBytes);
  memStream.Position := 0;
Image56.Picture.Graphic := Memstream.Memory;

Ich bekomme aber die Fehlermeldung:
Inkompatible Typen: 'string' und 'System.TArray<System.Byte>'

Wie kann ich das aus dem Blobfeld anders laden ?

Ich hab mir schon viele Beispiele rausgesucht ... aber es funktioniert nicht

[arnof]

Zitat von sammynrw:

Hallo Freunde,

ich versuche gerade aus einem Blobfeld ein Bild zu laden und einem Image anzuzeigen zu lassen.

Mein Code:

Delphi-Quellcode:

memStream := TMemoryStream.Create;
  memStream.LoadFromStream(MyQuery2.FieldByName('fahrzeugbild1').AsBytes);
  memStream.Position := 0;
Image56.Picture.Graphic := Memstream.Memory;

Ich bekomme aber die Fehlermeldung:
Inkompatible Typen: 'string' und 'System.TArray<System.Byte>'

Wie kann ich das aus dem Blobfeld anders laden ?

Ich hab mir schon viele Beispiele rausgesucht ... aber es funktioniert nicht

nicht AsByte sondern Value mal versuchen (As… macht immer eine Typewandelung)

Ich meine hier im Forum gibt es dazu Beiträge: suche mal Ohne MYSQL, das ist ja überall gleich mit Delphi!

[sammynrw]

Zitat von arnof:

Zitat von sammynrw:

Hallo Freunde,

ich versuche gerade aus einem Blobfeld ein Bild zu laden und einem Image anzuzeigen zu lassen.

Mein Code:

Delphi-Quellcode:

memStream := TMemoryStream.Create;
  memStream.LoadFromStream(MyQuery2.FieldByName('fahrzeugbild1').AsBytes);
  memStream.Position := 0;
Image56.Picture.Graphic := Memstream.Memory;

Ich bekomme aber die Fehlermeldung:
Inkompatible Typen: 'string' und 'System.TArray<System.Byte>'

Wie kann ich das aus dem Blobfeld anders laden ?

Ich hab mir schon viele Beispiele rausgesucht ... aber es funktioniert nicht

nicht AsByte sondern Value mal versuchen (As… macht immer eine Typewandelung)

Ich meine hier im Forum gibt es dazu Beiträge: suche mal Ohne MYSQL, das ist ja überall gleich mit Delphi!

Also mit Value bekomme ich dann folgende Fehlermeldung:
Inkompatible Typen: 'TStream' und 'System.TArray<System.Byte>'

[sammynrw]

Ich versuche gerade mit diesem Code:

Delphi-Quellcode:

memStream := TMemoryStream.Create;
Memstream.Memory := datamodule3.MyQuery1.FieldByName('fahrzeugbild1').AsBytes;
memStream.Position := 0;
Image56.Picture.Graphic.LoadFromStream(Memstream.Memory);

Hier bekomme ich folgenden Fehler:
E2129 Einer Nur-Lesen Eigenschaft kann kein Wert zugewiesen werden

Ich könnte Verrückt werden

[borstenei]

...warum verwendest Du nicht einfach eine entsprechende DBImage Komponente zur Anzeige. Ich benutze zum Zugriff auf eine MySQL Datenbank zum Anzeigen von Bildern DBAdvPicture von TMS..

[sammynrw]

Zitat von borstenei:

...warum verwendest Du nicht einfach eine entsprechende DBImage Komponente zur Anzeige. Ich benutze zum Zugriff auf eine MySQL Datenbank zum Anzeigen von Bildern DBAdvPicture von TMS..

Die DBImage zeigt mir nicht das Blobfeld an. Und wenn man die im Quellcode zuweist kommt eine Fehlermeldung.

[borstenei]

..stimmt , mit der DelphiDBImage - Komponente kommt auch bei mir ein Fehler...bmp Format ungültig.
Du könntest aber auch die JvDBImage aus den Jedi Komponenten nehmen die funktionieren bei mir auch und sind kostenlos ..

[Sir Rufo]

Also dieses Thema ist mehrfach hier und anderswo behandelt worden.

Und das das so nicht funktionieren kann, sieht man schon beim Blick in die Dokumentation (wird aber meistens überbewertet) allerdings auch die Namensgebung LoadFromStream sollte doch alle Glocken läuten lassen, dass das wohl nur mit einem Stream funktioniert.

[Perlsau]

Delphi-Quellcode:

// ----- Lädt eine Datei in ein Blob-Feld
Function TDatMod.DateiInBlobFeld(Feld: TField; Datei: String): Boolean;
Var
  S     : TStream;
  FileS : TFileStream;

begin
  Result := False;
  If Not FileExists(Datei) Then Exit;
  If Not Feld.IsBlob       Then Exit;
  If Not ((Feld.DataSet.State = dsInsert) Or
          (Feld.DataSet.State = dsEdit)) Then Exit;

  S := Feld.DataSet.CreateBlobStream(Feld, bmReadWrite);

  Try
    Try
      FileS  := TFileStream.Create(Datei, fmOpenRead);
      S.CopyFrom(FileS, FileS.Size);
      Result := True;
    Except
      on e:exception Do GL.FehlerMeldung := e.Message;
    End;
  Finally
    FileS.Free;
    S.Free;
  End;
end;

// ----- Speichert den Inhalt eines Blob-Feldes in einer Datei
Function TDatMod.BlobFeldInDatei(Feld: TField; Datei: String): Boolean;
Var
  S     : TStream;
  FileS : TFileStream;

begin
  Result := False;
  If Not Feld.IsBlob Then Exit;
  If Feld.IsNull     Then EXIT;

  S     := Feld.DataSet.CreateBlobStream(Feld, bmRead);
  FileS := TFileStream.Create(Datei, fmCreate);
  Try
    Try
      FileS.CopyFrom(S, S.Size);
      Result := FileExists(Datei);
    Except
      on e:exception Do
      Begin
        GL.FehlerMeldung := e.Message;
        Result := False;
      End;
    End;
  Finally
    S.Free;
    FileS.Free;
  End;
end;

// ----- Übergibt den Inhalt eines Streams an ein Blobfeld
Function TDatMod.StreamInBlobFeld(Strom: TMemoryStream; Feld: TField): Boolean;
Var
  S : TStream;

begin
  Result := False;
  If Not Feld.IsBlob Then Exit;
  If Not ((Feld.DataSet.State = dsInsert) Or
          (Feld.DataSet.State = dsEdit)) Then Exit;

  S := Feld.DataSet.CreateBlobStream(Feld, bmReadWrite);

  Try
    S.CopyFrom(Strom,Strom.Size);
    Result := True;
  Finally
    S.Free;
  End;
end;

// ----- Übergibt den Inhalt eines Blobfelds an Strom
Function TDatMod.BlobFeldInStream(Strom: TMemoryStream; Feld: TField): Boolean;
Var
   S : TStream;

begin
   Result := False;
   If Not Feld.IsBlob Then Exit;
   If Feld.IsNull     Then Exit;

   Try
     S := Feld.DataSet.CreateBlobStream(Feld, bmRead);
     Strom.Clear;
     Strom.CopyFrom(S,S.Size);
     Result := True;
   Finally
     S.Free;
   End;
end;

// ----- Übergibt den Inhalt eines Blobfelds an ein TBitMap
Function TDatMod.BlobFeldInImage(Feld: TField; Bild: TBitMap): Boolean;
Var
  S     : TStream;
  JBild : TJpegImage;

begin
  Result := False;
   If Not Feld.IsBlob Then Exit;
   If Feld.IsNull     Then Exit;

  JBild := TJPegImage.Create;
  S     := Feld.DataSet.CreateBlobStream(Feld, bmRead);

  Try
    JBild.LoadFromStream(S);
    Bild.Assign(JBild);
    Result := True;

  Finally
    If Not Result Then
       GL.FehlerMeldung := 'Fehler beim Speichern eines Blobfelds in ein Bitmap';
    S.Free;
    JBild.Free;
  End;
end;

// ----- Übergibt den Inhalt eines BitMaps an ein Blobfeld
Function TDatMod.ImageInBlobFeld(Feld: TField; Bild: TBitMap): Boolean;
Var
  S     : TStream;
  JBild : TJpegImage;

begin
  Result := False;
  If Not Feld.IsBlob Then Exit;
  If Not ((Feld.DataSet.State = dsInsert) Or
          (Feld.DataSet.State = dsEdit)) Then Exit;

  JBild := TJPegImage.Create;
  S     := Feld.DataSet.CreateBlobStream(Feld, bmWrite);

  Try
    JBild.Assign(Bild);
    JBild.CompressionQuality := 100;
    JBild.Compress;
    JBild.SaveToStream(S);
    S.Position := 0;
    Result := True;
  Finally
    If Not Result Then
       GL.FehlerMeldung := 'Fehler beim Speichern eines Bitmap in ein Blobfeld';
    S.Free;
    JBild.Free;
  End;
end;

Diese Methoden funktionieren bei mir mit allen gängigen Datenbanken: Firebird, MySQL, MsSQL, PostGreSQL ... wobei GL.Fehlermeldung eine ClassVar in meiner Tools-Klasse darstellt, was aber für die eigentliche Funktionalität der obigen Methoden keine wichtige Rolle spielt.

[sammynrw]

Zitat von borstenei:

..stimmt , mit der DelphiDBImage - Komponente kommt auch bei mir ein Fehler...bmp Format ungültig.
Du könntest aber auch die JvDBImage aus den Jedi Komponenten nehmen die funktionieren bei mir auch und sind kostenlos ..

jap .. dieser fehler wird angzeigt