Laufwerksangaben aus Listbox verwenden

[Paulman]

Hallo und guten Abend,

ich bastle nun schon eine ganze Weile an einer eigentich einfachen Sache, komme aber mangels Erfahrung nicht weiter.
Folgender Umstand:
Ich lese vorhandene Laufwerke in eine Listbox ein, wo diese dann per Auswahl des jeweiligen Items angesprochen werden sollen.
Das Problem dabei ist nur, dass sich beim Anstecken bzw. Entfernen von USB oder Netzlaufwerken der Index ändert, sodass ich den Wert nicht dem Laufwerk zuordnen kann.
Meines Erachtens müsste ich die Laufwerksbuchstaben temporär speichern, um dann die Zuordnung zu bekommen. Vielleicht bin ich aber auch auf'm Holzweg.
Hier mal kurz was bisher passiert.
Suche nach den Laufwerken:

Delphi-Quellcode:

function DriveExists(DriveByte: Byte): Boolean;
begin
  Result := GetLogicalDrives and (1 shl DriveByte) <> 0;
end;

function DriveType(DriveByte: Byte): String;
begin
  case GetDriveType(PChar(Chr(DriveByte + Ord('A')) + ':\')) of
    DRIVE_UNKNOWN: Result := 'unbekannt';
    DRIVE_NO_ROOT_DIR: Result := 'Laufwerk existiert nicht';
    DRIVE_REMOVABLE: Result := 'Wechselmedium';
    DRIVE_FIXED: Result := 'Festplatte';
    DRIVE_REMOTE: Result := 'Netzwerk';
    DRIVE_CDROM: Result := 'CD-ROM/DVD';
    DRIVE_RAMDISK: Result := 'RAM Disk';
  else
    Result := 'anderer Laufwerkstyp';
  end;
end;

Übertrag an die Listbox:

Delphi-Quellcode:

var
I: Integer;
begin
    for I := 0 to 25 do
    if DriveExists(I) then
    listbox1.Items.Add(Chr(I + Ord('A')) + ':\ (' + DriveType(I) + ')');
end;

Nur um zu gucken ob's bis hier geht, frage ich dann die Items ab:

Delphi-Quellcode:

begin
case ListBox1.ItemIndex of
  0 : ShowMessage('LW C:\');
  1 : ShowMessage('DVD');
  2 : ShowMessage('USB Platte');
end;

Ändert sich nun die Reihenfolge der Laufwerke, ändert sich ja auch der Index.. wie gehe ich das am besten an?
Danke schon mal!
PM

[Klaus01]

Guten Abend,

Windows feuert doch ein WM_DEVICECHANGE event wenn sich z.B. ein USB drive an- bzw. abmeldet.
Auf diese Message kannst Du doch reagieren und Deine Liste anpassen.

Beispiel

Grüße
Klaus

[Paulman]

Danke, guter Ansatz.
Leider ist aber das Problem mit den Netzlaufwerken dabei nicht gelöst, ich denke da kommt kein Event.
Ein richtiges Chaos wirds wenn man Einträge löscht, dann verschiebt sich ja auch alles.
Muss doch einfacher gehen, oder?

[Volker Z.]

Zitat:

Leider ist aber das Problem mit den Netzlaufwerken dabei nicht gelöst, ich denke da kommt kein Event.

Das stimmt so nicht. Windows feuert den WM_DEVICECHANGE Event auch beim mappen bzw. unmappen eines Netzlaufwerks.

Zitat:

Ein richtiges Chaos wirds wenn man Einträge löscht, dann verschiebt sich ja auch alles.

Macht eigentlich keinen Sinn, dass der Anwender Einträge aus der Liste löscht. Oder?

Zitat:

Muss doch einfacher gehen, oder?

Einfacher gehts kaum :

1. Event-Handler ins Form - so wie es Klaus vorgeschlagen hat
2. Im Event-Handler den passenden Event filtern (siehe wParam in der Hilfe). Falls zutreffend Step 3 sonst Step 4
3. ListBox1.Items.Clear und die Liste neu aufbauen
4. Fertig

Es sei denn, ich habe Dein Problem nicht richtig verstanden.


Gruß

[Helmi]

Auch auf die Gefahr hin geschlagen zu werden, es gäbe noch die Möglichkeit einem Item ein Object mit zu geben.
Als Object würde dann ein Index mitgegeben werden, den man auch auslesen kann (siehe Button1Click)

Beispiel:

Delphi-Quellcode:

procedure TForm1.Button1Click(Sender: TObject);
var
  i: Integer;

begin
  i := ListBox1.ItemIndex;

  ShowMessage(Format('%s, Index: %d',[ListBox1.Items.Strings[i], Integer(ListBox1.Items.Objects[i])]));
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  ListBox1.Items.AddObject('Laufwerk A', TObject(1));
  ListBox1.Items.AddObject('Laufwerk B', TObject(2));
  ListBox1.Items.AddObject('Laufwerk C', TObject(3));
end;

oder man speichert sich nen Buchstaben im TObject:

Delphi-Quellcode:

procedure TForm1.Button1Click(Sender: TObject);
var
  i: Integer;

begin
  i := ListBox1.ItemIndex;

  ShowMessage(Format('%s, Buchstabe: %s',[ListBox1.Items.Strings[i], Chr(Integer(ListBox1.Items.Objects[i]))]));
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  ListBox1.Items.AddObject('Laufwerk 1', TObject(Ord('A')));
  ListBox1.Items.AddObject('Laufwerk 2', TObject(Ord('B')));
  ListBox1.Items.AddObject('Laufwerk 3', TObject(Ord('C')));
end;

Aber schön ist was anderes...

[Paulman]

Danke Helmi, ich glaub das isses!

Ich brauche ja das Ergebnis immer nur unmittalbar nachdem die Laufwerke abgefragt wurden, für eine erneute Auswahl wird ja vorher sowieso neu abgefragt und da sind die Laufwerke ja entsprechend vorhanden. Ach ja, und Änderungen während der Laufzeit müssen nicht berücksichtigt werden.

Werd's gleich mal anpassen und testen.

[Paulman]

Hab's jetzt so gelöst:

Delphi-Quellcode:

procedure TForm1.FormCreate(Sender: TObject);
var
I: Integer;
begin
for I := 0 to 25 do
    if DriveExists(I) then
    ListBox1.Items.AddObject(Chr(I + Ord('A')) +':\ (' + DriveType(I) + ')', TObject(I));
end;


procedure TForm1.ListBox1Click(Sender: TObject);
var
i: integer;
begin
  i := ListBox1.ItemIndex;
  ShowMessage(Format('%s, Index: %d',[ListBox1.Items.Strings[i], Integer(ListBox1.Items.Objects[i])]));
end;

So wollte ich das, supi.
Danke und viele Grüße
PM

[Helmi]

auch wenns OffTopic ist - aber hierbei würde sich Format anbieten:
ListBox1.Items.AddObject(Chr(I + Ord('A')) +':\ (' + DriveType(I) + ')', TObject(I)); .

und zwar so:
ListBox1.Items.AddObject(Format('%s:\ (%s)', [Chr(I + Ord('A')), DriveType(I)]), TObject(I));

[Paulman]

Zitat:

auch wenns OffTopic ist - aber hierbei würde sich Format anbieten:
ListBox1.Items.AddObject(Chr(I + Ord('A')) +':\ (' + DriveType(I) + ')', TObject(I)); .

und zwar so:
ListBox1.Items.AddObject(Format('%s:\ (%s)', [Chr(I + Ord('A')), DriveType(I)]), TObject(I));

macht Sinn, danke. An diesen Feinheiten erkennt man halt den Profi und den Dilletanten.
Wenn man nur gelegentlich damit zu tun hat ist das leider so

Frohe Weihnachten
PM