Probleme mit onClick procedure

[Satyr]

Hi,

ich habe mein dynamisch erzeugtes TMenuItem. Das zuweisen von Eigenschaften usw. funktioniert wunderbar.
Ich stecke aber beim zuweisen des onClick Ereignisses Fest. Eine Procedure kann ich hier problemlos hinterlegen - solange sie keine Übergabewerte hat.

Also folgendes funktioniert:

ASub.OnClick := meineProcedure;
Die Procedure dazu ist in folgendem Format deklariert:
procedure meineProcedure(Sender:TObject); Nun würde ich an die Procedure aber noch gerne zusätzlich einen String übergeben.
Wie mache ich das? Einfach die Parameterliste erweitern funktioniert nicht, das wäre wohl auch zu einfach.
Jemand ne Idee?

Gruß,
Andreas

[mkinzler]

Müsste man über das Senderobjekt machen. Wenn es ein Integer wäre infach im Tag. so müsstest du dort eine Pointer auf den Inhalt ( in diesem Fall den String oder einer datenstruktur) hinterlegen.

[himitsu]

Jupp, genau für solche Zusatzinformationen ist TComponent.Tag oder das Objekts in einer StringListe, bzw. in einer TListBox da.

Woher soll denn das OnClick die Info hernehmen, welche sie für dich senden soll, wenn man draufklickt? Du rufst das OnClick ja vermutlich nicht selber (manuell) auf.


Der Sender ist das Item, von welchem die Nachricht kommt und schon kann man darüber auf .Tag zugreifen.

[Satyr]

Ok, das hab ich befürchtet. Aus irgendeinem Grund ist mir .Tag Suspekt, deshalb hatte ich gehofft es geht auch anders... eben mit konkreter Stringübergabe.
Aber dann mache ich es halt im Tag, danke .

[mjustin]

Ab Delphi 2009 ist ein TDictionary dafür ideal. Wenn man zum Beispiel zu jeder Komponente nur einen String zwischenspeichern will, kann man sich den Datenspeicher so deklarieren und erzeugen:

Delphi-Quellcode:

var
  ZusatzInfo : TObjectDictionary<TComponent, string>;
begin
  ZusatzInfo := TObjectDictionary<TComponent, string>.Create;

Und dann speichern:

  ZusatzInfo.Add(Button1, 'Infotext zu Button 1');
Lesen:

Text := ZusatzInfo[Button1]; // Text enthält jetzt 'Infotext zu Button 1'

[Satyr]

Schade, ich benutze noch Delphi2007.

[neo4a]

Zitat von Satyr:

ich habe mein dynamisch erzeugtes TMenuItem.

Dann deklariere im Interface-Teil:

Delphi-Quellcode:

type
  TSpecMenuItem = class(TMenuItem)
  private
    Message : string;
    EinWert : Integer;
  end;

Erzeuge dynamisch:

Delphi-Quellcode:

var
  aMenuItem : TSpecMenuItem;
begin
  aMenuItem := TSpecMenuItem.Create(Self);
  aMenuItem.Message := 'Hi';
  aMenuItem.EinWert := 4711;
  aMenuItem.OnClick := actMenuClickExecute;
  FPopupMenu.Items.Add(aMenuItem);
end;

Und benutze:

Delphi-Quellcode:

procedure TMyForm.actMenuClickExecute(Sender : TObject);
var
  aMenuItem : TSpecMenuItem;
begin
  aMenuItem := Sender as TSpecMenuItem;
  ShowMessage(Format('%s : %d', [aMenuItem.Message, aMenuItem.EinWert]));
end;

Das geht auch mit D2007.

Da fällt mir noch ein: Wenn Dir das Arbeiten mit einer eigenen abgeleiteten Klasse nicht behagt, kannst Du mit dem Interceptor Pattern die gewünschte Erweiterung auch einem TMenuItem "unterschieben". Dazu deklariert man in einer separaten Unit:

Delphi-Quellcode:

unit uMenuItemInterceptor;

interface

uses
  Menus;

type
  TMenuItem = class(Menus.TMenuItem)
    MeinWert : string
  end;

implementation

end.

Diese Unit bindest Du dann als letzte Unit in Deiner Form-Unit ein und schon kannst Du Deinem TMenuItem beliebige Werte (hier MeinWert) mit auf den Weg geben.

Diese Technik funktioniert immer nur einmal pro Klasse (ähnlich wie bei den Class Helper).

[Satyr]

Danke für die Hilfe aber ich habe es jetzt über den Tag gelöst. Das ging schneller als ich dachte... da der String den ich übergeben wollte eh nur eine Art Datum war, konnte ich das leicht als Integer im Tag ablegen.

[neo4a]

Zitat von Satyr:

Danke für die Hilfe aber ich habe es jetzt über den Tag gelöst. Das ging schneller als ich dachte...

Schau Dir unter dem Gesichtspunkt "better practise" ruhig die von mir empfohlene Lösung noch einmal genauer an: Sie ist intern deutlich dokumentiert und abgesichert, flexibel anpassbar und effektiv vielleicht 10 Zeilen "umfangreicher".

Wenn man schon dynamisch Kompononenten erzeugt, dann ist der Rückgriff auf die Tag-Lösung etwas für "Baumarkt-Handwerker".

[Satyr]

Zitat von neo4a:

Wenn man schon dynamisch Kompononenten erzeugt, dann ist der Rückgriff auf die Tag-Lösung etwas für "Baumarkt-Handwerker".

Deshalb war das mit dem Tag auch nicht meine erste Wahl...

Ich teste mal mit dem Code von Dir rum, danke dafür .