Gibt es sowas wie einen String-Index bei Propertys?

[Jumpy]

Hallo,

ich habe eine abstrakte Klasse TJob und davon abgeleitet TJob1, TJob2, usw.
Eine Factory/Manager-Klasse bekommt eine Job-ID übergeben und kann in einer Tabelle nachsehen, was für ein Job-Typ das ist und eine entsprechende Klasse erzeugen und als TJob zurückgeben.
Sie soll dabei aber auch die Jobs mit den Parametern versorgen, die die brauchen, um ihre arbeit zu machen. Dazu gibt es zu jeder Jobart eine Tabelle, wobei jede Spalte (von der ID abgesehen) einem Parameter (somit auch Feld/variable der Klasse) entspricht. Ich hätte nun gerne sowas wie:

Delphi-Quellcode:

var t:TJob;
begin
//[...]TJob wird erzeugt[...]

for i:=1 to Query.Fields.Count-1 do
  begin
  t.SetParameter[Query.Fields[i].Fieldname]:=Query.Fields[i].AsString;
  end;

Wie (wenn überhaupt) geht das?

Mir ist klar dass das ganze als Funktion wahrsch. gehen würde ala:
t.SetParameter(Query.Fields[i].Fieldname],Query.Fields[i].AsString);
Aber so als Property mit String-Index sieht das doch netter aus.
Da müsste wahrsch. dann eine virtual Procedure dahinter stehen, die in jeder Klasse entsprechend angepasst wird, oder?

Das ganze soll so eine Art ORM für Arme sein und wäre wahrsch. mit neuerem Delphi auch ein Fall für RTTI, aber ich hab für das Projekt nur D6 zur Verfügung.

[shmia]

Du kannst doch gleich das TField-Object übergeben:

Delphi-Quellcode:

var t:TJob;
begin
//[...]TJob wird erzeugt[...]

for i:=1 to Query.Fields.Count-1 do
begin
  t.AddField(Query.Fields[i]);
end;
....
procedure TJob.AddField(f:TField);
begin
  SetParameter({Name=}f.FieldName, {Value=}f.AsString);
end;

[Blup]

RTTI ist keine Erfindung von Delphi.
Wenn die Unit TypInfo schon vorhanden ist, kann man alles notwendige damit programmieren.
Die Property müssen published sein oder durch Compilerschalter RTTI-Informationen erzeugt werden.

GetPropInfo
GetObjectProp
GetPropValue
SetPropValue

[himitsu]

Das nennt sich Array-Property.

Delphi-Quellcode:

function GetParameter(const ParamName: string): string;
procedure SetParameter(const ParamName: string; const Value: string);
property Parameter[const ParamName: string]: string read GetParameter write SetParameter;

[Jumpy]

Array-Property werd ich mir merken. Scheint so zu funktionieren wie ich wollte. Musste aber die Setter&Getter Funktionen von private nach protected verschieben, weil ich die sonst nicht überschreiben konnte. Kann das sein?

Delphi-Quellcode:

unit uJob;

interface

uses uMSG;

Type TJob = class
  private
  protected
    fMSG:TMSG;
    ID:String;
    function JobInfo:String; virtual;abstract;
    function GetParameter(const ParamName: string): string;virtual;abstract;
    procedure SetParameter(const ParamName: string; const Value: string);virtual;abstract;
  public
    function Execute:Boolean;virtual;abstract;
    procedure Clear;virtual;abstract;
    property MSG:TMSG read fMSG write fMSG;
    property Parameter[const ParamName: string]: string read GetParameter write SetParameter;
  end;

implementation

{ TJob }

end.

[himitsu]

fMSG und fID würde ich dennoch in Private drin lassen.

Nja,
private = nur für micht
protected = auch für meine Nachfahren
public = für jeden
publisched = für die Serialisierung und Co. (z.B. für den FormDesigner/PropertyEditor)

Für Code innerhalb einier Unit ist aber für jeden alles wie public, drum wurde inzwischen (neuere Delphis) strict private und strict protected eingeführt.



Das Selbe nutzen z.B. TStringList ... siehe TStrings.Values.
Und die Anzahl oder Art der Array-IndizeParameter ist nicht beschränkt.


PS: Nur bei den Default-Property muß man aufpassen, den der Zusatz "Default" ist doppelt belegt.

Delphi-Quellcode:

property Index: Integer read x write x default 132; // der FormDesigner speichert den Wert nur dann in der DFM, wenn er nicht 123 ist.

property Irgendwas[idx: Integer]: string read x write x; default;  // hier kann man auch ohne Namen drauf zugreifen ... siehe TStrings.Strings

var
  SL: TStringList;

SL.Strings[123] := SL[123];

[Bummi]

Sind die Parameterdaten alle vom gleichen Datentyp, sonst könnte der Ansatz von Blub der interessantere sein.