Umsetzung von XCode nach Delphi

[RWarnecke]

Hallo zusammen,

könnte mir bitte jemand anhand des Beispiels für den Battery Status erklären, wie ich das mit den Notifications nach Delphi umsetzte. Hier ein Teil des Quelltextes :

Code:

- (void)batteryLevelChanged:(NSNotification *)notification
{
    [self updateBatteryLevel];
}

- (void)batteryStateChanged:(NSNotification *)notification
{
    [self updateBatteryLevel];
    [self updateBatteryState];
}

- (void)viewDidLoad
{
    [super viewDidLoad];

   // Register for battery level and state change notifications.
   [[NSNotificationCenter defaultCenter] addObserver:self
                   selector:@selector(batteryLevelChanged:)
                       name:UIDeviceBatteryLevelDidChangeNotification object:nil];
   
   [[NSNotificationCenter defaultCenter] addObserver:self
                   selector:@selector(batteryStateChanged:)
                                                     name:UIDeviceBatteryStateDidChangeNotification object:nil];
    
    [self switchAction:self.monitorSwitch];
}

Wenn ich diesen Teil des Quelltextes doch richtig verstehe, korrigiert mich bitte wenn ich falsch liege, wird in der Funktion viewDidLoad die beiden Funktionen batteryLevelChanged und batteryStateChanged entsprechend als Ereignis registriert. Damit wird dann automatisch bei einer Änderung des Batteriestatus die beiden Funktionen batteryLevelChanged und batteryStateChanged ausgeführt. Jetzt zu meiner Frage, wie muss ich diese Funktion viewDidLoad umsetzen, damit ich den gleichen Effekt in Delphi habe ? Ich habe im Moment die Vermutung, dass ich die ChangeNotifications im NotififcationCenter registrieren muss, damit das mit den Funktionen batteryLevelChanged und batteryStateChanged funktioniert oder ?

Habe ich den Teil des Quelltextes richtig verstanden und liege ich mit meiner Vermutung richtig ? Könnte mir bitte jemand die Umsetzung nach Delphi erklären und/oder mir zumindest Lesematerial geben, wo ich eine solche Umsetzung nachlesen kann.

[Mavarik]

hmm mit den Event...

Ich hab das... vielleicht hilft es Dir?!

Delphi-Quellcode:

Function GetBatteryState:Integer;
begin
{$IFDEF IOS}
  if TUIDevice.Wrap(TUIDevice.OCClass.currentDevice).isBatteryMonitoringEnabled
    then Result := TUIDevice.Wrap(TUIDevice.OCClass.currentDevice).batteryState
    else begin
           TUIDevice.Wrap(TUIDevice.OCClass.currentDevice).setBatteryMonitoringEnabled(true);
           if TUIDevice.Wrap(TUIDevice.OCClass.currentDevice).isBatteryMonitoringEnabled
             then Result := TUIDevice.Wrap(TUIDevice.OCClass.currentDevice).batteryState
             else result := 0;
         end;
... 

Android?!?

Mavarik

[RWarnecke]

Hallo Frank,

danke für Deine Antwort, aber den Teil habe ich schon. Mir geht es hauptsächlich um das Event. Ich habe das verlinkte Beipsiel mit XCode ausprobiert und es funktioniert wirklich mit einem Event. Und wenn ich den XCode-Quelltext richtig verstanden habe, liegt es an der Funktion viewDidLoad.

[RWarnecke]

*push* Hat keiner dazu Informationen, wie ich die Events für die Änderung des BatteryState und BatteryLevel in Delphi umsetze ?

[daywalker9]

Schau mal hier

Delphi-Quellcode:

unit Unit5;

interface

uses
  System.TypInfo,
  System.SysUtils, System.Types, System.UITypes, System.Classes, System.Variants,
  FMX.Types, FMX.Controls, FMX.Forms, FMX.Graphics, FMX.Dialogs, iOSapi.UIKit,
  iOSapi.Foundation, Macapi.ObjCRuntime, Macapi.ObjectiveC,  System.Mac.CFUtils,
  Macapi.OCMarshal, iOSapi.CocoaTypes, Macapi.CoreFoundation, FMX.StdCtrls;

type
  INotifier = interface(NSObject)
    ['{B0069354-3EF8-48F4-84E1-E6223E648BFA}']
    procedure CallBack(notification : Pointer); cdecl;
  end;

  TNotifier = class(TOCLOcal)
  protected
    function GetObjectiveCClass: PTypeInfo; override;
  public
    procedure CallBack(notification: Pointer); cdecl;
  end;

  TForm5 = class(TForm)
    Button1: TButton;
    procedure FormCreate(Sender: TObject);
    procedure Button1Click(Sender: TObject);
  private
    FNotifier: TNOtifier;
  public
    { Public declarations }
  end;

var
  Form5: TForm5;

implementation

{$R *.fmx}

function UIDeviceBatteryLevelDidChangeNotification : CFStringRef;
begin
  Result := CFStringRef(CocoaPointerConst(libUIKit, 'UIDeviceBatteryLevelDidChangeNotification')^);
end;

function UIDeviceBatteryStateDidChangeNotification : CFStringRef;
begin
  Result := CFStringRef(CocoaPointerConst(libUIKit, 'UIDeviceBatteryStateDidChangeNotification')^);
end;

procedure TForm5.Button1Click(Sender: TObject);
var
  lNSSotificationCenter: NSNotificationCenter;
  lCFString: TCFString;
  s:String;
begin
  FNotifier := TNotifier.Create;

  lCFString := UIDeviceBatteryLevelDidChangeNotification;

  lNSSotificationCenter := TNSNotificationCenter.Wrap(TNSNotificationCenter.OCClass.defaultCenter);
  lNSSotificationCenter.addObserver(FNotifier.GetObjectID,
    sel_getUid('CallBack:'),
    (NSSTR(lCFString.AsString()) as ILocalObject).GetObjectID, nil);

  lCFString := UIDeviceBatteryStateDidChangeNotification;

  lNSSotificationCenter.addObserver(FNotifier.GetObjectID,
    sel_getUid('CallBack:'),
    (NSSTR(lCFString.AsString()) as ILocalObject).GetObjectID, nil);

  TUIDevice.Wrap( TUIDevice.OCClass.currentDevice).setBatteryMonitoringEnabled(true);
end;


{ TNotifier }

procedure TNotifier.CallBack(notification: Pointer);
begin
  showmessage('Notification');
end;

function TNotifier.GetObjectiveCClass: PTypeInfo;
begin
  result:=TypeInfo(INotifier);
end;

[RWarnecke]

Hallo Lars,

vielen Dank für die Umsetzung der Events für den Batterie Status und das Level. Ich werde es gleich morgen ausgiebig ausprobieren.Gibt es dazu irgendwelche Anleitung wie man diese Sachen übersetzt oder Regeln, was man wie beachten muss ? Ich möchte ja nicht bei jedem kleinen Problem bei irgend jemand betteln gehen.

Wenn Du dazu Links hast, wäre es super, wenn Du mir noch mitteilen könntest.

[daywalker9]

Einen Link dazu habe ich nicht. Viele Dinge habe ich damals in der XE4 Beta Phase selber angelernt. Delphi Souce Code angeschaut und übertragen auf die Dinge, die ich machen wollte. Ich kann mal gucken, ob ich dazu mal etwas zusammenschreiben kann.

[RWarnecke]

Hallo Lars,

das wäre auf jedenfall super, wenn Du mal was dazu zusammenschreiben könntest. Ich würde es auf jedenfall ausgiebig ausprobieren.

[romber]

Ich versuche gerade die Notifications für BatteryLevel und BatteryState hinzukriegen mit dem Beispiel von daywalker9. Beim mir bleibt die App beim laden hängen und sturzt nach ca. 20-30 Sekunden ab. Das Problem liegt offenbar hier

Delphi-Quellcode:

lCFString := UIDeviceBatteryStateDidChangeNotification;
lNSSotificationCenter.addObserver(FNotifier.GetObjectID, sel_getUid('CallBack:'), (NSSTR(lCFString.AsString()) as ILocalObject).GetObjectID, nil);

denn sobald ich die Zeilen auskomentiere startet die App und bekommt die Notifications für BatteryLevel.
Mache ich etwas falsch? Wie bekomme ich es mit BatteryState hin?

[daywalker9]

Im FormCreate? Probiere es mal per Button click