FileExistsWait

[PeterPanino]

Diesmal keine Frage, sondern eine kleine praktische Funktion, die sich beim Umgang mit Dateien als nützlich erwiesen hat. Oft muss man nämlich eine Datei kopieren und die Ziel-Datei dann weiterverarbeiten (z.B. öffnen). Wenn man aber große Dateien kopiert, kann es unter Umständen passieren, dass die Zieldatei noch nicht (oder nicht vollständig) existiert, wenn das Programm nachher versucht, diese zu öffnen. Wenn man nun aber eine statische Wartezeit nach dem Kopieren einbaut, kann es sein, dass ein zu langes Warten den Benutzer nervt oder die Datei trotzdem noch nicht existiert und ein Fehler auftritt. Diese kleine Funktion löst dieses Problem, indem sie intervall-weise wiederholt prüft, ob die Datei bereits existiert:

Delphi-Quellcode:

procedure MyDelay(const Milliseconds: Integer);
var
  Tick: DWord;
  Event: THandle;
  ms: Integer;
begin
  ms := Milliseconds;
  Event := CreateEvent(nil, False, False, nil);
  try
    Tick := GetTickCount + DWord(ms);
    while (ms > 0) and
          (MsgWaitForMultipleObjects(1, Event, False, ms, QS_ALLINPUT) <> WAIT_TIMEOUT) do
    begin
      Application.ProcessMessages;
      if Application.Terminated then Exit;
      ms := Tick - GetTickcount;
    end;
  finally
    CloseHandle(Event);
  end;
end;

function FileExistsWait(const AFile: string; const AIntervallMS, ATimeMS: Integer): Boolean;
var
  i: Integer;
begin
  Result := False;

  i := 0;
  while not FileExists(AFile) do
  begin
    MyDelay(AIntervallMS);
    Inc(i, AIntervallMS);
    if i > ATimeMS then
      EXIT;
  end;

  Result := True;
end;

[Uwe Raabe]

Zitat von PeterPanino:

      Application.ProcessMessages;

Da war doch was...

[PeterPanino]

Meinst du, dass Application.ProcessMessages die Delay-Funktion in irgendeiner Weise beeinträchtigt?

[Uwe Raabe]

Zitat von PeterPanino:

Meinst du, dass Application.ProcessMessages die Delay-Funktion in irgendeiner Weise beeinträchtigt?

Das kommt ganz darauf an, welche Events im Application.ProcessMessages denn alle so ausgeführt werden. D.h. was auch immer der User oder das OS so alles an Messages absetzt, wird durch diesen Aufruf ausgeführt und somit die entsprechenden Events in den Forms getriggert. Der Programmfluss ist damit kaum vorhersehbar. Das würde jemand, der lediglich FileExistsWait aufruft, vielleicht nicht erwarten.

[DeddyH]

Ich habe es noch nie benutzt, aber wäre beispielsweise CopyFileEx nicht besser geeignet, da es einen Callback verwendet? Damit könnte man sich das Pollen sparen.

[musicman56]

Hallo,

wenn es darum geht sicherzustellen, dass eine Kopiervorgang abgeschlossen ist, verwende ich meine eigene kleine Kopier-Routine:

Delphi-Quellcode:

type
  TFileOverwriteMode = (fomAlways, fomIfNewer, fomIfOlder, fomIfSameDate);
  TFileCopyCallback  = procedure(ProgressValue: int64) of object;

function RF_SetAllFileDates(FName: string;
                            aCreation,
                            aLastAccess,
                            aLastWrite : TDateTime): boolean;
var
  aHandle: integer;
  FT1, FT2, FT3: TFileTime;
  locFT1, locFT2, locFT3: TFileTime;
  ST1, ST2, ST3 : TSystemTime;
begin
  aHandle := FileOpen(FName, fmOpenWrite or fmShareDenyWrite);
  Result := aHandle >= 0;

  if Result then
  try
    DateTimeToSystemTime(aCreation,ST1);
    DateTimeToSystemTime(aLastAccess,ST2);
    DateTimeToSystemTime(aLastWrite,ST3);

    SystemTimeToFileTime(ST1,FT1);
    SystemTimeToFileTime(ST2,FT2);
    SystemTimeToFileTime(ST3,FT3);

    LocalFileTimeToFileTime(FT1,locFT1);
    LocalFileTimeToFileTime(FT2,locFT2);
    LocalFileTimeToFileTime(FT3,locFT3);

    SetFileTime(aHandle,@locFT1, @locFT2, @locFT3);
  finally
    FileClose(aHandle);
  end;
end;

function RF_CopyFile(SourceName, DestName: string;
                     CopyMode: TFileOverwriteMode;
                     Progress: TFileCopyCallback): boolean;
var
  BytesRead,BytesToRead, P, Percent: Int64;
  SourceStream, DestStream: TFileStream;
  SourceDateTime, DestDateTime: TDateTime;
  Execute: boolean;
begin
  Result := false;
  if not FileExists(SourceName) then exit;
  if not FileAge(SourceName, SourceDateTime) then exit;
  Execute:= true;
  BytesRead := 0;
  Percent := 0;
  P := 0;
  {-DestName darf auch ein Directory sein...dann den Dateinamen ran hängen}
  if DirectoryExists(DestName)
  then DestName := IncludeTrailingBackslash(DestName)+ExtractFileName(SourceName);
  if FileExists(DestName) then begin
    if not FileAge(DestName, DestDateTime) then exit;
    case CopyMode of
      fomAlways     : ;
      fomIfNewer    : Execute := DestDateTime > SourceDateTime;
      fomIfOlder    : Execute := DestDateTime < SourceDateTime;
      fomIfSameDate : Execute := Trunc(DestDateTime) = Trunc(SourceDateTime);
    end;
  end;
  if not Execute then exit;
  SourceStream := TFileStream.Create(SourceName,fmOpenRead or fmShareDenyNone);
  DestStream := TFileStream.Create(DestName,fmCreate);
  try
    if @Progress = nil then begin // so geht es am schnellsten
      DestStream.CopyFrom(SourceStream,SourceStream.Size);
      Result := true; // was soll noch schiefgehen ??
    end else begin // mit Fortschrittanzeige
      Progress(Percent);
      BytesToRead := SizeOf(StreamCopyBuffer);
      if SourceStream.Size < BytesToRead then BytesToRead := SourceStream.Size;
      repeat
        SourceStream.ReadBuffer(StreamCopyBuffer,BytesToRead);
        DestStream.WriteBuffer(StreamCopyBuffer,BytesToRead);
        BytesRead := BytesRead + BytesToRead;
        Percent := (BytesRead * 100) div SourceStream.Size;
        if P <> Percent then begin
          Progress(Percent);
          P := Percent;
        end;
        if (SourceStream.Size - BytesRead) <= BytesToRead
        then BytesToRead := SourceStream.Size - BytesRead;
      until BytesRead >= SourceStream.Size;
      Result := BytesRead = SourceStream.SIZE;
    end;
  finally
    SourceStream.Free;
    DestStream.Free;
  end;
  if Result then RF_SetAllFileDates(DestName, SourceDateTime, SourceDateTime, SourceDateTime);
end;

So nebenbei hab ich eine bessere Kontrolle was mit einer vorhandenen Datei passieren soll.

[Uwe Raabe]

Was habt ihr denn alle mit CopyFile? Es ging doch darum, zu warten, bis eine Datei existiert, oder nicht?

[DeddyH]

Dem Ausgangspost nach zu schließen geht es um das Kopieren (großer) Dateien.

[musicman56]

@Uwe

Das verstehe ich nun wiederum nicht. Es geht doch darum...Zitat vom Thread-Eröffner:

Zitat:

Wenn man aber große Dateien kopiert, kann es unter Umständen passieren....

Also geht es primär um's kopieren...

Wenn man ein Problem (Datei existiert nach Kopieraufruf noch nicht) damit lösen kann, dass man verhindert, dass das Problem auftritt, dann ist das doch optimal...oder etwa nicht?

[Uwe Raabe]

Sowohl CopyFile als auch CopyFileEx sind blockierende Funktionen, die erst dann zurückkommen, wenn der Kopiervorgang abgeschlossen ist. Insofern sollte ein Programm, das erst eine Datei mittels CopyFile (oder TFile.Copy) kopiert und dann weiterverarbeitet, keine Problem mit (noch) nicht existierenden Dateien haben und eine FileExistWait-Routine wäre wohl obsolet.

Ich habe also vermutet, daß der Kopiervorgang von einem anderen Prozess (z.B. Explorer) angestoßen wurde. In dem Fall kann es schon vorkommen, daß man auf die Existenz der Datei warten muss. Es könnte auch sein, daß die Datei nach dem Kopieren noch von einem Virenscanner festgehalten wird, womit aber auch die oben beschriebenen Copy-Ansätze ins Leere laufen würden.

Grundsätzlich habe ich ja auch nicht den Wait-Ansatz an sich in Frage gestellt, sondern lediglich die Nebenwirkungen eines Aufrufs von Application.ProcessMessages zur Diskussion gebracht. Dabei spielt es überhaupt keine Rolle, warum und worauf eigentlich gewartet wird.

Man kann das natürlich machen, muss sich aber darüber in Klaren sein, was das für Auswirkungen hat. Beispiel: der Kopiervorgang wird durch einen Button-Click ausgelöst. Innerhalb des Delay wird ein erneuter Klick ausgeführt. Darf dieser den Kopiervorgang nochmal starten?

Ich weiß nicht, ob jedem besusst ist, was während eines Application.ProcessMessages alles passieren kann. So könnte der Benutzer z.B. das Programm beenden. Das würde im obigen Beispiel zwar vielleicht noch die Delay-Funktion verlassen, aber nicht das FileExistsWait.