Problem mit Darstellung einer CombBox in StringGrid mit "csOwnerDrawFixed"

[Helmi]

Hallo,

ich hab ein kleines optisches Problem.

In einer StringGrid wird beim klick auf bestimmte Zellen (bzw. Spalten) eine Combobox in der Zelle angezeigt.
In den Spalten 1 und 2 wird die Combobox mit "csDropDownList" angezeigt, in der 3. Spalte mit "csOwnerDrawFixed". Bei den ersten zwei Spalten bleibt kein "Rest" mehr übrig, wenn die Combobox wieder ausgeblendet wird, bei "csOwnerDrawFixed" aber schon.
(siehe Bilder).

Das gleiche passiert mir auch in der letzten Spalte, in der ein SpinEdit angezeigt wird.

Wie kann ich verhindern, dass noch ein "Rest" übrig bleibt?

Hier noch ein bischen Code zum Anzeigen der Combobox und des SpinEdits:

Delphi-Quellcode:

procedure TMainForm.StringGridSelectCell(Sender: TObject; ACol, ARow: Integer;
  var CanSelect: Boolean);
const
  Diff = 2;

var
  S   : String;
  i   : Integer;
  Min : Integer;
  Max : Integer;
  Rect: TRect;

begin
  //aktuelle Zeile größer der ersten (fixen) Zeile?
  If ARow > 0 then
    begin
      //Zellen-Rect auslesen
      Rect := StringGrid.CellRect(ACol, ARow);

      //Zellen-Text auslesen
      S := StringGrid.Cells[ACol, ARow];

      If ACol in [1, 2, 3] then
        begin
          //ComboBox positionieren
          ComboBox.SetBounds(Rect.Left + StringGrid.Left + Diff,
            Rect.Top + StringGrid.Top + Diff, Rect.Width, Rect.Height - Diff);

          //je nach Spalte die dementsprechende StringList in die ComboBox laden
          //und den Style der ComboBox setzen
          case ACol of
            1:  begin //Spalte: "Linie"
                  ComboBox.Items.Assign(StringList_Linien);

                  ComboBox.Style := csDropDownList;
                end;
            2:  begin //Spalte: "Ziele"
                  ComboBox.Items.Assign(StringList_Ziele);

                  ComboBox.Style := csDropDownList;
                end;
            3:  begin //Spalte: "Länge"
                  ComboBox.Items.Assign(StringList_Laenge);

                  ComboBox.Style := csOwnerDrawFixed;
                end;
          end;

          //Index des aktuellen Zellen-Text in der ComboBox ermitteln
          ComboBox.ItemIndex := ComboBox.Items.IndexOf(S);

          //ComboBox anzeigen und fokusieren
          ComboBox.Visible := true;
          ComboBox.SetFocus;
        end;

      If ACol in [4] then
        begin
          //SpinEdit positionieren
          SpinEdit.SetBounds(Rect.Left + StringGrid.Left + Diff,
            Rect.Top + StringGrid.Top + Diff, Rect.Width, Rect.Height - Diff);

          //Wert der Zelle eine Zeile drüber auslesen und als Min-Wert für
          //das SpinEdit verwenden
          Min := 0;
          If ARow > 1 then
            Min := StrToIntDef(StringGrid.Cells[ACol, Pred(ARow)], 0) + 1;

          //Wert der Zelle drüber auslesen und als Max-Wert für das SpinEdit
          //setzen (wenn der Wert größer null ist)
          Max := 60;
          If ARow < StringGrid.RowCount then
            begin
              i := StrToIntDef(StringGrid.Cells[ACol, Succ(ARow)], 0) - 1;

              If i > 0 then
                Max := i;
            end;

          //Min- und Max-Werte setzen
          SpinEdit.MinValue := Min;
          SpinEdit.MaxValue := Max;

          //Zahl des aktuellen Zellen-Text in SpinEdit laden
          SpinEdit.Value := StrToIntDef(S, 1);

          //SpinEdit anzeigen und fokusieren
          SpinEdit.Visible := true;
          SpinEdit.SetFocus;
        end;
    end;

  //
  CanSelect := true;
end;

[Volker Z.]

Hallo,

der Rest, der da überbleibt hat wohl folgenden Hintergrund: Die minimale Höhe der Combobox und der SpinEdit hängen von der gewählten Schrift bzw. Schriftgröße ab. Eine Combobox mit Style csDropDown / csDropDownList nimmt keine Änderung an der Höhe an. Im Style csOwnerDrawFixed hängt die Höhe von ItemHeight ab. Bei einem SpinEdit ist die Höhe zwar variabel, kann aber nicht die Mindesthöhe unterschreiten.

Szenario 1:

Delphi-Quellcode:

Combobox.Font.Name := 'Tahoma';
Combobox.Font.Size := 8;
Combobox.Style := csDropDownList; // oder csDropDown

hat zur Folge:
Combobox.Height := 21; // zumindest mit meinen Einstellungen

Szenario 2:

Delphi-Quellcode:

Combobox.Font.Name := 'Tahoma';
Combobox.Font.Size := 8;
Combobox.Style := csOwnerDrawFixed;

hat zur Folge:
Combobox.Height := 22; // zumindest mit meinen Einstellungen

Delphi-Quellcode:

SpinEdit.Font.Name := 'Tahoma';
SpinEdit.Font.Size := 8;
SpinEdit.Height := 22; // Minimalhöhe zumindest hier bei mir

Die Höhe ist nicht änderbar, deshalb läuft Dein SetBounds - zumindest was die Höhe anbelangt - ins Leere. Oder: Die Combobox passt mal genau in die Zelle, mal ist sie etwas zu hoch und überdeckt dann auch die Gridline (und/oder mehr); und diese wird anscheinend nicht aktualisiert.

Zitat:

Wie kann ich verhindern, dass noch ein "Rest" übrig bleibt?

Hast Du schon mal versucht das StringGrid zum Neuzeichnen zu zwingen?

Gruß

[Helmi]

Zitat von Volker Z.:

Hallo,

der Rest, der da überbleibt hat wohl folgenden Hintergrund: Die minimale Höhe der Combobox und der SpinEdit hängen von der gewählten Schrift bzw. Schriftgröße ab. Eine Combobox mit Style csDropDown / csDropDownList nimmt keine Änderung an der Höhe an. Im Style csOwnerDrawFixed hängt die Höhe von ItemHeight ab. Bei einem SpinEdit ist die Höhe zwar variabel, kann aber nicht die Mindesthöhe unterschreiten.

Szenario 1:

Delphi-Quellcode:

Combobox.Font.Name := 'Tahoma';
Combobox.Font.Size := 8;
Combobox.Style := csDropDownList; // oder csDropDown

hat zur Folge:
Combobox.Height := 21; // zumindest mit meinen Einstellungen

Szenario 2:

Delphi-Quellcode:

Combobox.Font.Name := 'Tahoma';
Combobox.Font.Size := 8;
Combobox.Style := csOwnerDrawFixed;

hat zur Folge:
Combobox.Height := 22; // zumindest mit meinen Einstellungen

Delphi-Quellcode:

SpinEdit.Font.Name := 'Tahoma';
SpinEdit.Font.Size := 8;
SpinEdit.Height := 22; // Minimalhöhe zumindest hier bei mir

Die Höhe ist nicht änderbar, deshalb läuft Dein SetBounds - zumindest was die Höhe anbelangt - ins Leere. Oder: Die Combobox passt mal genau in die Zelle, mal ist sie etwas zu hoch und überdeckt dann auch die Gridline (und/oder mehr); und diese wird anscheinend nicht aktualisiert.

Zitat:

Wie kann ich verhindern, dass noch ein "Rest" übrig bleibt?

Hast Du schon mal versucht das StringGrid zum Neuzeichnen zu zwingen?

Gruß

Danke für deine Ausführungen!
Das mit der Höhe hatte ich mir auch schon gedacht und von daher die Zellengröße des Grids mal erhöht. Leider brachte es keinen Erfolg.

Das mit dem Neuzeichnen hab ich mir auch schon überlegt, nur wüsst ich nicht, wo genau ich das Neuzeichnen einbauen soll

[Volker Z.]

Hallo,

ich habe mal versucht mit Deinem Code die "Überbleibsel" hier nachzubilden; ist mir allerdings bis jetzt nicht gelungen.

Gruß

[Helmi]

Zitat von Volker Z.:

ich habe mal versucht mit Deinem Code die "Überbleibsel" hier nachzubilden; ist mir allerdings bis jetzt nicht gelungen.

Deine Aussage hat mich jetzt stutzig gemacht und hatte daraufhin einen Verdacht.

In der 4. Spalte wird nicht nur in der Combobox gezeichnet, sondern auch in der StringGrid.
Blende ich das Zeichnen in der 4. Spalte aus, so bleibt nichts übrig.
Also hängt es mit dem Zeichnen zusammen.

[Volker Z.]

Hallo,

Zitat:

Also hängt es mit dem Zeichnen zusammen.

Sieht wohl so aus. Dazu müsste man dann aber Code sehen.

Gruß

[Helmi]

Viel mach ich da nicht:

Delphi-Quellcode:

procedure TMainForm.StringGridDrawCell(Sender: TObject; ACol, ARow: Integer;
  Rect: TRect; State: TGridDrawState);
begin
  //Wenn es sich nicht um die 3. Spalte und Zeilen ab der Ersten handelt, dann
  //die Procedure beenden
  If (ACol <> 3) or (ARow < 1) then
    exit;

  //
  Zuege_zeichnen(StringGrid.Canvas, Rect, StringGrid.Cells[ACol, ARow]);
end;

und hier Zuege_zeichnen:

Delphi-Quellcode:

procedure TMainForm.Zuege_zeichnen(const Canvas: TCanvas; const Rect: TRect;
  const S: String);
const
  const_Abstand = 2;

var
  i          : Integer;
  mit_Zug    : Boolean;
  Bitmap_Zug : TBitmap;
  Rect_Zug   : array[1..3] of TRect;
  Rect_Bitmap: TRect;
  StringList : TStringList;

begin
  //Bitmap erzeugen
  Bitmap_Zug := TBitmap.Create;

  //StringList erzeugen
  StringList := TStringList.Create;

  //StringList beschreiben
  StringList.Delimiter := ',';
  StringList.StrictDelimiter := true;
  StringList.DelimitedText := S;

  try
    //Bitmap laden
    Bitmap_Zug.LoadFromResourceName(HInstance, 'ZZA_RES');

    //Bitmap-Rect definieren
    Rect_Bitmap := Bounds(0, 0, Bitmap_Zug.Width, Bitmap_Zug.Height);

    //
    Canvas.FillRect(Rect);

    //Umrandung leeren
    Canvas.Pen.Style := psClear;

    //Pinsel leeren
    Canvas.Brush.Style := bsClear;

    If StringList.Count >= 1 then
      begin
        //Zug links berechnen und anzeigen
        i := (Rect.Width - (2 * const_Abstand) - (3 * Bitmap_Zug.Width)) div 2;
        Rect_Zug[1].Left    := Rect.Left + i;
        Rect_Zug[1].Top     := Rect.Top + (Rect.Height - Rect_Bitmap.Height) div 2;
        Rect_Zug[1].Width   := Rect_Bitmap.Width;
        Rect_Zug[1].Height  := Rect_Bitmap.Height;

        //Zug-links: prüfen ob angezeigt werden soll
        mit_Zug := StrToBoolDef(StringList.Strings[0], false);

        If mit_Zug then
          Canvas.BrushCopy(Rect_Zug[1], Bitmap_Zug, Rect_Bitmap, clWhite);
      end;

    If StringList.Count >= 2 then
      begin
        //Zug mitte berechnen und anzeigen
        Rect_Zug[2].Left    := Rect_Zug[1].Right + const_Abstand;
        Rect_Zug[2].Top     := Rect_Zug[1].Top;
        Rect_Zug[2].Width   := Rect_Bitmap.Width;
        Rect_Zug[2].Height  := Rect_Bitmap.Height;

        //Zug-mitte: prüfen ob angezeigt werden soll
        mit_Zug := StrToBoolDef(StringList.Strings[1], false);

        If mit_Zug then
          Canvas.BrushCopy(Rect_Zug[2], Bitmap_Zug, Rect_Bitmap, clWhite);
      end;

    If StringList.Count >= 3 then
      begin
        //Zug rechts berechnen und anzeigen
        Rect_Zug[3].Left    := Rect_Zug[2].Right + const_Abstand;
        Rect_Zug[3].Top     := Rect_Zug[1].Top;
        Rect_Zug[3].Width   := Rect_Bitmap.Width;
        Rect_Zug[3].Height  := Rect_Bitmap.Height;

        //Zug-rechts: prüfen ob angezeigt werden soll
        mit_Zug := StrToBoolDef(StringList.Strings[2], false);

        If mit_Zug then
          Canvas.BrushCopy(Rect_Zug[3], Bitmap_Zug, Rect_Bitmap, clWhite);
      end;
  finally
    //StringList löschen und freigeben
    FreeAndNil(StringList);

    //Bitmap löschen und freigeben
    FreeAndNil(Bitmap_Zug);
  end;
end;

Die letzte Procedure nutze ich auch für eine Combobox, daher ist diese allgemein gehalten
(deswegen wird Canvas übergeben)

[Volker Z.]

Hallo,

nimm doch mal das Canvas.Pen.Style := psClear; aus Deiner Zeichenroutine raus.

Gruß

[Helmi]

Zitat von Volker Z.:

nimm doch mal das Canvas.Pen.Style := psClear; aus Deiner Zeichenroutine raus.

Peinlich!
Danke! - das wars!