String Code überprüfen

[DeddyH]

Zitat von p80286:

Du solltst diese dan von 0.. .count durchgehen

0.. .count - 1

[idefix2]

Mit dem regex "^O(\d+)" habe ich alle Prüfungen erschlagen und schon den reinen Ziffernstring in match[1] gespeichert, dann einfach ein strtoint(match[1]) (nicht einmal trystrtoint ist nötig, weil in match[1] steht sicher eine Ziffernfolge, wenn regexmatch erfolgreich war). Wenn man will, kann man sogar leicht die Anzahl der Ziffern auf maximal 4, 5 oder irgend etwas sinnvolles beschränken, gefolgt vom Zeilenende oder einem Zeichen, das keine Ziffer ist, um sicherzustellen, dass kein Überlauf bei der String-Konvertierung erfolgt, es könnte ja auch eine Zeile: O1234567891234567891234567891234567891234567891234 56789+- dazwischenrutschen. Der Regex schaut dann einfach so aus: "^O(\d{1,5})(\D|$)"

Wie mühsam das Ganze auf die Klassische Art ist (und in Wirklichkeit auch insofern schlecht lesbar, als nicht auf den 1. Blick sichtbar ist, was genau in Sonderfällen passiert), siehst Du schon daran, dass auch diese schon recht komplizierte Variante nicht ausreicht: Was ist, wenn weder "+" noch "-" auf die Zahl, sondern ein anderes Zeichen folgt - es geht übrigens aus der Beschreibung nicht klar hervor, ob z.B. O17abc-+ erlaubt oder verboten wäre?

Wenn nur + oder - oder das Zeilenende auf die Ziffern folgen darf, aber kein anderes Zeichen, dann ändere ich den Regex einfach auf "$O(\d{1,5})([+-]|$)". Wenn ich so eine Änderung mit klassischer Programmierung machen will, dann muss ich bei jeder Kleinigkeit am code selbst basteln und über die richtige Abfolge der Abfragen tüfteln.

Noch dazu ist die klassische Programmierung durch die schiere Codemenge fehleranfälliger, hier müsste z.B. die letzte Abfrage if pos('+',satz)>0 then statt if pos('-',satz)>0 then lauten, das ist sicher beim copy & paste untergegangen.

[p80286]

Zitat von DeddyH:

Zitat von p80286:

Du solltst diese dan von 0.. .count durchgehen

0.. .count - 1

Omnia mea culpa, omnia maxima culpa

salve

Carolus

[DeddyH]

Wer ohne Fehler ist, der werfe das erste Schwein (oder so ähnlich)

[Amateurprofi]

Hallo lemomo,

wie Bummi schon ausdrückte ist deine Beschreibung des Problems recht dürftig.

Du schriebst in #1
"Es muss auch überprüft werden ob unser String auf die erste Reihe geschrieben ist"
In #8 schriebst du
"d.h vor der O1- oder O3 muss nicht leer sein"

Den Satz aus #1 interpretiere ich so, dass die "Oxx" linksbündig angeordnet sein müssen.
Dagegen den Satz aus #8 verstehe ich so, dass davor Leerzeichen stehen dürfen.

Wie auch immer, da mich das interessierte, habe ich eine Prozedur geschrieben, die die Prüfungen ausführt.

Ist etwas länger, dafür recht flink. Für eine 25 MB Datei < 100 ms.

Delphi-Quellcode:

PROCEDURE CheckText(const s:string; CheckLeadingBlanks:boolean);
var p:PChar;
PROCEDURE NextLine;
begin
   while not CharInSet(p^,[#0,#10,#13]) do inc(p);
   while CharInSet(p^,[#10,#13]) do inc(p);
end;
FUNCTION ReadNumber:integer;
const max1=MaxInt div 10; max2=MaxInt-max1*10;
var c:integer;
begin
   result:=0;
   while CharInSet(p^,['0'..'9']) do begin
      c:=Ord(p^)-Ord('0');
      if (result>max1) or ((result=Max1) and (c>max2)) then
         raise Exception.Create('Zahlenüberlauf');
      result:=result*10+c;
      inc(p);
   end;
end;
FUNCTION Find_Ox(var value:integer):boolean;
var HasLeadingBlanks:boolean;
begin
   repeat
      hasleadingblanks:=p^=' ';
      while p^=' ' do inc(p); // Blanks am Zeilenanfang übergehen
      if p^='O' then begin  // O gefunden
         inc(p);
         if CharInSet(p^,['0'..'9']) then begin
            value:=ReadNumber;
            if CheckLeadingBlanks and HasLeadingBlanks then
               raise Exception.Create('"O'+IntToStr(value)+'" ist nicht linksbündig.');
            NextLine;
            Exit(true);
         end else begin
            raise Exception.Create('Keine Ziffer hinter "O".');
         end;
      end;
      NextLine;
   until p^=#0;
   result:=false;
end;
var n,k:integer; ss:string;
begin
   p:=@s[1];  // Zeigt auf erstes Zeichen im String
   try
      if not Find_Ox(n) then
         raise Exception.Create('Kein "O" gefunden, dem eine Zahl folgt');
      while Find_Ox(k) do
         if k=n+1 then begin
            n:=k
         end else begin
            ss:='Nach "O'+IntToStr(n)+'" folgt "O'+IntToStr(k)+'".';
            raise Exception.Create(ss);
         end;
      ShowMessage('OK');
   except
      on E:Exception do ShowMessage(E.Message);
   end;
end;

procedure TForm1.Button1Click(Sender: TObject);
var list:TStrings;
begin
   list:=TStringList.Create;
   try
      try
         list.LoadFromFile('text1.txt');
         CheckText(list.Text,false);
      except
         On E:Exception do ShowMessage(E.Message);
      end;
   finally
      list.free;
   end;
end;

[idefix2]

Und unter Verwendung von regex wird daraus dann ungefähr so etwas:

Delphi-Quellcode:

PROCEDURE Checkfile(const fn:string);

var 
rgx: TRegexpr;
newnumber,oldnumber: integer;
f: textfile;
s: string;

begin
assign(f,fn); reset(f);
rgx:=TRegexpr.Create;
rgx.Expression:='^O(\d{1,5})([+-]|$)';
oldnumber:=0;

while not eof(f) do
  begin readln(f,s);
  if rgx.exec(s)
  then begin 
       newnumber := StrToInt(rgx.Match[1]);
       if newnumber <> oldnumber+1
       then Showmessage ('Out of sequence: '+rgx.Match[1]);
       oldnumber := newnumber;
       end;
  end;
rgx.free;
end;

[Amateurprofi]

Zitat von idefix2:

Und unter Verwendung von regex wird daraus dann ungefähr so etwas:

Delphi-Quellcode:

PROCEDURE Checkfile(const fn:string);

var 
rgx: TRegexpr;
newnumber,oldnumber: integer;
f: textfile;
s: string;

begin
assign(f,fn); reset(f);
rgx:=TRegexpr.Create;
rgx.Expression:='^O(\d{1,5})([+-]|$)';
oldnumber:=0;

while not eof(f) do
  begin readln(f,s);
  if rgx.exec(s)
  then begin 
       newnumber := StrToInt(rgx.Match[1]);
       if newnumber <> oldnumber+1
       then Showmessage ('Out of sequence: '+rgx.Match[1]);
       oldnumber := newnumber;
       end;
  end;
rgx.free;
end;

In #5 sagtest du "ist es praktisch immer viel bequemer, eine Regex Unit einzubinden".
Frage : Welche denn ?
Ich habe versucht das nachzuvollziehen und habe die System.RegularExpressions eingebunden.
Die kennt aber kein "TRegexpr.Create" (aber ein TRegEx.Create, bei dem als Parameter der Suchtext mitgegeben wird).
Sie kennt auch kein "rgx.Match[1]".

Mal unabhängig davon, wird damit nicht das erreicht, was lemomo wollte.
Zum Beispiel kann nicht geprüft werden, ob da vielleicht ein Oxx nicht am Zeilenanfang steht.
Ein weiteres Problem, nämlich Oxx zu finden, bei denen das xx nicht direkt dem "O" folgt wird ebenfalls nicht gelöst.

Aber trotzdem würde ich das gern mal testen, deshalb die Bitte, mal das "eine RegEx Unit" zu präzisieren. Danke.

[dunningkruger]

Wurde in idefix2 #16 nicht ein FileClose vergessen?

Interessiere mich so langsam auch für einen RegEx-Link (unit oder Komponente mit Doku) für Delphi 5.

Ggf. Danke!

[idefix2]

Ich weiss nicht mehr, wo genau ich diese Regex Implementierung gefunden habe. Sie ist gratis und darf frei verteilt werden, ich habe sie jetzt hochgeladen. Sie kann leider nicht alles, was die Perl Regex Syntax erlaubt, aber die Einschränkungen sind nicht schlimm. Ich bin z.B. einmal darüber gestolpert, dass (?:...) nicht möglich ist. Nicht auszuschliessen, dass die Version, die bei Delphi-XE2 dabei ist, besser ist (aber wohl auch etwas anders in der Handhabung). Dass der Regex-String gleich beim Create als Parameter mitgegeben werden kann, gefällt mir z.B. besser als bei meiner Regex-Klasse. Ich habe nur Delphi 2009, da ist von Emba aus kein Regex dabei.

Zitat:

Zum Beispiel kann nicht geprüft werden, ob da vielleicht ein Oxx nicht am Zeilenanfang steht.

Wenn ein Oxx nicht am Zeilenanfang steht, wird es ignoriert, und ich denke, das ist in Ordnung, weil es könnte ja irgendwo mitten im Text zufällig Oxx vorkommen, das gilt dann eben nicht. Wenn es doch gelten sollte und irrtümlich nicht am Zeilenanfang steht, würde dann das nächste Oxx einen Out-of-Sequence Fehler produzieren.

Zitat:

Ein weiteres Problem, nämlich Oxx zu finden, bei denen das xx nicht direkt dem "O" folgt wird ebenfalls nicht gelöst.

Sollte das laut Beschreibung erlaubt sein? Wenn ja, könnte man das mit einer einfachen Änderung des regex-Strings lösen (Einfügen von \D* nach dem O), ohne am Programm irgend etwas zu verändern.

Zitat:

Wurde in idefix2 #16 nicht ein FileClose vergessen?

Ja, wurde. Mea culpa.

Ob die Unit mit D5 kompatibel ist, kann ich leider nicht sagen. Ich verwende D2009. Ich fürchte, da wird die geänderte String-Implementierung Probleme schaffen.

[dunningkruger]

@idefix2: Danke, schau ich mir an!