Menüpunkt eine "Pseudo"-Funktion zuweisen

[JKHero]

gibt es eine möglichkeit, einem einem Menüpünkt eine Funktion zuzuweisen, dass er das macht, was ein Button auf einem Aktiven tab machen würde?

[Luckie]

Wo ist das Problem:

Code:

function DoSomeThing
begin

end;

procedure ButtonClick
begin
  DoSomething;
end;

procedure MeueClick
begin
  DoSomething;
end;

[DeddyH]

Sofern ich die Frage richtig verstanden habe: erstelle eine Methode vom Typ TNotifyEvent und weise diese sowohl dem Button als auch dem MenuItem im OnClick zu.

[Neutral General]

Oder noch einfacher (erklärt):

Statt einen Doppelklick auf das Menü-Item klickst du 1x drauf, wählst im Objektinspektor das Tab "Ereignisse" und wählst beim OnClick-Ereignis in der ComboBox das OnClick-Ereignis des Buttons aus.

[JKHero]

das gilt ja leider nur für einen button. Das Problem jedoch ist, dass ich viele viele Tabs habe auf denen diese buttons sind (anzeigen von Lösungen zu einer aufgabe). Da ja jeder Tab/lernkarte eine eigene Lösung hat, hat ja auch jeder button seine eigene Methode mit der die entsprechende Lösung angezeigt wird.
nun möchte ich aber über die menüleiste auch die lösungen anzeigen lassen können. deswegen dachte ich:
weise dem menuitem eine methode zu, die besagt, dass er das gleiche machen soll, wie der Lösungsknopf auf dem aktiven tab.

[Neutral General]

Dann musst du im OnChange des Page-Controls das Click-Ereignis des Menüpunkts dynamisch auf das OnClick des richtigen Lösungs-Buttons setzen.

[DeddyH]

Das klingt mir aber sehr nach "VCL-Gefrickel". Was genau machen die Buttons denn unterschiedlich, geben die nur andere Daten aus? Dann könnte man das nämlich auch eleganter lösen.

[Furtbichler]

Actions und Actionlists sind eigentlich die Mittel der Wahl, um eine Funktion durch unterschiedliche GUI-Elemente auszuführen.

[Sir Rufo]

Wenn in dem PageControl immer das Gleiche angezeigt wird (eine Aufgabe) und es demzufolge einen Button gibt zum Anzeigen der Lösung, dann bietet es sich an ein Formular (TAufgabeForm) zu erstellen und dann x-beliebig viele Instanzen an das PageControl zu docken.

Dieser Form gibt man nun noch eine public Funktion (ShowSolution), die dann von dem Menüpunkt aufgerufen wird.

[Sir Rufo]

Ich hab da mal was gebastelt, was das ganze verdeutlichen soll:

Delphi-Quellcode:

unit Main.View;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.ComCtrls, Vcl.ActnList, Vcl.StdCtrls;

type
  TMain_View = class( TForm )
    PageControl1 : TPageControl;
    ActionList1 : TActionList;
    Action1 : TAction;
    Button1 : TButton;
    procedure FormCreate( Sender : TObject );
    procedure Action1Execute( Sender : TObject );
    procedure Action1Update( Sender : TObject );
  private
    { Private-Deklarationen }
  public
    { Public-Deklarationen }
  end;

var
  Main_View : TMain_View;

implementation

uses
  Aufgabe.View;

{$R *.dfm}

procedure TMain_View.Action1Execute( Sender : TObject );
begin
  // Aktive AufgabenForm ermitteln und die Methode ShowSolution aufrufen
  ( PageControl1.ActivePage.Controls[0] as TAufgabe_View ).ShowSolution( Sender );
end;

procedure TMain_View.Action1Update( Sender : TObject );
begin
  // Nur wenn die aktive Page auch eine AufgabenForm enthält, wird die Action aktiviert
  Action1.Enabled := Assigned( PageControl1.ActivePage ) and ( PageControl1.ActivePage.ControlCount > 0 ) and
    ( PageControl1.ActivePage.Controls[0] is TAufgabe_View );
end;

procedure TMain_View.FormCreate( Sender : TObject );
var
  idx : Integer;
  frm : TForm;
begin
  // Es werden mal eben 20 Formulare erzeugt und angedockt
  for idx := 1 to 20 do
    begin
      if idx mod 3 = 1
      then
        begin
          // ein Dummy-Formular, hier wird die Action disabled sein
          frm := TForm.Create( Self );
          frm.Caption := Format( 'Nur so %d', [idx] );
        end
      else
        begin
          frm         := TAufgabe_View.Create( Self );
          frm.Caption := Format( 'Aufgabe %d', [idx] );
        end;
      frm.ManualDock( PageControl1, nil, alClient );
      frm.Show;
    end;
end;

end.