Timer Anhalten Während Fenster Verschoben Wird

[terence14]

Hallo liebe DP-Gemeinde,

ich suche nach dem Befehl, mit dem ich feststellen
kann, ob ich gerade das Fenster meiner Anwendungen
in der Caption-Leiste mit dem Mauszeiger festhalte,
um das Fenster zu verschieben / zu bewegen. NICHT
die Größe des Fensters zu ändern!

Weil in meiner Anwendung eine TTimer-Komponente
läuft, die Enabled:=True ist, springt mir das
Fenster immer wieder in die alte Position zurück,
wenn der Timer1.Timer gerade ausgelöst wird

Deshalb versuche ich festzustellen, ob ich das
Fenster gerade "festhalte" um den Timer1.Enabled
in dieser Zeit auf False zusetzen.

MfG,
terence

[CGEu]

Hallo
vielleicht musst du den Timer gar nicht deaktivieren.

wie wärs damit:

Code:

procedure TForm1.FormMouseDown(Sender: TObject; Button: TMouseButton; Shift: TShiftState; X, Y: Integer);
begin
  Inc(nClickCount)
end;

procedure TForm1.FormMouseUp(Sender: TObject; Button: TMouseButton; Shift: TShiftState; X, Y: Integer);
begin
  Dec(nClickCount)
end;

und im Timer

Code:

procedure TForm1.Timer1Timer(Sender: TObject);
begin
  if nClickCount = 0 then
  begin
    // Tu was
  end;
end;

Gruß
Christian

[terence14]

@CGEu

Werd' ich gleich ausprobieren!
Danke...

MfG,
terence

[Paulman]

Funktioniert aber doch nur beim Klick auf die Form, nicht aber beim bewegen mit der Leiste, oder?

[bernerbaer]

Start der Bewegung erkennen:

Delphi-Quellcode:

procedure WMEnterSizeMove(var Message: TMessage) ; message WM_ENTERSIZEMOVE;


procedure TForm1.WMEnterSizeMove(var Message: TMessage) ;
begin
   Timer1.enabled:= false;
end;

Ende der Bewegung erkennen

Delphi-Quellcode:

procedure WMExitSizeMove(var Message: TMessage) ; message WM_EXITSIZEMOVE;


procedure TForm1.WMExitSizeMove(var Message: TMessage) ;
begin
   Timer1.enabled:= true;
end;

[terence14]

Habe ein kleines Test Beispiel geschrieben,

funktioniert nur bei Klick in die Form,
nicht aber beim Klick auf die Caption
des Fensters, um es zu bewegen

Anhang: PStopTimerOnWindowMoving_2013_01_14.zip - 226.238 Bytes

@bernerbaer
Das sieht verdächtig nach Lösung meines Problems aus...
Dankeschön

MfG,
terence

[DeddyH]

Oder in Kombination mit dem anderen Vorschlag oben:

Delphi-Quellcode:

type
  TForm1 = class(TForm)
    ...
  private
    { Private-Deklarationen }
    FMovingOrSizing: Boolean;
    procedure WMEnterSizeMove(var Message: TMessage) ; message WM_ENTERSIZEMOVE;
    procedure WMExitSizeMove(var Message: TMessage) ; message WM_EXITSIZEMOVE;
    ...
  end;

procedure TForm1.Timer1Timer(Sender: TObject);
begin
  if not FMovingOrSizing then
    (* Timercode ausführen *)
end;

procedure TForm1.WMEnterSizeMove(var Message: TMessage);
begin
  FMovingOrSizing := true;
end;

procedure TForm1.WMExitSizeMove(var Message: TMessage);
begin
  FMovingOrSizing := false;
end;

[Paulman]

Funktioniert doch prima, habs nur mal so getestet

Delphi-Quellcode:

type
  TForm1 = class(TForm)

  private
    { Private-Deklarationen }

    procedure WMEnterSizeMove(var Message: TMessage) ; message WM_ENTERSIZEMOVE;
    procedure WMExitSizeMove(var Message: TMessage) ; message WM_EXITSIZEMOVE;

  public
    { Public-Deklarationen }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.WMEnterSizeMove(var Message: TMessage) ;
begin
  Form1.Color:= clGreen;
  Form1.Caption:=('hey, wo willste denn mit mir hin?');
end;


procedure TForm1.WMExitSizeMove(var Message: TMessage) ;
begin
  Form1.Color:= clRed;
  Form1.Caption:=('nu gut..');
end;

end.

Gruß
Paul

[DeddyH]

Zitat von Paulman:

Funktioniert doch prima, ...

Das hat doch auch niemand angezweifelt

[terence14]

So, jetzt funktioniert es,
dank bernerbaer.

Danke Paulman,
danke DeddyH.

Anhang: PStopTimerOnWindowMoving_2013_01_14_okay.zip - 227.422 Bytes

MfG,
terence