InsertSort

[Overprogrammer]

Hallo Leute, ich hab ein Problem ich hab hier den Quelltext für ein insertionSort-Programm aber ich krieg nicht angepasst so das ich die Zahlen per editfeld eingeben und die sortierten Daten in einer Listbox ausgegeben werden...
LG Overprogrammer

Delphi-Quellcode:

 for i:= 1 to 6 do
  if (a[i]<a[i-1]) then
  begin
    j:= i;
    tmp := a[i];
    while (j > 0) and (a[j-1] > tmp) do
    begin
      // Verschieben:
      a[j]:= a[j-1];
      Dec(j);
    end;
    a[j]:= tmp;
end;

[Furtbichler]

Zitat von Overprogrammer:

...aber ich krieg nicht angepasst so das ich die Zahlen per editfeld eingeben und die sortierten Daten in einer Listbox ausgegeben werden...

Stimmt. Laut Code hast Du ja auch noch nichts versucht. Und wer noch nichts versucht hat, kriegts auch nicht hin.

Wie lautet eigentlich deine Frage?

PS: Ist das eine Hausaufgabe?

[busybyte]

Auf Arrays würde ich ganz verzichten und Pointer nehmen und
Arbeite dann mit TList und lass diese Liste sortieren, das geht wesentlich schneller.

http://www.delphipraxis.net/147610-d...schreiben.html

Delphi-Quellcode:

Type PMeinTyp=^TMeinTyp;
TMeinTyp=Record
i1:integer;
s1:String;
//usw.
End;



procedure ShowData(aList:Tlist);
Var cnt1:integer;
begin
if not Assigned(aList) then
 exit;

with Form1.ListBox1 do
begin
 try
 items.BeginUpdate;
 Clear;

   for cnt1:=0 to aList.Count-1 do
    with PMeinTyp(aList[cnt1])^ do
     Items.Add(inttostr(i1)+','+s1);
 finally
 items.EndUpdate;
 end;
end;
end;

Procedure AddMeinTyp(Var aList:TList;X:integer;irgendwas:String);
Var
Tmp:PMeinTyp;
begin
  try
   if not Assigned(aList) then
    aList:=TList.Create;
  Tmp:=New(PMeinTyp);
  Tmp.i1:=X;
  Tmp.s1:=irgendwas;
  aList.Add(Tmp);
  except
  FreeandNil(aList);
  end;
end;

function MySortInteger(Item1, Item2: Pointer): Integer;
begin
  Result := Integer(Item1^) - Integer(Item2^);
end;

procedure TForm1.Button1Click(Sender: TObject);
Var
i,cnt1:integer;
S:String;
DieListe:TList;
begin
 try
  Randomize;

   for cnt1 := 0 to 10000 do
    begin
    i:=random(cnt1);
    AddMeinTyp(DieListe,i,' irgendwas '+inttostr(i));
    end;
  ShowData(DieListe);

  showMessage('Sortieren');
  DieListe.Sort(@MySortInteger);
  ShowData(DieListe);
  showMessage('Fertig');
 
 finally
  if Assigned(DieListe) then
   FreeandNil(DieListe);
 end;
end;

[p80286]

Zitat von Furtbichler:

Zitat von Overprogrammer:

...aber ich krieg nicht angepasst so das ich die Zahlen per editfeld eingeben und die sortierten Daten in einer Listbox ausgegeben werden...

Stimmt. Laut Code hast Du ja auch noch nichts versucht. Und wer noch nichts versucht hat, kriegts auch nicht hin.

Wie lautet eigentlich deine Frage?

PS: Ist das eine Hausaufgabe?

Was denn sonst?

Zitat von busybyte:

Auf Arrays würde ich ganz verzichten und Pointer nehmen und
Arbeite dann mit TList und lass diese Liste sortieren, das geht wesentlich schneller.

Ob da der Lehrer mit einverstanden wäre?

Gruß
K-H

[Bjoerk]

Fragt man sich allerdings, ob es nicht besser wäre, gar nicht abzugeben, als den Speicherleckcode #3.

[busybyte]

OT:
Ständig diese Überbewertung von Speicherlecks, manche haben halt an allem was auszusetzen.
Ich habe in mehr als 15 Jahren, effektiv nichts von Speicherlecks bemerkt.
Wenn es nicht Tools dafür gäbe diese festzustellen, würde ich nichtmal wissen das es die gibt,
was nicht bedeuten soll das auch ich versuche sie gering zu halten aber man muß es auch nicht übertreiben.


Wenn ich hier Codeschnipsel reinstelle will ich, wie die meisten Anderen hier auch, zu bestimmten Problemen Denk-/Lösungsansätze geben und kein copy/paste mein Programm ist fertig.
Mir persönlich haben solche Code-Post's (auch wenn sie "nur mal eben" quick and dirty waren) mehr geholfen als die vielen Nörgler, die nur ihre persönliche Meinung und sonst nichts zum Besten geben.

[Bjoerk]

BusyByte, meine Posts sind grundsätzlich nie böse oder persönlich gemeint. Du benutzt new ohne dispose, das produziert halt Speicherlecks. Des weitern ist der Code gelinde gesagt ziemlich unstrukturiert und trennt auch nicht Logik von Darstellung und hat auch mit der Frage des TE nichts zu tun. Dein Hinweis, hier TList statt ein Array zu benutzen ist fast schon aberwitzig, benutzt TList intern doch ein statisches Array. Die Frage bezog sich auch den Insertsort, TList benutzt den Quicksort. Anyway, nicht für ungut.

Da du mir vorwirfst, hier nur herumnörgeln und sonst nichts zum Besten geben, hier mein Vorschlag. Wie gesagt, hat mir der Frage des TE nicht zu tun, exklusiv für dich:

Delphi-Quellcode:

unit AUnit;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  PRecordTyp = ^TRecordTyp;

  TRecordTyp = record
    I1: integer;
    S1: String;
  end;

  TForm1 = class(TForm)
    Button1: TButton;
    ListBox1: TListBox;
    Button2: TButton;
    procedure Button1Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure Button2Click(Sender: TObject);
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

function CompareByI1(const Item1, Item2: PRecordTyp): integer;
begin
  Result := 0;
  if Item1^.I1 > Item2^.I1 then
    Result := 1
  else
    if Item1^.I1 < Item2^.I1 then
      Result := -1
end;

function CompareByS1(const Item1, Item2: PRecordTyp): integer;
begin
  Result := 0;
  if Item1^.S1 > Item2^.S1 then
    Result := 1
  else
    if Item1^.S1 < Item2^.S1 then
      Result := -1
end;

procedure AddItem(const List: TList; const I1: integer; const S1: string);
var
  P: PRecordTyp;
begin
  P := New(PRecordTyp);
  P.I1 := I1;
  P.S1 := S1;
  List.Add(P);
end;

procedure DelItem(const List: TList; const Index: integer);
var
  P: PRecordTyp;
begin
  P := List.Items[Index];
  Dispose(P);
  List.Delete(Index);
end;

procedure FillList(const List: Tlist);
const
  N = 10000;
var
  I, I1: integer;
  S1: string;
begin
  for I := 1 to N do
  begin
    I1 := Random(N);
    S1 := IntToStr(Random(N));
    AddItem(List, I1, S1);
  end;
end;

procedure FillListBox(const List: Tlist; const ListBox: TListBox);
var
  I: integer;
  P: PRecordTyp;
begin
  ListBox.Items.BeginUpdate;
  ListBox.Clear;
  try
    for I := 0 to List.Count - 1 do
    begin
      P := List[I];
      ListBox.Items.Add(IntToStr(P^.I1) + ' - ' + P^.S1);
    end;
  finally
    ListBox.Items.EndUpdate;
  end;
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  List: TList;
begin
  List := TList.Create;
  try
    FillList(List);
    List.Sort(@CompareByI1);
    FillListBox(List, ListBox1);
    while List.Count > 0 do
      DelItem(List, List.Count - 1);
  finally
    List.Free;
  end;
end;

procedure TForm1.Button2Click(Sender: TObject);
var
  List: TList;
begin
  List := TList.Create;
  try
    FillList(List);
    List.Sort(@CompareByS1);
    FillListBox(List, ListBox1);
    while List.Count > 0 do
      DelItem(List, List.Count - 1);
  finally
    List.Free;
  end;
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  Randomize;
end;

end.