Der Prozess kann nicht auf die Datei zugreifen, da sie von einem anderen Prozess ...

[Perlsau]

Genau deshalb starte ich meine Firebird-DB-Clients, die einerseits die Server-Variante, andererseits aber auch die Embedded-Variante bedienen sollen, mit Startparametern. Daraus ergibt sich dann, welche Client-DLL geladen wird:

Delphi-Quellcode:

Function TDatMod.VerbindenDatenbank : Boolean;
begin
  Result := False;

  If ConMain.Connected Then ConMain.Disconnect;

  Case GL.DB_Modus Of

  0 : Begin // Embedded
        ConMain.ClientLibrary := GL.Pfad_Main + GL.ClientEName;
        ConMain.Server := '';
        ConMain.Port   := '';
      End;

  1 : Begin // Server Lokal
        ConMain.ClientLibrary := GL.Pfad_Main + GL.ClientName;
        ConMain.Server := 'LocalHost';
        ConMain.Port   := '3050';
      End;

  2 : Begin // Server Remote
        ConMain.ClientLibrary := GL.Pfad_Main + GL.ClientName;
        ConMain.Server := 'MyDBServer';
        ConMain.Port   := '3050';
      End;
  End;

  ConMain.Database                := GL.DB_Pfad + GL.DB_Name;
  ConMain.AutoCommit              := True;
  ConMain.LoginPrompt             := False;
  ConMain.Options.Charset         := 'UTF8';
  ConMain.Options.DefaultSortType := stCaseInsensitive;
  ConMain.Options.UseUnicode      := True;
  ConMain.SQLDialect              := 3;

  Try
    ConMain.Connect;
    Result := True;
  Except
    On e:exception DO GL.FehlerMeldung := 'Fehler beim Verbinden mit Datenbank: ' + e.Message;
  End;
end;

wobei

Delphi-Quellcode:

UNIT GlobalVars;

INTERFACE


...
    PUBLIC  { Public-Deklarationen  }
      Const
        ClientName      = 'fbclient.dll';
        ClientEName     = 'fbclientE.dll';
...
      Class Var
...
        DB_Modus        : Byte;
...

Aufgerufen wird das Ganze dann beim Programmstart:

Delphi-Quellcode:

Procedure TFormMain.FormActivate(Sender: TObject);
begin
  ...

  If Not DatMod.VerbindenDatenbank Then
  Begin
    ShowMessage(GL.FehlerMeldung);
    Close;
    Exit;
  End;

  ...
end;

[pmoegenb]

Zitat von Perlsau:

Genau deshalb starte ich meine Firebird-DB-Clients, die einerseits die Server-Variante, andererseits aber auch die Embedded-Variante bedienen sollen, mit Startparametern.

Ich habe das über eine .ini-Datei gelöst mit nachfolgender Struktur, die im jeweiligen Programmverzeichnis liegt:

Delphi-Quellcode:

[Sicherheit]
Server=
Port=
LoginPrompt=False
Client=fbembed.dll
[Database]
RIS=D:\Delphi_Projekte\RIS_FB\RIS.FDB
RISH=D:\Delphi_Projekte\RIS_FB\RISH.FDB

Die .ini-Datei wird dann wie folgt ausgelesen:

Delphi-Quellcode:

     Ini := TIniFile.Create(HelpPfad+'\FB.INI');
     UniConnection1.Server   := Ini.ReadString('Sicherheit','Server', '');
     UniConnection1.Port     := Ini.ReadInteger('Sicherheit','Port', 0);
     UniConnection1.SpecificOptions.Values['ClientLibrary'] :=
     Ini.ReadString('Sicherheit','Client', 'fbembed.dll');
     UniConnection1.LoginPrompt := Ini.ReadBool('Sicherheit','LoginPrompt', False);
     UniConnection2.Server   := UniConnection1.Server;
     UniConnection2.Port := UniConnection1.Port;
     UniConnection2.SpecificOptions.Values['ClientLibrary'] :=
     UniConnection1.SpecificOptions.Values['ClientLibrary'];
     UniConnection2.LoginPrompt := UniConnection1.LoginPrompt;
     // Aktuelle Daten
     UniConnection1.Database :=
     Ini.ReadString('Database','RIS', 'RIS.FDB');
     // Historische Daten
     UniConnection2.Database :=
     Ini.ReadString('Database','RISH', 'RISH.FDB');

     // Existenz der Datenbanken prüfen
     if not FileExists(UniConnection1.Database) then
        begin
        Messagedlg('Datenbank '+UniConnection1.Database+
        ' nicht gefunden', mtError, [mbOK,mbHelp], 216);
        Application.Terminate;
        end;
     if not FileExists(UniConnection2.Database) then
        begin
        Messagedlg('Datenbank '+UniConnection2.Database+
        ' nicht gefunden', mtError, [mbOK, mbHelp], 216);
        Application.Terminate;
        end;

     try
     if not UniConnection1.Connected then UniConnection1.Open;
     except
     on Exception do
     begin
     Messagedlg('Verbindung zur aktuellen Datenbank fehlgeschlagen', mtError,
     [mbOK,mbHelp],25);
     Application.Terminate;
     end;
     end;

     try
     if not UniConnection2.Connected then UniConnection2.Open;
     except
     on Exception do
     begin
     Messagedlg('Verbindung zur historischen Datenbank fehlgeschlagen', mtError,
     [mbOK,mbHelp],25);
     Application.Terminate;
     end;
     end;
     Ini.Free;
     CFGIni.Free;