Cursor auf Komponente legen

[Ajintaro]

Hi DP !

Ich habe einen TWebBrowser auf meiner Form liegen und möchte den Cursor an der Ecke unten links vom Browser platzieren. D.h. unabhängig von der Desktop-Auflösung oder der Screen-Position der Anwendung wird der Cursor immer an der Ecke unten links vom Browser platziert.

Delphi-Quellcode:

procedure TFmain.Button1Click(Sender: TObject);
var
  pt: TPoint;
begin
  WB_ScrollTo(WebBrowser1, wbPosBottom); //Webbrowser: an das ende scrollen
  pt := WebBrowser1.ScreenToClient(Mouse.CursorPos);

  e_x.Text:=IntToStr(pt.X);
  e_y.Text:=IntToStr(pt.Y);
  SetCursorPos(pt.X,pt.Y);  //mouseposition setzen

Ich dachte damit kann ich zumindest den Cursor auf den Webbrowser der Anwendung setzen, aber der Cursor verlässt das Fenster der Anwendung.
Gibt es eine Methode, den Cursor auf den Ursprung (0/0) einer Komponente zu platzieren ?

[Volker Z.]

Hallo,

suchst Du vielleicht etwas in der Richtung?

Delphi-Quellcode:

type
  TCursorPos = (cpTopLeft, cpTopRight, cpBottomLeft, cpBottomRight, cpCentered);

procedure SetControlCursorPos (const Form : TForm; const Control : TControl; const CursorPos : TCursorPos);
var
  p : TPoint;
begin
  case CursorPos of
    cpTopLeft     : p := Form.ClientToScreen (Point (Control.Left, Control.Top));
    cpTopRight    : p := Form.ClientToScreen (Point (Control.Left + Control.Width, Control.Top));
    cpBottomLeft  : p := Form.ClientToScreen (Point (Control.Left, Control.Top + Control.Height));
    cpBottomRight : p := Form.ClientToScreen (Point (Control.Left + Control.Width, Control.Top + Control.Height));
    cpCentered    : p := Form.ClientToScreen (Point (Control.Left + Control.Width div 2, Control.Top + Control.Height div 2));
  end;

  SetCursorPos (p.X, p.Y)
end;

procedure TFmain.Button1Click(Sender: TObject);
begin
  SetControlCursorPos (Self, WebBrowser1, cpBottomLeft)
end;

Gruß

[DeddyH]

Etwas vereinfacht ohne Form-Parameter:

Delphi-Quellcode:

procedure SetControlCursorPos(const Control : TControl; const CursorPos : TCursorPos);
var
  P: TPoint;
begin
  Assert(Assigned(Control), 'Kein Control zur Ausrichtung übergeben');
  case CursorPos of
    cpTopLeft:
      P := Control.ClientToScreen(Point(0, 0));
    cpTopRight:
      P := Control.ClientToScreen(Point(Control.Width, 0));
    cpBottomLeft:
      P := Control.ClientToScreen(Point(0, Control.Height));
    cpBottomRight:
      P := Control.ClientToScreen(Point(Control.Width, Control.Height));
    cpCentered:
      P := Control.ClientToScreen(Point(Control.Width div 2, Control.Height div 2));
  end;
  SetCursorPos(P.X, P.Y);
end;

[Ajintaro]

Guten Morgen DP !

Ja genau das ist was ich versucht habe zu bauen. Von ClientToScreen(Point(0, 0) ausgehend, hätte ich wirklich nur die "Ecken" mit Control.Width und Control.Height selbst errechnen können.

Super Sache, werde ich mir merken. Vielen Dank !