TDrawcell mit einem Teil einer Bitmap füllen

[haderlump]

Hallo zusammen
Ich möchte in einem Drawgrid in die Zellen Ausschnitte einer Bitmap copieren.
Ich habe schon im Netz rumgesucht, finde aber nur Beispiele, wie man ganze Bilder hineinlädt.
Konkret: Ich habe ein Bild in der Anwendung, mit Symbolen für das Gleisbild . In Abhängigkeit von bestimmten Kriterien soll nun ein Gleiselement (Auschnitt von 13X9 Pixeln in die zugehörigen Zellen kopiert werden.

Ich habe das schon mal mit einer Zeichenfläche gemacht, aber nicht mit einem Gitter.

Ich habe damals folgender Anweisung verwendet:

Delphi-Quellcode:

Hauptform.Gitter.canvas.CopyRect(Rect(spalte*9+1),reihe*14-1,spalte*9+10,reihe*14+13)
,Hauptform.hintergrundbild.canvas,(Rect(akt_symbol*10+1,1+status,akt_symbol*10+10,13+status)))

Die zweite Hälfte (die die Bildquelle bhandelt) wird wohl so bleiben können, aber die erste Zeile geht wohl nicht, da sie sich ja auf eine einfache Zeichenfläche bezieht.
vielleicht gibt es diese Methode bei DrawCell garnicht.

Vielleicht weiß jemand was besseres.

Gruß Fritz

[Bummi]

Optisch nicht ansprechend umgesetztes Beispiel nur für den technischen Ansatz ...

Delphi-Quellcode:

procedure TForm1.DrawGrid1DrawCell(Sender: TObject; ACol, ARow: Integer; Rect: TRect; State: TGridDrawState);
var
  c: TCanvas;
  dx, dy, dw, dh: Integer;
begin
  c := DrawGrid1.Canvas;
  dx := -1;
  dh := 30;  // nur geschätzt nicht gemessen
  dw := 31;
  case ACol of   // irgnedwelche Randombedingungen
    1:
      begin
        case ARow of
          1:
            begin
              dx := 5 * dw;
              dy := 3 * dh;
            end;
          4 .. 6:
            begin
              dx := Random(10) * dw;
              dy := 2 * dh;
            end
        end;
      end;
    2:
      if ARow > 0 then
      begin
        dx := ARow * dw;
        dy := ACol * dh;
      end
  end;
  if dx > -1 then
    Stretchblt(c.Handle, Rect.Left, Rect.Top, Rect.Right - Rect.Left, Rect.Bottom - Rect.Top, Image1.Canvas.Handle, dx, dy, dw, dh, srcCopy)
end;

procedure TForm1.FormCreate(Sender: TObject);
var
  bmp: TBitmap;
begin
  DrawGrid1.ColCount := 10;
  DrawGrid1.RowCount := 10;
  DrawGrid1.DefaultColWidth := 60;  // etwas größer als die Bilder um Strech zu zeigen
  DrawGrid1.DefaultRowHeight := 60;

  if Assigned(Image1.Picture.Graphic) then  // kein Bitmap sondern etwas anderes geladen
  begin
    bmp := TBitmap.Create;
    try
      bmp.Width := Image1.Picture.Graphic.Width;
      bmp.Height := Image1.Picture.Graphic.Height;
      bmp.Canvas.Draw(0, 0, Image1.Picture.Graphic);
      Image1.Picture.Assign(bmp);
    finally
      bmp.Free;
    end;
  end;
  Image1.Picture.Bitmap; // Dummyzugriff um ein (leeres) Bitmap zu erzeugen wenn keines vorhanden ist
end;