Hallo Zusammen.

Gegeben sei ein Thread der ein MyEvent := TEvent... handle hat.

zusammenfalten · markieren

Delphi-Quellcode:

Procedure TMyThread.Execute;
begin
  While not Terminated do
   begin
     MyEvent.WaitFor(infinite);
     if not(Terminated) then
       begin
         // Mach was schlaues...
       end;
   end;
end;

Destructor TMyThread.destroy;
begin
  Terminate;
  MyEvent.SetEvent;
  MyEvent.Free; // Gut oder schlecht???
  Inherited;
end;

Mavarik

markieren

Delphi-Quellcode:

if Mavarik.Erstellt(MyEvent).Im(Konstruktor) then
  result := Gut
else
  result := Not Gut;

Zitat von Dejan Vu:

markieren

Delphi-Quellcode:

if Mavarik.Erstellt(MyEvent).Im(Konstruktor) then
  result := Gut
else
  result := Not Gut;

LOL...

markieren

Delphi-Quellcode:

Constructor TMyThread.Create;
begin
  inherited Create(true);

  MyEvent := TEvent.Create(NIL,false,false,'');
  ....
end;

Const
  Mavarik = Gut;

Danke

PS.: Die eigentliche Frage war, wird bei MyEvent.SetEvent der Thread sofort gestartet oder kann es sein, dass die
MyEvent.WaitFor(Infinite); plötzlich keinen Rücksprung mehr hat.

Der Punkt ist folgender: Dein Thread läuft. Er ist zwar nicht sonderlich aktiv und wartet bis zum Tag des jüngsten Gerichts dass myEvent eintritt, aber er ist gestartet.

Wenn du ihn terminierst, läuft er weiter. Und weiter. Denn er wartet auf das Event.

Daher würde ich in deinem Thread noch die Methode TerminatedSet überschreiben: Diese sollte sich um das Setzen des Events kümmern, damit der Thread nicht ewig dort in seinem Execute darauf wartet, sollte es nie eingetreten sein.

Siehe auch hier: http://www.delphipraxis.net/1254537-post13.html

Zitat von Der schöne Günther:

Der Punkt ist folgender: Dein Thread läuft. Er ist zwar nicht sonderlich aktiv und wartet bis zum Tag des jüngsten Gerichts dass myEvent eintritt, aber er ist gestartet.

Wenn du ihn terminierst, läuft er weiter. Und weiter. Denn er wartet auf das Event.

emm... Nein...

Deswegen mache ich ja ein
   MyEvent.SetEvent;

Terminate gehört eigentlich nicht in den Destruktor, der ist rein zum Aufräumen da. Oder wenn es dort schon steht, sollte dann ein WaitFor auf den Thread folgen, in diesem Fall nach dem SetEvent. Danach kannst du ruhigen Gewissens alles freigeben.

Bei mir steht die Sequenz Terminate, WaitFor, Free außerhalb des Threads.

So ist es richtig und ausreichend:
(Ich habe mir erlaubt aus MyEvent ein FMyEvent um zu verdeutlichen, dass es sich um ein Feld der Klasse handelt)

zusammenfalten · markieren

Delphi-Quellcode:

procedure TMyThread.TerminatedSet;
begin
  inherited;
  FMyEvent.SetEvent; // auf jeden Fall auch NACH INHERITED!!!!
end;

Procedure TMyThread.Execute;
begin
  While not Terminated do
   begin
     FMyEvent.WaitFor(infinite);
     if not(Terminated) then
       begin
         // Mach was schlaues...
       end;
   end;
end;

Destructor TMyThread.destroy;
begin
  Inherited;
  FMyEvent.Free; // NACH INHERITED!!!!!!
end;

Wen man wissen möchte, warum das reicht, dann schaut man sich den Source von TThread.Destroy einfach mal an (so habe ich auch herausgefunden, warum das so ausreicht) und sieht dort folgende lustige Dinge:

zusammenfalten · markieren

Delphi-Quellcode:

destructor TThread.Destroy;
begin
  if (FThreadID <> 0) and not FFinished and not FExternalThread then
  begin
    Terminate;
    if FCreateSuspended or FSuspended then
      Resume;
{$IFDEF MSWINDOWS}
    while not FStarted do
{$ELSE}
    while not ((not FCreateSuspended or FInitialSuspendDone) and FStarted) do
{$ENDIF}
      Yield;
    WaitFor;
  end;
  ...
end;

Zitat von Sir Rufo:

So ist es richtig und ausreichend:
(Ich habe mir erlaubt aus MyEvent ein FMyEvent um zu verdeutlichen, dass es sich um ein Feld der Klasse handelt)

zusammenfalten · markieren

Delphi-Quellcode:

procedure TMyThread.TerminatedSet; // Erst ab XE? jedenfalls gibt es das nicht in D2007
begin
  inherited;
  FMyEvent.SetEvent;
end;

Procedure TMyThread.Execute;
begin
  While not Terminated do
   begin
     FMyEvent.WaitFor(infinite);
     if not(Terminated) then
       begin
         // Mach was schlaues...
       end;
   end;
end;

Destructor TMyThread.destroy;
begin
  Inherited;
  FMyEvent.Free; // NACH INHERITED!!!!!! Stimmt hab ich auch gefunden!
end;

s.o.

Zitat von jaenicke:

Terminate gehört eigentlich nicht in den Destruktor, der ist rein zum Aufräumen da. Oder wenn es dort schon steht, sollte dann ein WaitFor auf den Thread folgen, in diesem Fall nach dem SetEvent. Danach kannst du ruhigen Gewissens alles freigeben.

Bei mir steht die Sequenz Terminate, WaitFor, Free außerhalb des Threads.

Waitfor nicht nötig da im Thread Destructor schon vorhanden!

Zitat von Mavarik:

Waitfor nicht nötig da im Thread Destructor schon vorhanden!

Wenn man es denn in der Reihenfolge aufruft wie Sir Rufo geschrieben hat, funktioniert das auch, ja.