Function (WIMGetMountedImageInfo)

[Sir Rufo]

@Zacherl

Folgendes würde ich ändern

• Wenn LoadLibrary dann auch FreeLibrary inkl. Fehlerbehandlung (Exception)
• GetLastError nur einmal aufrufen
  

  Zitat:

  Der Aufruf dieser Funktion setzt in der Regel den Fehlerstatus des Betriebssystems zurück.

• Da alle anderen Fehlermeldungen in diesem Kontext eine Ausnahme sind, würde ich auch eine Exception werfen
• Statt PChar auf jeden Fall PWideChar nehmen, denn hier gibt es nur WCHAR (und PChar ist abhängig vom Compiler -> bei der nächsten Umstellung des Standard-String-Typs sind wieder alle am Weinen ).
  Wenn sich die API ändert, dann ändert die sich eben ... nachführen

Delphi-Quellcode:

var
  Lwimgapi                                  : HMODULE;
  LSuccess                                  : Boolean;
  LBuffer                                   : PWIM_MOUNT_INFO_LEVEL0_LIST;
  LBufferLength, LReturnLength, LImageCount : DWord;
  LIdx                                      : Integer;
  LLastError                                : Cardinal;

begin
  Lwimgapi := LoadLibrary( 'wimgapi.dll' );
  if Lwimgapi = 0
  then
    RaiseLastOSError;

  try
    @WIMGetMountedImageInfo := GetProcAddress( Lwimgapi, 'WIMGetMountedImageInfo' );
    LBufferLength           := SizeOf( WIM_MOUNT_INFO_LEVEL0 ) * 8;
    GetMem( LBuffer, LBufferLength );
    try
      repeat
        LSuccess := WIMGetMountedImageInfo( MountedImageInfoLevel0, LImageCount, LBuffer, LBufferLength, LReturnLength );
        if LSuccess
        then
          begin
            for LIdx := 0 to LImageCount - 1 do
              begin
                ShowMessage( StrPas( PWideChar( @LBuffer^[LIdx].WimPath[0] ) ) );
              end;
          end
        else
          begin
            LLastError := GetLastError;
            case LLastError of
              ERROR_INSUFFICIENT_BUFFER :
                begin
                  ReallocMem( LBuffer, LReturnLength );
                end;
            else
              RaiseLastOSError( LLastError );
            end;
          end;
      until LSuccess;
    finally
      FreeMem( LBuffer );
    end;
  finally
    FreeLibrary( Lwimgapi );
  end;
end;

EDIT
GetProcAddress ist auch noch ein Kandidat zum Prüfen ... aber jetzt nicht mehr

[Zacherl]

Dein Code sieht auf jeden Fall besser aus, als mein nächtlicher Versuch , aber der Hinweis zu GetLastError in der Delphi Hilfe ist definitiv falsch Habe es unter verschiedenen Windows Versionen getestet und der Error Code wird auf jeden Fall nicht resetted. Im MSDN ist unter GetLastError ebenfalls kein Hinweis darauf zu finden.

[Sir Rufo]

Zitat von Zacherl:

Dein Code sieht auf jeden Fall besser aus, als mein nächtlicher Versuch , aber der Hinweis zu GetLastError in der Delphi Hilfe ist definitiv falsch Habe es unter verschiedenen Windows Versionen getestet und der Error Code wird auf jeden Fall nicht resetted. Im MSDN ist unter GetLastError ebenfalls kein Hinweis darauf zu finden.

Nun ja irgendwie schon

Zitat:

You should call the GetLastError function immediately ...

Also immer direkt nach dem API Aufruf ist gewährleistet, dass da der passende Fehlercode zu finden ist.
Danach kann schon wieder sonst was drin stehen (you never know).

Potentiell handelt man sich so diese unliebsamen SideEffects ein

[Zacherl]

Der Vollständigkeit halber:

Zitat:

You should call the GetLastError function immediately when a function's return value indicates that such a call will return useful data. That is because some functions call SetLastError with a zero when they succeed, wiping out the error code set by the most recently failed function.

Solange man also nicht bewusst eine andere API / Funktion aufruft, sollte der Wert von GetLastError demnach unverändert bleiben. Empfinde den Text in der Delphi Hilfe deshalb nach wie vor als unzutreffend, da GetLastError selbst nichts resetted.

[Sir Rufo]

Problematisch ist aber eben der unbewusste Aufruf von API Funktionen (weil die mit einem harmlosen Befehl irgendwo versteckt aufgerufen werden).

Bei MS wird es erklärt und Emba schürt Angst

[SlpLow]

Zitat von Zacherl:

Thats because of the C style boolean definition:
You can just check the flag like this:
if (Buffer^[I].MountedForRW) then

Genau. Aber richtig identifiziert das nur, wenn Sie die Konstanten ändern
MountedImageInfoLevel0 = 0;
Warum?

Sir Rufo Vielen Dank!

[Zacherl]

Zitat von SlpLow:

Genau. Aber richtig identifiziert das nur, wenn Sie die Konstanten ändern
MountedImageInfoLevel0 = 0;
Warum?

I dont know the correct value for that constant. I could not found it in the MSDN, but i googled it and it seems to be 1.

[SlpLow]

Zitat von Zacherl:

I dont know the correct value for that constant. I could not found it in the MSDN, but i googled it and it seems to be 1.

In den Header-Dateien = 1 auch.

// MOUNTED_IMAGE_INFO_LEVELS
MountedImageInfoLevel0 = 1;
MountedImageInfoLevel1 = 2;
MountedImageInfoLevelInvalid = 3;