Export nach Excel

[joehoehal]

Das mit der CSV-Datei isr zwar einfach, aber umständlich, weil man die dann manuell in Excel laden und nachträglich formatieren muss.

[Bummi]

Nein, Du kannst das ganze in einer Stringlist aufbauen, den Text in die Zwischenablage legen und per OLE einfügen.

Delphi-Quellcode:

clipboard.Settextbuf(Pchar(sl.Text));
FWorkBook.ActiveSheet.Paste;
FWorkBook.ActiveSheet.Columns.EntireColumn.AutoFit;

// folgendes wenn Du die Header mit ausgibst
FExcel.Rows.Item[0].Select;
FExcel.Selection.Interior.Color  := Color;
Fexcel.ActiveWindow.FreezePanes := False;
Fexcel.Cells[0,1].Select;
Fexcel.ActiveWindow.FreezePanes := True;

[himitsu]

Und Eines ist Fakt:
Die CSV-Importer von Excel und Open Office sind nicht "leicht" zu bediehnen. (jedenfalls nicht von Jedermann)

[Furtbichler]

Zitat von himitsu:

Und Eines ist Fakt:
Die CSV-Importer von Excel und Open Office sind nicht "leicht" zu bediehnen. (jedenfalls nicht von Jedermann)

Also ich finde 'Doppelklick' ziemlich leicht. Klappt jedenfalls bei meinem EXCEL.

[himitsu]

Wenn du dann noch aufpassen mußt, wie importiert werden soll, dann isses nicht so einfach.

, oder ; oder Tab oder ... als Trennzeichen
exklusive Trennzeichen (Leerzeichen trennen nicht)
Dezimalkomma oder Dezimalpunkt (ja, es gibt immer wieder CSVs, wo Kommas drin vorkommen)
usw.

[Furtbichler]

Zitat von himitsu:

Wenn du dann noch aufpassen mußt, wie importiert werden soll, dann isses nicht so einfach.

Dazu ist doch CSV gar nicht gedacht, menno.
CSV ist nur gut, wenn die Windows-Versionen aus dem gleichen Land kommen (bzw. identische Listen-, Dezimal- und Datumstrennzeichen sowie das identische Datumsformat besitzen. Es eignet sich also quasi nur abteilungsintern oder für kleine Betriebe.

Zitat:

ja, es gibt immer wieder CSVs, wo Kommas drin vorkommen)
usw.

Ja natürlich. z.B. alle chinesischen und amerikanischen verwenden das Komma als Trennzeichen und alle deutschen CSV-Dateien das Komma als Dezimaltrenner.

Wie gesagt: Solange Du im gleichen Land bleibst, hast Du 0 Probeme. Sonst wird es albern (also z.B. US-CSV in Deutschland importieren usw.). Aber was erzähl ich Dir das, Du weisst das ja.

[Bummi]

mit den Routinen aus #17 für den Weg über die Zwischenablage hatte ich mit folgendem Code bisher keinen Ärger (gegf. müsste #9 ausgesiebt werden)

Delphi-Quellcode:

Function GetAds4Excel(ads:TAdoDataset):String;
var
  sl:TStringList;
  s:String;
  i:Integer;
  Procedure ClipIt;
    begin
      s := Copy(s,1,length(s) - 1);
      sl.Add(s);
      s := '';
    end;
begin
  sl:=TStringList.Create;
  try
  s := '';
  For i := 0 to ads.FieldCount - 1 do
    begin
      if ads.Fields[i].Visible then s := s + ads.Fields[i].DisplayLabel + #9;
    end;
  ClipIt;
  while not Ads.Eof do
    begin
      For i := 0 to ads.FieldCount - 1 do
        begin
          if ads.Fields[i].Visible then s := s + ads.Fields[i].DisplayText + #9;
        end;
    ClipIt;
    Ads.Next;
    end;
  Result := sl.Text;
  finally
  sl.Free;
  end;
end;

[himitsu]

Wobei die Stringliste noch viel mehr Features bietet.

Delphi-Quellcode:

function GetAds4Excel(ads: TAdoDataset): string;
var
  sl, sl2: TStringList;
  i:       Integer;
begin
  sl := TStringList.Create;
  sl2 := TStringList.Create;
  try
    sl2.Delimiter := #9;
    for i := 0 to ads.FieldCount - 1 do
      if ads.Fields[i].Visible then
        sl2.Add(ads.Fields[i].DisplayLabel);
    sl.Add(sl2.DelimitedText);
    Ads.First;
    while not Ads.Eof do begin
      sl2.Clear;
      for i := 0 to ads.FieldCount - 1 do
        if ads.Fields[i].Visible then
          sl2.Add(ads.Fields[i].DisplayText);
      sl.Add(sl2.DelimitedText);
      Ads.Next;
    end;
    //sl.LineBreak := #10;
    Result := sl.Text;
  finally
    sl2.Free;
    sl.Free;
  end;
end;

Und wenn man will, kann man auch noch die Enumeratoren ausnutzen.

Delphi-Quellcode:

function GetAds4Excel(ads: TAdoDataset): string;
var
  sl, sl2: TStringList;
  F:       TField;
begin
  sl := TStringList.Create;
  sl2 := TStringList.Create;
  try
    sl2.Delimiter := #9;
    for F in ads.Fields do
      if F.Visible then
        sl2.Add(F.DisplayLabel);
    sl.Add(sl2.DelimitedText);
    Ads.First;
    while not Ads.Eof do begin
      sl2.Clear;
      for F in ads.Fields do
        if F.Visible then
          sl2.Add(F.DisplayText);
      sl.Add(sl2.DelimitedText);
      Ads.Next;
    end;
    //sl.LineBreak := #10;
    Result := sl.Text;
  finally
    sl2.Free;
    sl.Free;
  end;
end;

Damit optimiert man sogar noch die vielen Stringconcatinierungen, bzw. das Speichermanagement, welches nur noch einmal pro Zeile alles zusammenfügt und nicht bei jedem einzelnem Wert.

Mit der selben Technik lassen sich auch CSVs erstellen oder auslesen, wobei das ja schon eine CSV ist, nur eben mit Tabulator als Trennzeichen.