Einfügen einer Grafik in DBImage

[Siggi]

Hallo zusammen,
wenn ich in einem DBImage mit LoadFromFile eine Grafik einfüge, bemerkt dies die Datenbakkompnente nicht. Bedeutet: das Bild wird in der Oberfläche im DBImage angezeigt, aber die DBNavigator-Komponente bemerkt nicht, dass ich etwas geändert hat (nbPost bleibt disabled).

Ich habe mir im Moment mit einem umkopieren über das ClipBoard geholfen, weil ich zuerst testweise statt LoadFromFile das PasteFromClipboard implementiert hatte und wusste dass es funktioniert. Wollte aber auf LoadFromFile umstellen, da vorheriges Öffnen in Paint und Kopieren ins Clipboard für Tests OK ist aber für Anwender dann doch eher "suboptimal" :

Delphi-Quellcode:

procedure TfrmMedia.sButton1Click(Sender: TObject);
begin
  if OpenPictureDialog1.Execute then
  begin
    DBImage1.Picture.LoadFromFile(OpenPictureDialog1.filename);
    DBImage1.CopyToClipboard;
    dbimage1.PasteFromClipboard;
  end;
end;

Aber das muss doch auch anders gehen, als umständlich erst mal mit CopyToClipboard und PasteFromClipboard den Inhalt zweimal hin und her zu schieben??

(Falls das im Datenbank-Forum besser aufgehoben ist kann es vielleicht jemand dort hin schieben - war mir nicht sicher wo es hingehört)

Gruß,
Siggi

[mkinzler]

Warum fügst du es nicht direkt in das DataSet ein?

[RSF]

Bilder lade ich einfach so:

Delphi-Quellcode:

IF OpenPictureDialog1.Execute THEN
  BEGIN
    TBlobField(DataModule2.Artikel.FieldByName('Bild')).LoadFromFile(OpenPictureDialog1.FileName);
  end;

(Datenbank = ADS)

[Siggi]

Hatte ich auch schon versucht, aber wenn ich ein JPG direkt mit LoadFromFile in das Dataset einfüge, kommt immer "Bitmap ist ungültig" als Fehlermeldung. Die DBImage-Komponente kommt nach Einbinden der UNIT JPEG mit dem Dateiformat JPG zurecht, das direkte Einfügen in das Dataset scheint nur mit BMP zu funktionieren.

[Perlsau]

Zitat von Siggi:

Hatte ich auch schon versucht, aber wenn ich ein JPG direkt mit LoadFromFile in das Dataset einfüge, kommt immer "Bitmap ist ungültig" als Fehlermeldung. Die DBImage-Komponente kommt nach Einbinden der UNIT JPEG mit dem Dateiformat JPG zurecht, das direkte Einfügen in das Dataset scheint nur mit BMP zu funktionieren.

Ich mach das über TStream und TFileStream, da lade ich ohne Probleme BMP- und JPG-Grafiken in ein Blobfeld bzw. speichere die Bilder aus einem Blobfeld auf Platte:

Delphi-Quellcode:

// ********** DATEI IN BLOBFELD SPEICHERN ********************************************************************************************
Function TDatMod.File_To_Blob(FileName: String; BlobFeld: TField): Boolean;
VAR
  S     : TStream;
  FileS : TFileStream;

begin
  Result := FALSE;
  IF NOT FileExists(FileName) THEN EXIT;

  S     := BlobFeld.DataSet.CreateBlobStream(BlobFeld, bmReadWrite);
  FileS := TFileStream.Create(FileName, fmOpenRead);
  TRY
    S.CopyFrom(FileS, FileS.Size);
    Result := TRUE;
  FINALLY
    FileS.Free;
    S.Free;
  END;
end;

// ********** DATEN AUS BLOBFELD IN DATEI SPEICHERN **********************************************************************************
Function TDatMod.Blob_To_File(FileName: String; BlobFeld: TField): Boolean;
VAR
  S     : TStream;
  FileS : TFileStream;

begin
  Result := FALSE;
  IF BlobFeld.IsNull THEN EXIT;

  S     := BlobFeld.DataSet.CreateBlobStream(BlobFeld, bmRead);
  FileS := TFileStream.Create(FileName, fmCreate);
  TRY
    FileS.CopyFrom(S, S.Size);
    Result := TRUE;
  FINALLY
    S.Free;
    FileS.Free;
  END;
end;

// ***** AUFRUF DER BLOBFELD-METHODEN AUS FORMMAIN HERAUS **************************************************************
Procedure TFormMain.DBImg_FirmaClick(Sender: TObject);
Var
  Datei : String;
begin
  IF DatMod.BTab.ModusEdit THEN
  BEGIN
    IF NOT OpenPicDlg.Execute THEN Exit;
    Datei := OpenPicDlg.FileName;
    IF NOT SysUtils.FileExists(Datei) THEN Exit;
    IF NOT DatMod.File_To_Blob(Datei,DatMod.Qset_Arbeitgeber.FieldByName('BILD')) THEN
           ShowMessage('Einlesen von "' + ExtractFileName(Datei) + '" leider mißlungen ...');
  END ELSE
  BEGIN
    IF NOT SavePicDlg.Execute THEN Exit;
    Datei := SavePicDlg.FileName;
    IF NOT DatMod.Blob_To_File(Datei,DatMod.Qset_Arbeitgeber.FieldByName('BILD')) THEN
           ShowMessage('Abspeichern von "' + ExtractFileName(Datei) + '" leider mißlungen ...');
  END;
end;

Natürlich mußt du selbst dafür sorgen, daß dein Dataset vor dem beim Speichern in ein Blobfeld in den Edit- oder Append-Modus versetzt wird. Im hier gezeigten Fall wird abhängig vom Edit-Modus (den ich in der Variablen DatMod.BTab.ModusEdit verwalte) entweder ein Bild reingeladen oder eben auf Datenträger gespeichert. Mit diesen beiden Methoden kannst du im Prinzip alles in ein Blobfeld speichern bzw. daraus wieder hervorholen, ob Grafik, PDF, RichText, Exe-Dateien usw.