edits sortier darstellen?

[Foxi1896]

@ sx2008: Also ich habe ein Messgerät und machte 8 Messungen wo ich jede Messung in ein Edit anzeigen lasse.
Nun kommen Werte wie z.B. 3 / 5 / 11 / 15 / 2 / 5 / 9 / 12 raus und und die Darstellung ist dann später für ein Diagramm nicht so schön. Da soll es mit der 2 anfangen (dem kleinsten Wert) also 2 / 5 / 9 / 12 / 3 / 5 / 11 / 15 ... und danach wollte ich es erst in ein Memo anzeigen lassen um dort alle Messungen die ich mit einem Bauteil mache untereinander bekomme.
evtl versteht ihr jetzt besser was ich habem möchte.

@DeddyH: versuche mal ob ich das was du mir da geschrieben hast hinbekomme.

[sx2008]

Zitat von Foxi1896:

@ sx2008: Also ich habe ein Messgerät und machte 8 Messungen wo ich jede Messung in ein Edit anzeigen lasse.

Ok. Aber warum verwendest du statt den 8 Edits nicht ein StringGrid?
Das Stringgrid könnte z.B. 9 Zeilen haben wobei die oberste Zeile für die Beschriftung verwendet wird.
Du kannst auch mehr als eine Spalte vorsehen (Spalte 1=Nummer der Messung, Spalte 2=Meßwert).

[Foxi1896]

ok. wäre eine überlegung es so zu ändern. Ich habe ein Programm von meinem Betreuer bekommen und soll das weiter ausbauen und da ist es schon so gegeben. Deshalb hab ich noch nicht drüber nachgedacht es allzusehr umzubauen.

Wie füge ich Edits in ein Stringgrid ein? Hab gerade gedacht ich baue um =/

@DeddyH und auch andere: kann es sein das es bei Lazarus kein Minimum befehl gibt? Da sagt er mir Fehler.

[Sir Rufo]

Zitat von Foxi1896:

@DeddyH und auch andere: kann es sein das es bei Lazarus kein Minimum befehl gibt? Da sagt er mir Fehler.

Ich setze mir jetzt mal kurz die Oberlehrermütze auf ... Achtung ...

Lazarus kennt davon gar nichts, denn Lazarus ist eine IDE, wenn kennt der Compiler das.

Der Compiler (Lazarus bemüht FPC aka FreePascalCompiler) kennt den Befehl auch nicht nativ. Streng genommen kennt der recht wenig.

Komplexere Funktionen finden sich in Units (Bibliotheken), die man einfach bei uses einträgt, um diese in der eigenen Unit zu benutzen.

BTW: System.Math.Min und System.Math.Max (Achtung, das gilt so für Delphi, sollte aber bei FPC sehr ähnlich sein)

und hier der Link zur FPC Math-Unit-Referenz
http://www.freepascal.org/docs-html/...h/index-5.html

OK, Mütze wieder ab

[DeddyH]

Außerdem war Minimum als lokale Variable deklariert, das kann der Compiler gar nicht kennen, wenn man es ihm nicht sagt.

[Foxi1896]

@DeddyH: Ahh hatte es kopiert und da war ein Tippfehler: bei var Minimimum und unten Minimum =)

Ich habe es jetzt umgebaut und ein Stringgrid erstellt wo ich die Werte einlese. Wie kann ich dort die Reihenfolge so ändern?


if n_wert=1 then stringgrid1.cells[0,1]:= FormatFloat('0.00',y_wert);
if n_wert=2 then stringgrid1.cells[1,1]:= FormatFloat('0.00',y_wert);
if n_wert=3 then stringgrid1.cells[2,1]:= FormatFloat('0.00',y_wert);
if n_wert=4 then stringgrid1.cells[3,1]:= FormatFloat('0.00',y_wert);
if n_wert=5 then stringgrid1.cells[4,1]:= FormatFloat('0.00',y_wert);
if n_wert=6 then stringgrid1.cells[5,1]:= FormatFloat('0.00',y_wert);
if n_wert=7 then stringgrid1.cells[6,1]:= FormatFloat('0.00',y_wert);
if n_wert=8 then stringgrid1.cells[7,1]:= FormatFloat('0.00',y_wert);
if n_wert=9 then stringgrid1.cells[8,1]:= FormatFloat('0.00',y_wert);
if n_wert=9 then

[baumina]

Du könntest dir jetzt die zahlreichen if's sparen:

  stringgrid1.cells[n-1,1]:= FormatFloat('0.00',y_wert);

Zeilen verschieben geht mit MoveRow

[DeddyH]

Ob das ein TStringGrid, eine TListbox oder TSchießMichTot ist, spielt doch für die Logik gar keine Rolle. Erweitern wir meinen Code von gestern mal dahingehend, dass die Zahlen in der gewünschten Reihenfolge in ein weiteres Array geschrieben werden (den Tippfehler habe ich übrigens mittlerweile korrigiert):

Delphi-Quellcode:

type
  TIntArray = array[1..10] of integer;

procedure MinimumFirst(const Src: TIntArray; out Dest: TIntArray);
var
  (* Variable für die kleinste Zahl im Array *)
  Minimum: integer;
  (* Variable für den Index der kleinsten Zahl innerhalb des Array *)
  IndexOfMinimum: integer;
  (* Laufvariable für die Schleife *)
  i: integer;
  (* aktueller Index im Zielarray *)
  DestIndex: integer;
begin
  (* Initial setzen wir Minimum sowie dessen Index auf das erste Element im Array *)
  Minimum := Src[Low(Src)];
  IndexOfMinimum := Low(Src);
  (* Nun den Rest des Array durchgehen, vergleichen und Variablen ggf. anpassen *)
  for i := Low(Src) + 1 to High(Src) do
    if Src[i] < Minimum then
      begin
        Minimum := Src[i];
        IndexOfMinimum := i;
      end;
  DestIndex := Low(Dest);
  (* Nun in das Ausgabe-Array schreiben *)
  (* Zuerst ab der kleinsten Zahl bis zum Ende *)
  for i := IndexOfMinimum to High(Src) do
    begin
      Dest[DestIndex] := Src[i];
      inc(DestIndex);
    end;
  (* Nun noch die ggf. verbliebenen *)
  for i := Low(Src) to IndexOfMinimum - 1 do
    begin
      Dest[DestIndex] := Src[i];
      inc(DestIndex);
    end;
end;

Ein kurzer Test mit einer Listbox, damit man auch etwas sieht:

Delphi-Quellcode:

procedure TFormTest.FormCreate(Sender: TObject);
const
  Input: TIntArray = (5, 34, 23, 12, 8, 3, 42, 1, 98, 3);
var
  Output: TIntArray;
  i: integer;
begin
  MinimumFirst(Input, Output);
  for i := Low(Output) to High(Output) do
    ListBox1.Items.Add(IntToStr(Output[i]));
end;

[Foxi1896]

ich was ist dieses src? (source?)

[DeddyH]

Das ist der Name des Parameters der Prozedur (bei mir steht Src immer für Source und Dest für Destination).