Eine Generics TObjectList<T> als Parameter

[Stevie]

Da wir einen Typconstraint auf class haben, können wir davon ausgehen dass jedes T eine Klasse ist.
Somit können wir auch gefahrlos einen Hardcast auf TCustomObjectList<TObject> machen (Stichwort: Kovarianz).

Bei der Instanzierung einer Liste, merken wir uns, von welchem Typ T ist.
Dies muss auf Instanzebene gespeichert werden, damit wir auch nach dem zuvor erwähnten Hardcast noch die richtige Klasse herausbekommen.

Delphi-Quellcode:

type
  TCustomObjectList<T: class> = class(TObjectList<T>)
  private
    FItemClass: TClass;
  public
    constructor Create(AOwnsObjects: Boolean = True); overload;
    function AsNonGeneric: TCustomObjectList<TObject>;
    property ItemClass: TClass read FItemClass;
  end;

  TCustomObjectList = TCustomObjectList<TObject>;

function TCustomObjectList<T>.AsNonGeneric: TCustomObjectList<TObject>;
begin
  Result := TCustomObjectList<TObject>(Self);
end;

constructor TCustomObjectList<T>.Create(AOwnsObjects: Boolean);
begin
  inherited Create(AOwnsObjects);
  FItemClass := T;
end;

procedure Test(ObjectList: TCustomObjectList);
begin
  Writeln(objectList.ItemClass.ClassName);
end;

var
  ZahlungsartList: TCustomObjectList<TZahlungsart>;
  Postleitzahlen: TCustomObjectList<TPostleitzahlen>;
begin
  ZahlungsartList := TCustomObjectList<TZahlungsart>.Create;
  Postleitzahlen := TCustomObjectList<TPostleitzahlen>.Create;

  Test(ZahlungsartList.AsNonGeneric);
  Test(Postleitzahlen.AsNonGeneric);
end.

[RWarnecke]

Zitat von Uwe Raabe:

Als globale Prozedur wird das nicht gehen, lediglich als Methode eines Records oder einer Klasse:

Delphi-Quellcode:

  TDummy = record
    class procedure Test<T:class>(ObjectList: TCustomObjectList<T>); static;
  end;


  TDummy.Test<TZahlungsart>(ZahlungsartList);
  TDummy.Test<TPostleitzahlen>(Postleitzahlen);

Kann ich die Test-Procedure auch überladen ? Wenn ja, wie geht das ? Wo kann ich das nachlesen ?

[himitsu]

Was willst du denn überladen?

Aber ja, "overload" funktioniert wie mit jeder normalen Methode auch.


PS: Man kann sich auch aussuchen wo man den generischen Typen deklariert.

Delphi-Quellcode:

  TDummy = record // oder class macht keinen großen Unterschied
    class procedure Test<T:class>(ObjectList: TCustomObjectList<T>); static;
  end;

  TDummy.Test<TZahlungsart>(ZahlungsartList);
  TDummy.Test<TPostleitzahlen>(Postleitzahlen);

  TDummy<T:class> = record // oder class macht keinen großen Unterschied
    class procedure Test(ObjectList: TCustomObjectList<T>); static;
  end;

  TDummy<TZahlungsart>.Test(ZahlungsartList);
  TDummy<TPostleitzahlen>.Test(Postleitzahlen);

Letzeres hat einen Vorteil, wenn man eine Funktion mit einem bestimmten Typen oft aufruft.
Ersteres, wenn man viele Verschiedene Typen nutzt.
Und es läßt sich beliebig kombinieren.

Delphi-Quellcode:

type ZahlDummy = TDummy<TZahlungsart>;

ZahlDummy.Test(ZahlungsartList);

[RWarnecke]

Zitat von himitsu:

Was willst du denn überladen?

Wenn ich inder Procedure noch einen weiteren Parameter einfüge und den zum Beispiel einmal als String und einmal als Integer haben möchte. Beispiel :

Delphi-Quellcode:

  TDummy = record
    class procedure Test<T:class>(ObjectList: TCustomObjectList<T>; ID: Integer); static;
    class procedure Test<T:class>(ObjectList: TCustomObjectList<T>; ID: string); static;
  end;


  TDummy.Test<TZahlungsart>(ZahlungsartList, 1);
  TDummy.Test<TZahlungsart>(ZahlungsartList, '1');

So wie ich es im Beispiel angegeben habe, funktioniert es nicht mit static oder overload. Dieses soll nur ein Beispiel sein um das Überladen zu verstehen.

[himitsu]

overload?



overload = Methode überladen (weitere Deklaration mit anderen Parameter-Typen
virtual = überschreibbar
static = statischer Aufruf (es gibt kein Self)



[add]

Delphi-Quellcode:

  TDummy = record
    class procedure Test<T:class>(ObjectList: TCustomObjectList<T>; ID: Integer); static; overload;  // könnte auch  overload; static;  sein
    class procedure Test<T:class>(ObjectList: TCustomObjectList<T>; ID: string); static; overload;
  end;

oder meinst du

Delphi-Quellcode:

  TDummy = record
    class procedure Test<T:class; T2>(ObjectList: TCustomObjectList<T>; ID: T2); static;
  end;

[RWarnecke]

Delphi-Quellcode:

  TDummy = record
    class procedure Test<T:class>(ObjectList: TCustomObjectList<T>; ID: Integer); static;
    class procedure Test<T:class>(ObjectList: TCustomObjectList<T>; ID: string); static;
  end;


  TDummy.Test<TZahlungsart>(ZahlungsartList, 1);
  TDummy.Test<TZahlungsart>(ZahlungsartList, '1');

Bekomme ich den Fehler

Zitat:

E2254 Overloaded procedure 'Test' must be marked with the 'overload' directive

Ersetze ich jetzt static durch overload , bekomme ich den Fehler

Zitat:

E2398 Class methods in record types must be static

Wenn ich diese Funktion mit ganz normalen Parametern verwende ohne den Record funktioniert ja das overload .

Wie mache ich das ganze richtig ?

[JamesTKirk]

Zitat von RWarnecke:

Ersetze ich jetzt static durch overload , bekomme ich den Fehler

Zitat:

E2398 Class methods in record types must be static

Du musst beide Modifier deklarieren:

static; overload;
oder

overload; static;
(ich weiß jetzt nicht wie rum es deklariert werden muss)

Gruß,
Sven