Auslesen TObjectlist - rückgabewert von T.ObjectList.Add immer 0

[Hausmarke]

Hallo Leute,

folgender Sachverhalt:
Ich lege befüllte TObjects in eine TObjectlist.
Laut Delphi gibt TObjectlist.add(TObject) den Index als integer zurück.
Allerdings ist dieser immer null und ich verstehe nicht weshalb.

hier wie ich in die ObjectList schreibe:

Delphi-Quellcode:

var MultiSQLQ - TIBQuery;
    w - TMeinObject;
    j: integer;

while not MultiSQLQ.Eof do
  begin
    for i := 0 to MultiSQLQ.FieldCount - 1 do
    begin
      w.LoadProp(MultiSQLQ.Fields[i].FieldName, MultiSQLQ.Fields[i].Value);
    end;
    j := Result.Add(w);      
    MultiSQLQ.Next;
  end;

lesen der Objectlist:

Delphi-Quellcode:

var 
u : TMeinObject;
w : TObjectlist;

// ich gebe die Objectlist aus einer Function zurück

for I := 0 to w.Count - 1 do
    begin
      u :=(W[i]) as TMeinObject;
      StringGrid1.Cells[1,i] := IntToStr(u.ID);
      StringGrid1.Cells[2,i] := U.Content;
      StringGrid1.Cells[3,i] := IntToStr(U.Wert);
    end;

wenn ich nun die TObjectlist auslese, gibt er mir nur den letzten gespeicherten Eintrag.
Allerdings gibt TObjectlist.count den korrekten Wert der vorhandenen TMeinObject aus, nur kann ich nicht über den Index auf die weiteren Datensätze zugreifen.

Was mache ich falsch?

[Blup]

Delphi-Quellcode:

while not MultiSQLQ.Eof do
  begin
    w := TMeinObject.Create; // <- für jeden Datensatz ein neues Objekt erzeugen
    for i := 0 to MultiSQLQ.FieldCount - 1 do
    begin
      w.LoadProp(MultiSQLQ.Fields[i].FieldName, MultiSQLQ.Fields[i].Value);
    end;
    j := Result.Add(w);
    MultiSQLQ.Next;
  end;

[Christian Seehase]

Moin Hausmarke,

ein Objekt als Rückgabewert einer Funktion kann leicht problematisch sein, da es in der Funktion erzeugt werden muss, aber anschliessend schwer zu entscheiden ist, wann man es wieder freigeben darf bzw. muss. Ausserdem kann man diese Freigabe leicht vergessen.

So wie es aussieht dürfte es in Deinem Falle nicht schwierig sein erst die Objectlist zu erzeugen und anschliessend als Parameter zu übergeben, so dass die Funktion die Liste füllen kann.

Delphi-Quellcode:

ObjektlisteFuellen(const AListe : TObjectList);
begin
  //...
end;

w := TObjectList.Create;
try
  ObjektlisteFuellen(w);
  // weiterverarbeiten
finally
  w.Free;
end;

[Hausmarke]

@Blup: ja super besten dank, jetzt funktioniert es

@Christian:
du hast vollkommen recht, die Freigabe der Objekte in diesem Beispiel ist "problematisch", zudem die Objekte in einer ganz anderen stelle, quasi in einer anderen unit erzeugt werden.
Wenn ich es richtig verstanden habe, hat das setzen der Objectlist auf Nil keinerlei Auswirkungen auf die Existenz der darin abgelegten Objects, da nur die Zeigerposition in der liste gespeichert wird.

allerdings kann ich die objects vor dem auslesen der liste nicht freigeben. ich müsste also eine Art destructor prozedur basteln, die ich nach dem auslesen aufrufe, und welche mir die objects in der objectlist löscht.

oder gibt es eine andere Möglichkeit?

EDIT: leider ist der Rückgabewert von Objectlist.Add noch immer permanent "0"

EDIT:
ich schätze so dürfte es funktionieren die Objects in der Liste und anschließend die Liste selbst auf nil zu setzen:

Delphi-Quellcode:

var
u : TMeinObject;
w : TObjectlist;
.
.
.
  begin
    for I := 0 to w.Count - 1 do
    begin
      u :=(W[0]) as TMeinObject;
      StringGrid1.Cells[0,i+1] := IntToStr(u.ID);
      StringGrid1.Cells[1,i+1] := IntToStr(U.Wert);
      StringGrid1.Cells[2,i+1] := U.Content;
      w.Delete(0);      
    end;
  end;
  w.free;

[DeddyH]

Das Delete kannst Du Dir sparen, wenn Du die Liste anschließend freigibst, da diese dann sowieso geleert wird. Vielleicht könntest Du Dich aber mit einem Konzept dieser Art anfreunden?

Delphi-Quellcode:

procedure FillList(List: TObjectList);
var
  Obj: TSomeObject;
begin
  Assert(Assigned(List), 'Keine gültige Listeninstanz übergeben');
  while SomeCondition do
    begin
      Obj := TSomeObject.Create;
      Obj.Property := SomeValue;
      List.Add(Obj);
    end;
end;

procedure TFormDings.MachWas;
var
  List: TObjectList;
  Obj: TSomeObject;
  i: integer;
begin
  List := TObjectList.Create(true);
  try
    FillList(List);
    for i := 0 to List.Count - 1 do
      begin
        Obj := List[i] as TSomeObject;
        Obj.DoSomething;
      end;
  finally
    List.Free;
  end;
end;

Die Methode MachWas erzeugt also eine TObjectList und lässt sie dann von FillList befüllen. Anschließend arbeitet sie mit den enthaltenen Objekten und gibt zum Schluss die Liste samt aller enthaltenen Objekte wieder frei.

[Hausmarke]

@ DeddyH:
das ist natürlich eine elegante Lösung
ich habe das Prinzip übernommen und nun ist auch das letzte MemoryLeak weg.

besten dank für den Vorschlag