Mehrere Dreiecke zusammen drehen

[Astobix]

Hallo,

ich habe eine Klasse TRaumschiff, die ein Raumschiff aus mehreren Dreiecken erstellt. Um damit später eine schöne Bewegung durchzuführen, möchte ich das Raumschiff gerne um einen beliebigen Winkel drehen können.

Die Dreiecke sind jeweils ein Objekt der Klasse TDreieck. Wie ich ein einzelnen Dreieck drehen kann ist mir bereits klar, aber sobald ich versuche mehrere Dreieck zusammen zu drehen klappt mein Code von der Drehung nicht mehr.

Programmcode der Dreh-Prozedur:

Delphi-Quellcode:

procedure TDreieck.drehen(winkel: double);
var Ax,Ay,Bx,By,Cx,Cy: double;
begin

 //Rotationswinkel des Dreiecks wird berechnet - für spätere bewegung in Blickrichtung
 alpha := alpha+Winkel;
 if alpha > 360 then alpha := alpha-360;
 if alpha <0 then alpha := alpha+360;

 m_punkt.X := (A.X+B.X+C.X)/3;                               //Schwerpunkt des Dreiecks ausrechnen
 m_punkt.Y := (A.Y+B.Y+C.Y)/3;

 //Das Dreieck wird um den Koordinatenursprung gedreht, dementprechend muss es erst verschoben werden.
 //Ax,Ay,Bx,By,Cx,Cy sind dabei die temporären Koordinaten der Eckpunkte des Dreiecks.
 Ax := cos(degtorad(winkel)) * (A.X-m_punkt.x) - sin(degtorad(winkel)) * (A.Y-m_punkt.y);
 Ay := sin(degtorad(winkel)) * (A.X-m_punkt.x) + cos(degtorad(winkel)) * (A.Y-m_punkt.y);
 A.X:=m_punkt.x+Ax;
 A.y:=m_punkt.y+Ay;

 Bx := cos(degtorad(winkel)) * (B.X-m_punkt.x) - sin(degtorad(winkel)) * (B.Y-m_punkt.y);
 By := sin(degtorad(winkel)) * (B.X-m_punkt.x) + cos(degtorad(winkel)) * (B.Y-m_punkt.y);
 B.X:=m_punkt.x+Bx;
 B.y:=m_punkt.y+By;

 Cx := cos(degtorad(winkel)) * (C.X-m_punkt.x) - sin(degtorad(winkel)) * (C.Y-m_punkt.y);
 Cy := sin(degtorad(winkel)) * (C.X-m_punkt.x) + cos(degtorad(winkel)) * (C.Y-m_punkt.y);
 C.X:=m_punkt.x+Cx;
 C.y:=m_punkt.y+Cy;

 // Die Float-Eckpunkte ergeben gerundet nun die neuen Eckpunkte des Dreiecks.
 setX1(Round(A.X));
 setX2(Round(B.X));
 setX3(Round(C.X));
 setY1(Round(A.Y));
 setY2(Round(B.Y));
 setY3(Round(C.Y));
end;

Das es nicht klappt sollte ja daran liegen, dass jedes Dreieck nur um seinen eigenen Mittelpunkt gedreht wird.
Meine Idee war jetzt, alle Dreiecke um einen Gemeinsamen Mittelpunkt / Schwerpunkt zu drehen. Aber entweder ist der Ansatz falsch, oder ich habe den Ansatz falsch umgesetzt.

Kann mir da jemand helfen?

Gruß,
Astobix

[Uwe Raabe]

Zitat von Astobix:

Das es nicht klappt sollte ja daran liegen, dass jedes Dreieck nur um seinen eigenen Mittelpunkt gedreht wird.
Meine Idee war jetzt, alle Dreiecke um einen Gemeinsamen Mittelpunkt / Schwerpunkt zu drehen. Aber entweder ist der Ansatz falsch, oder ich habe den Ansatz falsch umgesetzt.

Gib der Methode Drehen noch den Drehpunkt mit - also quasi den m_punkt, den du zur Zeit noch selbst berechnest. Alle Dreiecke drehst du dann um denselben Punkt. Das sollte irgendwie der Mittelpunkt des Raumschiffs sein, wie auch immer du den ermittelst.

[Mikkey]

Du musst nur die Verschiebung, die in Deinem Code so schön dokumentiert ist, weglassen. Dann dreht sich alles um einen Koordinatenursprung.

Noch ein Tip zur einfacheren Berechnung:

Eine Drehung in Ebene oder Raum kannst Du durch eine Matrixtransformation darstellen. Dabei bleibt die Matrix bei der Berechnung für alle Punkte dieselbe.

[Astobix]

Zitat von Uwe Raabe:

Zitat von Astobix:

Das es nicht klappt sollte ja daran liegen, dass jedes Dreieck nur um seinen eigenen Mittelpunkt gedreht wird.
Meine Idee war jetzt, alle Dreiecke um einen Gemeinsamen Mittelpunkt / Schwerpunkt zu drehen. Aber entweder ist der Ansatz falsch, oder ich habe den Ansatz falsch umgesetzt.

Gib der Methode Drehen noch den Drehpunkt mit - also quasi den m_punkt, den du zur Zeit noch selbst berechnest. Alle Dreiecke drehst du dann um denselben Punkt. Das sollte irgendwie der Mittelpunkt des Raumschiffs sein, wie auch immer du den ermittelst.

Die Idee hatte ich auch schon, aber dabei habe ich anscheinend ein paar Fehler gemacht. Ich hatte mir eine Dreieckgruppe erstellt und dort mit folgendem Code den Mittelpunkt der Dreieck ausgerechnet:

Delphi-Quellcode:

For i:=Dreiecke.Count-1 downto 0 do
 begin
  tmp_dr := Dreiecke.Items[i];
  mpunkt.x := mpunkt.x + (tmp_dr.A.x+tmp_dr.B.x+tmp_dr.C.x)/3;
  mpunkt.y := mpunkt.y + (tmp_dr.A.y+tmp_dr.B.y+tmp_dr.C.y)/3;               //Mittelpunkt der Gruppe ausrechnen
  mpunkt.x := mpunkt.x/Dreiecke.Count;
  mpunkt.y := mpunkt.y/Dreiecke.Count;
 end;

Das Problem ist allerdings, dass er das Raumschiff dann anscheinend immer um 0|0 dreht. Ich weiß allerdings nicht wieso

Delphi-Quellcode:

procedure TDreieck.drehen(winkel: double;mpunkt: TFPoint);
var Ax,Ay,Bx,By,Cx,Cy: double;
begin

 //Rotationswinkel des Dreiecks wird berechnet - für spätere bewegung in Blickrichtung
 alpha := alpha+Winkel;
 if alpha > 360 then alpha := alpha-360;
 if alpha <0 then alpha := alpha+360;


 //Das Dreieck wird um den Koordinatenursprung gedreht, dementprechend muss es erst verschoben werden.
 //Ax,Ay,Bx,By,Cx,Cy sind dabei die temporären Koordinaten der Eckpunkte des Dreiecks.
 Ax := cos(degtorad(winkel)) * (A.X-mpunkt.x) - sin(degtorad(winkel)) * (A.Y-mpunkt.y);
 Ay := sin(degtorad(winkel)) * (A.X-mpunkt.x) + cos(degtorad(winkel)) * (A.Y-mpunkt.y);
 A.X:=mpunkt.x+Ax;
 A.y:=mpunkt.y+Ay;

 Bx := cos(degtorad(winkel)) * (B.X-mpunkt.x) - sin(degtorad(winkel)) * (B.Y-mpunkt.y);
 By := sin(degtorad(winkel)) * (B.X-mpunkt.x) + cos(degtorad(winkel)) * (B.Y-mpunkt.y);
 B.X:=mpunkt.x+Bx;
 B.y:=mpunkt.y+By;

 Cx := cos(degtorad(winkel)) * (C.X-mpunkt.x) - sin(degtorad(winkel)) * (C.Y-mpunkt.y);
 Cy := sin(degtorad(winkel)) * (C.X-mpunkt.x) + cos(degtorad(winkel)) * (C.Y-mpunkt.y);
 C.X:=mpunkt.x+Cx;
 C.y:=mpunkt.y+Cy;

 // Die Float-Eckpunkte ergeben gerundet nun die neuen Eckpunkte des Dreiecks.
 setX1(Round(A.X));
 setX2(Round(B.X));
 setX3(Round(C.X));
 setY1(Round(A.Y));
 setY2(Round(B.Y));
 setY3(Round(C.Y));
end;

Zitat:

Du musst nur die Verschiebung, die in Deinem Code so schön dokumentiert ist, weglassen. Dann dreht sich alles um einen Koordinatenursprung.

Noch ein Tip zur einfacheren Berechnung:

Eine Drehung in Ebene oder Raum kannst Du durch eine Matrixtransformation darstellen. Dabei bleibt die Matrix bei der Berechnung für alle Punkte dieselbe.

Ich möchte eben nicht, dass es sich um den Koordinatenursprung dreht sondern um sich selbst.

Mit Matrixtransformationen kenn ich mich leider garnicht aus. Allerdings solle der Code auch so simple wie möglich bleiben, da es im Zusammenhang mit einem Schulprojekt steht und es auch die anderen Schüler (zumindest ungefähr) verstehen sollten

[Sir Rufo]

Also ich bin jetzt nicht der Spieleprofi und auch nicht der Polygonexperte, darum nur ein paar Gedanken:

Wenn die Punkte der Dreiecke gerundet werden, dann driften die Dreiecke zwangsläufig irgendwann einfach auseinander. Die gerundeten Werte werden eh nur zur Darstellung benötigt, also rundet man die, wenn es zur Darstellung kommt und nicht bei der Berechnung der Position.

Bei einem Verbund aus Polygonen (hier eben Dreiecke) sollen die Dreiecke ja "miteinander verbunden" sein.
Das bedeutet doch, dass bei 2 Dreiecken eine Seite komplett gleich ist. Merkt man sich nun nicht die Positionen der 3 Punkte, sondern die Vektoren, dann kann man ausgehend von einem Dreieck die Position des anderen Dreiecks errechnen.

[Astobix]

Zitat von Sir Rufo:

Also ich bin jetzt nicht der Spieleprofi und auch nicht der Polygonexperte, darum nur ein paar Gedanken:

Wenn die Punkte der Dreiecke gerundet werden, dann driften die Dreiecke zwangsläufig irgendwann einfach auseinander. Die gerundeten Werte werden eh nur zur Darstellung benötigt, also rundet man die, wenn es zur Darstellung kommt und nicht bei der Berechnung der Position.

Das habe ich ja auch gemacht. Berechnet wird alles mit den ungerundeten Koordinaten des Dreiecks / der Dreiecke, nur am Schluss wird eben einmal gerundet um er zeichnen zu können.

Zitat von Sir Rufo:

Bei einem Verbund aus Polygonen (hier eben Dreiecke) sollen die Dreiecke ja "miteinander verbunden" sein.
Das bedeutet doch, dass bei 2 Dreiecken eine Seite komplett gleich ist. Merkt man sich nun nicht die Positionen der 3 Punkte, sondern die Vektoren, dann kann man ausgehend von einem Dreieck die Position des anderen Dreiecks errechnen.

Also wäre der Ansatz falsch, einen gemeinsamen Mittelpunkt/Schwerpunkt zu berechnen und um diesen zu drehen?

[Uwe Raabe]

Zitat von Astobix:

Die Idee hatte ich auch schon, aber dabei habe ich anscheinend ein paar Fehler gemacht. Ich hatte mir eine Dreieckgruppe erstellt und dort mit folgendem Code den Mittelpunkt der Dreieck ausgerechnet:

Delphi-Quellcode:

For i:=Dreiecke.Count-1 downto 0 do
 begin
  tmp_dr := Dreiecke.Items[i];
  mpunkt.x := mpunkt.x + (tmp_dr.A.x+tmp_dr.B.x+tmp_dr.C.x)/3;
  mpunkt.y := mpunkt.y + (tmp_dr.A.y+tmp_dr.B.y+tmp_dr.C.y)/3;               //Mittelpunkt der Gruppe ausrechnen
  mpunkt.x := mpunkt.x/Dreiecke.Count;
  mpunkt.y := mpunkt.y/Dreiecke.Count;
 end;

Du dividierst zu oft!

Delphi-Quellcode:

mpunkt.x := 0;
mpunkt.y := 0;
For i:=0 to Dreiecke.Count-1 do
  begin
    tmp_dr := Dreiecke.Items[i];
    mpunkt.x := mpunkt.x + (tmp_dr.A.x+tmp_dr.B.x+tmp_dr.C.x)/3;
    mpunkt.y := mpunkt.y + (tmp_dr.A.y+tmp_dr.B.y+tmp_dr.C.y)/3;               //Mittelpunkt der Gruppe ausrechnen
  end;
mpunkt.x := mpunkt.x/Dreiecke.Count;
mpunkt.y := mpunkt.y/Dreiecke.Count;

[Astobix]

Zitat von Uwe Raabe:

Zitat von Astobix:

Die Idee hatte ich auch schon, aber dabei habe ich anscheinend ein paar Fehler gemacht. Ich hatte mir eine Dreieckgruppe erstellt und dort mit folgendem Code den Mittelpunkt der Dreieck ausgerechnet:

Delphi-Quellcode:

For i:=Dreiecke.Count-1 downto 0 do
 begin
  tmp_dr := Dreiecke.Items[i];
  mpunkt.x := mpunkt.x + (tmp_dr.A.x+tmp_dr.B.x+tmp_dr.C.x)/3;
  mpunkt.y := mpunkt.y + (tmp_dr.A.y+tmp_dr.B.y+tmp_dr.C.y)/3;               //Mittelpunkt der Gruppe ausrechnen
  mpunkt.x := mpunkt.x/Dreiecke.Count;
  mpunkt.y := mpunkt.y/Dreiecke.Count;
 end;

Du dividierst zu oft!

Delphi-Quellcode:

mpunkt.x := 0;
mpunkt.y := 0;
For i:=0 to Dreiecke.Count-1 do
  begin
    tmp_dr := Dreiecke.Items[i];
    mpunkt.x := mpunkt.x + (tmp_dr.A.x+tmp_dr.B.x+tmp_dr.C.x)/3;
    mpunkt.y := mpunkt.y + (tmp_dr.A.y+tmp_dr.B.y+tmp_dr.C.y)/3;               //Mittelpunkt der Gruppe ausrechnen
  end;
mpunkt.x := mpunkt.x/Dreiecke.Count;
mpunkt.y := mpunkt.y/Dreiecke.Count;

Oh Mann... was ein blöder Fehler

Vielen Dank, es funktioniert jetzt!