FireMonkey ohne LiveBinding?

[stahli]

Jetzt wollte ich mal einen Navigator von Hand nutzen...
So verweigert er aber direkt seine Arbeit.

Delphi-Quellcode:

procedure TBindNavigatorController.EnableButtons(AButtons: TNavigateButtons; ADataSourceEnabled: Boolean;
  ASetEnabled: TProc<TNavigateButton, Boolean>);
var
  FUpState: TState;
  FDnState: TState;
  FCanModifyState: TState;
  FStateSelected: TState;

...

  function UpEnable: Boolean;
  begin
    if FUpState = stUnknown then
      if ADataSourceEnabled and Selected and not Self.BOF then
        FUpState := stEnable
      else
        FUpState := stDisable;
    Result := FUpState = stEnable;
  end;

...

function TBindNavigatorController.GetBOF: Boolean;
begin
  if Assigned(FScopeNavigator) then  // NIX OHNE Scope
    Result := FScopeNavigator.BOF
  else
    Result := True;

end;

Die Hilfe bezieht sich z.T. auf den VCL-Navigator. Das hilft auch nicht wirklich weiter.

[stahli]

Ich habe mal noch etwas herumgespielt und das TMSFMGrid nun von Hand befüllt.

Das Grid habe ich auf einem eigenen Formular, das ich dann zur Laufzeit in das Hauptformular einbette (wie hier beschrieben - dem TRectangle "Body".Parent wird einfach ein Control aus dem Mainform zugewiesen).

Zum Ausblenden einer Spalte setze ich deren Breite einfach auf 0. Benötigt wird sie aber, da darin die ID verwaltet wird.
Das Grid hält dann Kopien der Daten und bei Änderungen werden diese per SQL in die Datenbank geschrieben.
Ändert sich durch eine Editierung die Reihenfolge der Datensätze, wird der Focus auf die aktuelle Zelle automatisch korrigiert.

Das hat so den Vorteil, dass man alle Steuerungen ganz gut kontrollieren kann. Natürlich ist damit etwas mehr Schreibarbeit verbunden.
Extrem große Tabellen sollte man dann nicht vollständig in das Gitter füllen.

Im Moment habe ich mich an die ersten Regelungen heran getastet und halte den Aufwand des Ansatzes für akzeptabel.
Das Grid kann ja Userbasiert sortiert und gruppiert werden. Anhand der ID in der ersten Spalte kann immer eine Verbindung zur Datenbank hergestellt werden.
Selbst Joins lassen sich darstellen und (da das händisch passiert) sinnvoll in die DB zurück speichern.

Löschen und Einfügen von Datensätzen habe ich noch nicht fertig, das wird sich aber lösen lassen.

Schade, dass der Navigator nicht frei (ohne angebundene Datenmange) verwendbar ist.
Eine direkte Bindung an das Gitter habe ich nicht regeln können (wird wohl nicht gehen).


Falls hier mal jemand eine Anregung entnehmen mag:

Delphi-Quellcode:

unit frmPersonsGrid;

interface

uses
  System.SysUtils, System.Types, System.UITypes, System.Rtti, System.Classes,
  System.Variants, FMX.Types, FMX.Controls, FMX.Forms, FMX.Dialogs,
  FMX.TMSBaseControl, FMX.TMSGridCell, FMX.TMSGridOptions, FMX.TMSGridData,
  FMX.TMSCustomGrid, FMX.TMSGrid, FMX.Objects, Data.Bind.EngExt,
  FMX.Bind.DBEngExt, FMX.TMSGridDataBinding, System.Bindings.Outputs,
  FMX.Bind.Editors, FMX.Layouts, FMX.Bind.Navigator, Data.Bind.Components,
  Data.Bind.Grid, Data.Bind.DBScope, Data.Bind.Controls;

type
  TFormPersonsGrid = class(TForm)
    TMSFMXGridPersons: TTMSFMXGrid;
    Body: TRectangle;
    BindNavigatorPersons: TBindNavigator;
    Button1: TButton;
    procedure TMSFMXGridPersonsGetCellReadOnly(Sender: TObject; ACol, ARow: Integer; var AReadOnly: Boolean);
    procedure TMSFMXGridPersonsCellCheckBoxClick(Sender: TObject; ACol, ARow: Integer; Cell: TFmxObject);
    procedure TMSFMXGridPersonsCellEditDone(Sender: TObject; ACol, ARow: Integer; CellEditor: TFmxObject);
    procedure TMSFMXGridPersonsGetCellProperties(Sender: TObject; ACol, ARow: Integer; Cell: TFmxObject);
    procedure TMSFMXGridPersonsGetCellData(Sender: TObject; ACol, ARow: Integer; var CellString: string);
  private
    FillFlag: Boolean;
  public
    procedure FillGridData(Id: Integer = 0);
    procedure SaveGridData;
  end;

var
  FormPersonsGrid: TFormPersonsGrid;

implementation

{$R *.fmx}

uses dFlyMagicM, Data.SqlExpr;

{ TFormPersonsGrid }

procedure TFormPersonsGrid.FillGridData(Id: Integer = 0);
var
  DS: TSQLDataSet;
  Grid: TTMSFMXGrid;
  C: Integer;
  R: Integer;
begin
  FillFlag := True;
  DS := DataModuleFlyMagicM.PERSONS;
  Grid := TMSFMXGridPersons;
  DS.Close;
  DS.Open;
  Grid.ColumnCount := 4 + 1;
  Grid.RowCount := DS.RecordCount + 1;
  Grid.ColumnWidths[1] := 0;
  Grid.AddCheckBoxColumn(2);
  for C := 1 to DS.Fields.Count do
  begin
    Grid.Cells[C, 0] := DS.Fields[C - 1].FieldName;
  end;
  for R := 1 to Grid.RowCount do
  begin
    if DS.FieldByName('Id').AsInteger = Id then
      Grid.FocusedCell := Grid.SingleCell(Grid.FocusedCell.Col, R);
    for C := 1 to DS.Fields.Count do
    begin
      Grid.Cells[C, R] := DS.Fields[C - 1].AsString;
    end;
    DS.Next;
  end;
  DS.Close;
  FillFlag := False;
end;

procedure TFormPersonsGrid.SaveGridData;
begin
end;

procedure TFormPersonsGrid.TMSFMXGridPersonsCellCheckBoxClick(Sender: TObject; ACol, ARow: Integer; Cell: TFmxObject);
var
  B: Boolean;
  DS: TSQLDataSet;
  Grid: TTMSFMXGrid;
  Id: Integer;
  FieldName: string;
  Value: string;
begin
  if FillFlag then
    Exit;
  if (ARow > 0) and (ACol = 2) then
  begin
    if Cell is TTMSFMXCheckGridCell then
    begin
      B := (Cell as TTMSFMXCheckGridCell).CheckBox.IsChecked;
      DS := DataModuleFlyMagicM.PersonsUpdate;
      Grid := TMSFMXGridPersons;
      Id := StrToIntDef(Grid.Cells[1, ARow], 0);
      FieldName := Grid.Cells[ACol, 0];
      Grid.FocusedCell := Grid.SingleCell(ACol, ARow);
      if B then
        Value := '1'
      else
        Value := '0';
      DS.Close;
      DS.CommandText := 'UPDATE Persons SET ' + FieldName + ' = :Value WHERE Id = :Id';
      DS.ParamByName('Id').AsInteger := Id;
      DS.ParamByName('Value').AsString := Value;
      DS.ExecSQL();
      DS.Close;
      FillGridData(Id);
    end;
  end;
end;

procedure TFormPersonsGrid.TMSFMXGridPersonsCellEditDone(Sender: TObject; ACol, ARow: Integer; CellEditor: TFmxObject);
var
  DS: TSQLDataSet;
  Grid: TTMSFMXGrid;
  Id: Integer;
  FieldName: string;
  Value: string;
begin
  DS := DataModuleFlyMagicM.PersonsUpdate;
  Grid := TMSFMXGridPersons;
  Id := StrToIntDef(Grid.Cells[1, ARow], 0);
  FieldName := Grid.Cells[ACol, 0];
  Value := Grid.Cells[ACol, ARow];
  DS.Close;
  DS.CommandText := 'UPDATE Persons SET ' + FieldName + ' = :Value WHERE Id = :Id';
  DS.ParamByName('Id').AsInteger := Id;
  DS.ParamByName('Value').AsString := Value;
  DS.ExecSQL();
  DS.Close;
  FillGridData(Id);
end;

procedure TFormPersonsGrid.TMSFMXGridPersonsGetCellData(Sender: TObject; ACol, ARow: Integer; var CellString: string);
var
  C: TFmxObject;
begin
  if (ARow > 0) and (ACol = 2) then
  begin
    C := TMSFMXGridPersons.CellControls[ACol, ARow];
    if C is TTMSFMXCheckGridCell then
      (C as TTMSFMXCheckGridCell).CheckBox.IsChecked := (CellString = '1');
    CellString := '';
  end;
end;

procedure TFormPersonsGrid.TMSFMXGridPersonsGetCellProperties(Sender: TObject; ACol, ARow: Integer; Cell: TFmxObject);
begin
  if Cell is TTMSFMXCheckGridCell then
    (Cell as TTMSFMXCheckGridCell).CheckBox.IsChecked := (TMSFMXGridPersons.Cells[ACol, ARow] = '1');
end;

procedure TFormPersonsGrid.TMSFMXGridPersonsGetCellReadOnly(Sender: TObject; ACol, ARow: Integer; var AReadOnly: Boolean);
begin
  AReadOnly := (ACol in [1, 2]);
end;

end.

[Darlo]

Hallo Strahli,

sorry das ich erst jetzt antworte, aber die letzten Tage hatte endlich mal wieder die Familie den Vorrang.
Löschen und Einfügen mache ich über einen Dialog. Ebenso wie Du habe ich die ID in einer Zelle mit width := 0.

Delphi-Quellcode:

   if frmContent.gridVertraege.Cells[6, frmContent.gridVertraege.Selected] <> '' then
      frmDatabase.dbVertragInsert(frmContent.gridVertraege.Cells[6, frmContent.gridVertraege.Selected]);

So kann ich auch in mehrere Tabellen mit einem Eingabedialog schreiben.
Ist eben Tipparbeit und Maskenbau.

[Sir Rufo]

Also ich bin generell kein Freund von der Datenhaltung in Elementen zur Visualisierung.

Wenn ich die Zeile weiß, die gemeint ist, dann weiß ich auch was gemeint ist, denn ich habe diese Zeile gefüllt. Dadurch wird es völlig egal, was dort dargestellt wird und welchen Typ die ID hat.

Vom Konzept her ist das MischMasch.

[Darlo]

Zitat von Sir Rufo:

Vom Konzept her ist das MischMasch.

Also passend zu Firemonkey

[Sir Rufo]

Zitat von Darlo:

Zitat von Sir Rufo:

Vom Konzept her ist das MischMasch.

Also passend zu Firemonkey

FireMonkey ist IMHO kein Mischmasch sondern noch im Beta-Stadium.
Die LiveBindings sind mit der heißen Nadel gestrickt (die sollten wohl einfach nur fertig werden)
Bei dem verzapften Code kräuseln sich einem die Fußnägel

[Stevie]

Zitat von Sir Rufo:

Die LiveBindings sind mit der heißen Nadel gestrickt (die sollten wohl einfach nur fertig werden)
Bei dem verzapften Code kräuseln sich einem die Fußnägel

Die sind einfach nur maßlos over-engineered.

[stahli]

@ Sir

Ja, das sehe ich im Grunde auch so.
Allerdings hat das Konzept auch Vorteile.

Man kann alle möglichen Datenbestände optimal darstellen (wenn man die Grid-Features erst mal vernünftig verstanden hat) und ist nicht auf die Bindung einer einzelnen SQL-Datenabfrage beschränkt.
Auch braucht man (wenn man bei dbExpress bleiben will) kein ClientDataSet und keinen Provider als Vermittler.

Durch die Auslagerung des Grids und seiner kompletten Befüllung und Ereignisbehandlungen in eine eigene Formularunit lässt sich das Ganze sehr gut handeln.

Man hat zwar doch wieder einigen Gluecode aber da man jedes Grid in einer eigenen Unit abwickeln und die ja auch duplizieren kann, ist mir das Ganze gar nicht so unsympatisch.

In Abwägung aller Optionen keine schlechte Lösung.