Drag&Drop vom Explorer auf Listboxen - Unterscheidung?

[hungrycoder]

Hallo zusammen,

habe ein Problem per Drag&Drop Dateien vom Explorer in meine Anwendung zu schaufeln. Ich würde gerne nur die Listbox befüllen auf die auch tatsächlich gedropt wurde, nur leider weiß ich nicht wie genau ich das realisieren soll.

Ich habe es bis jetzt so probiert und auch im Internet nachgeschaut -> Kein Erfolg:

Delphi-Quellcode:

const DF_NUMBEROFFILES = $FFFFFFFF;

procedure TForm1.FormCreate(Sender: TObject);
begin
  DragAcceptFiles(ListBox1.Handle, true);
  DragAcceptFiles(ListBox2.Handle, true);
end;

procedure TForm1.ListBox1DragDrop(Sender, Source: TObject; X, Y: Integer);
begin
  ListBox2.Enabled := false;
end;

procedure TForm1.ListBox2DragDrop(Sender, Source: TObject; X, Y: Integer);
begin
  ListBox1.Enabled := false;
end;

procedure TForm1.WMDROPFILES(var Msg: TMessage);
var i, anzahl, size: Integer;
 Dateiname: PChar;
begin
 inherited;
 anzahl := DragQueryFile(Msg.WParam, DF_NUMBEROFFILES, Dateiname, 255);
 for i := 0 to (anzahl - 1) do
 begin
 size := DragQueryFile(Msg.WParam, i, nil, 0) + 1;
 Dateiname := StrAlloc(size);
 DragQueryFile(Msg.WParam, i, Dateiname, size);
  if ListBox1.Enabled then
    Listbox1.Items.Add(StrPas(Dateiname))
  else
    ListBox2.Items.Add(StrPas(Dateiname));
 StrDispose(Dateiname);
 end;
 DragFinish(Msg.WParam);
 ListBox1.Enabled := true;
 ListBox2.Enabled := true;
end;

Das enablen der Listboxen wollte ich zur Unterscheidung verwenden. Es muss doch eine logische Lösung geben, nur sehe ich die irgendwie nicht. Einer eine Idee?

Gruß

hungrycoder

[DeddyH]

Ich bin da kein Experte, aber könnte man nicht über DragQueryPoint die Drop-Koordinaten auslesen und schauen, welches Control sich an der Position befindet?

[baumina]

Wie wäre es mit dieser Lösung? http://www.delphipraxis.net/103137-d...p-problem.html

[himitsu]

Sollte in Msg nicht auch das HWND des Empfängers drinstehen?

[DeddyH]

TMessage, da steht nix von HWnd (was ja irgendwie auch Sinn macht, denn normalerweise werden Nachrichten ja an bestimmte Fensterhandles geschickt, das muss also nicht auch noch in der Nachricht selbst stehen).

[hungrycoder]

@DeddyH
Mit überprüfen der Koordinaten geht es aufjeden Fall, kam mir aber irgendwie zu umständlich rüber.

@baumina
Ich glaub ich bin blind. Sehe in deinem Link keine Lösung für mein Problem

@himitsu
Wie genau meinst du? Oder war das eher als Frage zu verstehen?

[DeddyH]

Im verlinkten Thread fängt nicht mehr das Formular, sondern die ListBox selbst die Message ab, daher muss man nicht mehr unterscheiden.

[edit] Ganz Bequeme können aber auch die Drag&Drop Component Suite benutzen, da muss man sich darüber wohl keine Gedanken mehr machen. Ich selbst habe sie aber nie ausprobiert. [/edit]

[hungrycoder]

Ok es ist offiziel, ich werde langsam blind...

Klappt wunderbar, habs doch gewusst, dass es eine einfache Lösung gibt

Vielen Dank an baumina und DeddyH, der mir die Augen geöffnet hat

[himitsu]

Ach stimmt ja, Delphi gibt das an die eigenen Message-Methoden nicht weiter.

@hungrycoder:
Bei dir gäbe es noch ein nettes Problem: Wenn man dann doch nicht gedroppt hätte, wäre das Enabled auf False geblieben.

Ach ja, das OnDragDrop vom Delphi hat absolut nichts mit dem Drag&Drop vom Windows zu tun. Das ist was Eigenes, drum reagiert das OnDragDrop auch nicht.

Delphi-Quellcode:

type
  TListBox = class(StdCtrls.TListBox)
    procedure TForm1.WMDROPFILES(var Msg: TMessage) message WM_DROPFILES;
  end;
  
  TForm1 = class(TForm)
    ...
  end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  DragAcceptFiles(ListBox1.Handle, True);
  DragAcceptFiles(ListBox2.Handle, True);
end;

procedure TListBox.WMDROPFILES(var Msg: TMessage);
var
  i: Integer;
  Dateiname: String;
begin
  for i := 0 to DragQueryFile(Msg.WParam, DF_NUMBEROFFILES, nil, 0) - 1 do begin
    SetLength(Dateiname, DragQueryFile(Msg.WParam, i, nil, 0));
    DragQueryFile(Msg.WParam, i, PChar(Dateiname), Length(Dateiname) + 1);
    Items.Add(Dateiname);
  end;
  DragFinish(Msg.WParam);
end;