Hilfestellung: arithmetic exception numeric overflow or string truncation

[delphinub23]

Hallo DPler,

ich habe eine Tabelle:
CREATE TABLE test (TXT VARCHAR(255)); eine externe Funktion in einer dll:

Delphi-Quellcode:

function IB_ExtractBetween(Value, A, B: PAnsiChar): PAnsiChar;  cdecl; export;
var
  aPos: Integer;
  bPos: Integer;
  tmpA: string;
  tmpB: string;
  tmpValue: string;
begin
  Result := '';
  tmpA := String(AnsiString(A));
  tmpB := String(AnsiString(B));
  tmpValue := String(Value);

  aPos := Pos(tmpA, tmpValue);
  if aPos > 0 then
  begin
    aPos := aPos + Length(tmpA);
    bPos := PosEx(tmpB, tmpValue, aPos);
    if bPos > 0 then
    begin
      Result := PAnsiChar(AnsiString(Copy(tmpValue, aPos, bPos - aPos)));
    end;
  end;
end;

im interbase wie folg implementiert:

Delphi-Quellcode:

DECLARE EXTERNAL FUNCTION EXTRACTBETWEEN
CSTRING(256) CHARACTER SET NONE, CSTRING(256) CHARACTER SET NONE, CSTRING(256) CHARACTER SET NONE
RETURNS CSTRING(256) CHARACTER SET NONE FREE_IT
ENTRY_POINT 'IB_ExtractBetween' MODULE_NAME 'udf_dwfunc';

und folgenden Aufruf:

SELECT EXTRACTBETWEEN(CAST(LD.AdditionalInfo AS VARCHAR(255)), '[', ']') FROM LogDetail LD WHERE LD.Event_ID = 2
Das SELECT funktioniert. Aber wenn ich es direkt einfügen will, klappts nicht mit dem o.g. Fehler:

Delphi-Quellcode:

insert into test
SELECT EXTRACTBETWEEN(CAST(LD.AdditionalInfo AS VARCHAR(255)), '[', ']') FROM LogDetail LD WHERE LD.Event_ID = 2

Was ist da los?

[sx2008]

Das geht in die Hosen

Delphi-Quellcode:

function IB_ExtractBetween(Value, A, B: PAnsiChar): PAnsiChar; cdecl; export;
begin
.....

    if bPos > 0 then
    begin
      Result := PAnsiChar(AnsiString(Copy(tmpValue, aPos, bPos - aPos)));
      // Problem
      // sobald die Funktion verlassen wird zeigt "Result" auf ungültigen Speicher
      // weil der temporäre AnsiString schon freigegeben wurde
    end;
  end;
end;

Gut möglich, dass das gewünschte Ergebnis immer noch dort im Speicher steht worauf "Result" zeigt.
Stabil ist das aber nicht.

[delphinub23]

Zitat von sx2008:

Das geht in die Hosen

Delphi-Quellcode:

function IB_ExtractBetween(Value, A, B: PAnsiChar): PAnsiChar; cdecl; export;
begin
.....

    if bPos > 0 then
    begin
      Result := PAnsiChar(AnsiString(Copy(tmpValue, aPos, bPos - aPos)));
      // Problem
      // sobald die Funktion verlassen wird zeigt "Result" auf ungültigen Speicher
      // weil der temporäre AnsiString schon freigegeben wurde
    end;
  end;
end;

Gut möglich, dass das gewünschte Ergebnis immer noch dort im Speicher steht worauf "Result" zeigt.
Stabil ist das aber nicht.

Ich glaube, ich habe es nicht verstanden.
Wenn das nicht funktioniert, wie du sagst, dann dürfte das SELECT-Statement auch kein Resultat liefern, oder?
Das tut es aber. Lediglich das INSERT-Statement resultiert in dem o.g. Fehler

Ist mein Ansatz falsch? Hast du einen anderen Vorschlag für mich, der stabiler ist?

[Blup]

Noch einmal deutlich obwohl weiter oben bereits beschrieben:
Du reservierst nirgends Speicher, deine Deklaration sagt aber, das der zurückgegebene Speicher freigegeben werden soll.
Der zurückgegebene Zeiger weist auf einen Speicherbereich, den der Delphispeichermanager verwaltet (nähmlich einen String).
Beim Verlassen der Funktion wird dem Speichermanager automatisch mitgeteilt, alle lokalen Stringvariablen werden nicht mehr benötigt.
Der Zeiger Result verweist damit auf einen String, der eigentlich nicht mehr existiert.
Da der Speichermanager freigegebenen Speicher nicht sofort an Windows zurückgibt oder überschreibt, funktioniert das ganze unter glücklichen Umständen manchmal doch.
Zumindest gehört dieser Speicherbereich dem Delphi-Speichermanager und darf auf keinen Fall freigegeben werden!

Bin mir nicht sicher ob Result = nil auch zulässig ist, aber so sollte es funktionieren:

Delphi-Quellcode:

function IB_ExtractBetween(Value, A, B: PAnsiChar): PAnsiChar; cdecl; export;
var
  aPos, bPos: PAnsiChar;
  n: DWord;
begin
  GetMem(Result, 256);
  n := 0;
  aPos := StrPos(Value, A);
  if aPos <> nil then
  begin 
    Inc(aPos, StrLen(A));
    bPos := StrPos(aPos, B);
    if bPos <> nil then
    begin
      n := bPos - aPos;
      StrMove(Result, aPos, n);
    end;
  end;
  Result[n] := #0;
end;

oder so:

Delphi-Quellcode:

function IB_ExtractBetween(Value, A, B: PAnsiChar): PAnsiChar; cdecl; export;
var
  aPos, bPos: PAnsiChar;
  n: DWord;
begin
  Result := Value;
  if Result = nil then
    Exit;

  n := 0;
  aPos := StrPos(Value, A);
  if aPos <> nil then
  begin 
    Inc(aPos, StrLen(A));
    bPos := StrPos(aPos, B);
    if bPos <> nil then
    begin
      n := bPos - aPos;
      StrMove(Result, aPos, n);
    end;
  end;
  Result[n] := #0;
end;

// DECLARE EXTERNAL FUNCTION EXTRACTBETWEEN
// CSTRING(256) CHARACTER SET NONE, 
// CSTRING(256) CHARACTER SET NONE, 
// CSTRING(256) CHARACTER SET NONE
// RETURNS PARAMETER 1 CHARACTER SET NONE
// ENTRY_POINT 'IB_ExtractBetween' MODULE_NAME 'udf_dwfunc';