FindWindow von Pfad

[Premaider]

Ist es möglich bei Delphi7 einen Fensternamen eines Programmes anhand dessen .exe-Pfad herrauszufinden ? Wenn ja wie ?
Für einen fetzen Sourcecode wäre ich dankbar

[jaenicke]

Du kannst mit EnumWindows die Liste der Fenster durchgehen und mit GetWindowThreadProcessId herausfinden, zu welchem Prozess dieses Fenster gehört.

[Premaider]

Zitat von jaenicke:

Du kannst mit EnumWindows die Liste der Fenster durchgehen und mit GetWindowThreadProcessId herausfinden, zu welchem Prozess dieses Fenster gehört.

Ich verstehe die msdn-Beispiele nie wirklich. Könnest du mir ein Beispiel geben ?

[DeddyH]

Ähnliches Problem samt Lösungsvorschlägen: http://www.delphipages.com/forum/showthread.php?t=96891

[Premaider]

Zitat von DeddyH:

Ähnliches Problem samt Lösungsvorschlägen: http://www.delphipages.com/forum/showthread.php?t=96891

Das Problem ist dort wird die exe anhand des Handles gesucht. Ich suche das Handle anhand der exe

[DeddyH]

Der Vergleich ist aber doch derselbe. Ob Du nun von links oder von rechts kommst, dürfte doch egal sein.

[jaenicke]

Zitat von Premaider:

Ich verstehe die msdn-Beispiele nie wirklich. Könnest du mir ein Beispiel geben ?

Was hast du denn versucht?

Beispiele findet man eigentlich bei Google genug:
delphi enumwindows
z.B. ausführlich kommentiert:
http://delphi.about.com/od/windowssh.../aa080304a.htm

[Premaider]

Ich habe erst seit einem halben Jahr Informatik und seit ca. 1/4 Jahr programmieren. Es ist für mich schon schwer zu verstehen wie ich die beiden Funktionen überhaupt benutze und mit einander verbine. Für mich wäre es am einfachsten einen Sourcecode zu sehen in den ich nurnoch meinen Pfad einsetzten müsste und am Ende den Fensternamen herausbekommen würde

[DeddyH]

Dafür gibt es die Forensuche (EnumWindows, GetWindowThreadProcessID, CreateToolHelp32Snapshot). Wenn Du Dir eine Aufgabe suchst, die (momentan) einige Nummern zu hoch für Dich ist, so kann es nicht die Lösung sein, Dir diese komplett auf dem Silbertablett zu servieren, dabei lernst Du ja nichts.

[edit] Wenn Du es selbst versuchst und dabei steckenbleibst, helfen wir natürlich gerne weiter, nicht, dass wir uns da missverstehen. [/edit]

[DeddyH]

Ich habe soeben feststellen müssen, dass das Ganze wohl wirklich nicht so ganz ohne ist. Daher habe ich 2 Hilfsfunktionen geschrieben, ich hoffe, das hilft zunächst weiter, Fehler sind natürlich vorbehalten.

Delphi-Quellcode:

uses TLHelp32, PsAPI;

function ExeNameFromProcessID(ID: Cardinal): string;
var
  ProcessHandle: THandle;
begin
  Result := '';
  ProcessHandle := OpenProcess(PROCESS_QUERY_INFORMATION or PROCESS_VM_READ,
    false, ID);
  if ProcessHandle <> 0 then
    try
      SetLength(Result, MAX_PATH);
      if GetModuleFileNameEx(ProcessHandle, 0, PChar(Result), Length(Result)) <> 0 then
        SetLength(Result, StrLen(PChar(Result)));
    finally
      CloseHandle(ProcessHandle);
    end;
end;

procedure ListExeNamesAndIDs(const ResultList: TStrings);
var
  PE: TProcessEntry32;
  Snap: THandle;
  ExeName: string;
begin
  Assert(Assigned(ResultList));
  ResultList.BeginUpdate;
  try
    ResultList.Clear;
    Snap := CreateToolHelp32Snapshot(TH32CS_SNAPPROCESS, 0);
    PE.dwSize := SizeOf(PE);
    if Snap <> 0 then
      try
        if Process32First(Snap, PE) then
          repeat
            ExeName := ExeNameFromProcessID(PE.th32ProcessID);
            if ExeName <> '' then
              ResultList.AddObject(ExeName, TObject(PE.th32ProcessID));
          until not Process32Next(Snap, PE);
      finally
        CloseHandle(Snap);
      end;
  finally
    ResultList.EndUpdate;
  end;
end;

Für Dich von Belang ist dabei ListExeNamesAndIDs. Der übergibst Du ein TStrings-Objekt (Stringliste, ListBox.Items, ComboBox.Items oder Ähnliches), und dieses sollte nach dem Aufruf die kompletten Pfade zu den laufenden Prozessen sowie deren ProcessID (im Object-Feld hinterlegt) enthalten. Diese Liste kannst Du nun nach dem gesuchten Pfad filtern, die ProcessID auslesen und zum Vergleich für EnumWindows und GetWindowThreadProcessID heranziehen. Wenn ich keinen Denkfehler mache/gemacht habe, sollte das eigentlich funktionieren.