Zusammenhang TPicture und TGraphic

[Der schöne Günther]

Damit ich es endlich mal verstehe:

TPicture kann man als einen "Container" für ein TGraphic sehen. TGraphic ist eine abstrakte Basisklasse für TIcon , TMetaFile , TBitmap und viele weitere...

Alles richtig soweit?

Warum ergibt folgendes ein Speicherleck?

Delphi-Quellcode:

procedure TForm2.FormCreate(Sender: TObject);
var
   myPic: TPicture;
begin
   ReportMemoryLeaksOnShutdown := True;
   myPic := TPicture.Create();
   myPic.Graphic := TBitmap.Create();
   myPic.Free();
end;

Ich verstehe das nicht- Die .Graphic -Property setzt FGraphic meines TPicture auf das TBitmap -Objekt und im Destruktor wird es wieder freigegeben.

[Sir Rufo]

Die Zuweisung TPicture.Graphic := TBitmap.Create; veranlasst, dass der Inhalt der Bitmap-Instanz in die Graphic-Instanz kopiert (per Assign ) wird.

Die Bitmap-Instanz wird also nicht übernommen, von dir nicht freigegeben und dümpelt so bis zum Ende im Speicher rum -> Leck

(Ein Blick in den Setter-QuellCode hätte dir das auch verraten )

EDIT: Gerade gesehen, selbst die Dokumentation ist da eindeutig TPicture.Graphic

Zitat:

Anmerkung: Wenn die Eigenschaft Graphic zugewiesen wird, weist TPicture die Eigenschaften eines anderen TGraphic-Objekts zu. TPicture wird nicht der Eigentümer des angegebenen Objekts.

[DeddyH]

Wenn man TPicture.Graphic einen Wert zuweist, wird intern (im Setter) eine neue Instanz erzeugt und deren Werte mit Assign aus dem Original kopiert. Somit sind beide Instanzen völlig unabhängig voneinander. Das bedeutet aber auch, dass Du für die Freigabe Deiner Bitmap selbst zu sorgen hast.

[Der schöne Günther]

Hoppla, stimmt.

Delphi-Quellcode:

procedure TPicture.SetGraphic(Value: TGraphic);
var
  NewGraphic: TGraphic;
begin
  NewGraphic := nil;
  if Value <> nil then
  begin
    NewGraphic := TGraphicClass(Value.ClassType).Create;
    NewGraphic.Assign(Value);
    NewGraphic.OnChange := Changed;
    NewGraphic.OnProgress := Progress;
  end;
  try
    FGraphic.Free;
    FGraphic := NewGraphic;
    Changed(Self);
  except
    NewGraphic.Free;
    raise;
  end;
end;

NewGraphic sagt eigentlich schon alles...