ResCreator

[SimplySimon]

Nein, da der TFileOpenDialog die Option PickFolders hat...
Sonst müsste ich den anderen Standard FolderPicker nehmen und der ist längst nicht so elegant und benutzerfreundlich...

[himitsu]

OS-abhängig Beide einbauen.

[SimplySimon]

Gute Idee, so wirds gemacht, der Code wird hier mit Sicherheit zu finden sein

[uligerhardt]

Zitat von himitsu:

OS-abhängig Beide einbauen.

Ich hab mal schnell einen Wrapper zusammengeklatscht:

Delphi-Quellcode:

function SelectDirectory(const Caption: string;
  var Directory: string; Options: TSelectDirExtOpts; Parent: TWinControl): Boolean;
var
  dlg: TFileOpenDialog;
begin
  if (Win32MajorVersion >= 6) and UseLatestCommonDialogs then
  begin
    dlg := TFileOpenDialog.Create(nil);
    try
      dlg.Title := Caption;
      dlg.FileName := Directory;
      dlg.Options := dlg.Options + [fdoPickFolders];
      // Außerdem TSelectDirExtOpts auf TFileDialogOptions abbilden
      Result := dlg.Execute(Parent.Handle);
      if Result then
        Directory := dlg.FileName;
    finally
      dlg.Free;
    end;
  end
  else
  begin
    Result := FileCtrl.SelectDirectory(Caption, '', Directory, Options, Parent);
  end;
end;

Das kann man so aufrufen:
SelectDirectory('Test', Directory, [sdNewFolder, sdShowEdit, sdNewUI], Self);

[SimplySimon]

Vielen dank! Werde es demnächst einbinden

[Luckie]

Und ab welcher Delphiversion läuft das? Ab wann steht TFileOpenDialog und UseLatestCommonDialogs zur Verfügung?

[uligerhardt]

Hab's noch ein bisschen überarbeitet:

Delphi-Quellcode:

function SelectDirectory(const Caption: string;
  var Directory: string; Options: TFileDialogOptions; Parent: TWinControl): Boolean;
var
  dlg: TFileOpenDialog;
begin
  if (Win32MajorVersion >= 6) and UseLatestCommonDialogs then
  begin
    dlg := TFileOpenDialog.Create(nil);
    try
      dlg.Title := Caption;
      dlg.FileName := Directory;
      dlg.Options := Options + [fdoPickFolders];
      Result := dlg.Execute(Parent.Handle);
      if Result then
        Directory := dlg.FileName;
    finally
      dlg.Free;
    end;
  end
  else
  begin
    Result := FileCtrl.SelectDirectory(Caption, '', Directory, [sdNewFolder, sdShowEdit, sdShowShares, sdNewUI], Parent);
  end;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  UseLatestCommonDialogs := CheckBoxUseLatestCommonDialogs.Checked;
  if SelectDirectory('Test', Directory, [], Self) then
    Label1.Caption := Directory;
end;

Vielleicht kann man die beiden Option-Typen noch besser synchronisieren. Aber z.B. scheint sdShowShares nichts mit fdoShareAware zu tun zu haben, ebensowenig sdValidateDir mit fdoNoValidate, und mehr "Pärchen" habe ich auf die Schnelle nicht gefunden.

Zitat von Luckie:

Und ab welcher Delphiversion läuft das? Ab wann steht TFileOpenDialog und UseLatestCommonDialogs zur Verfügung?

Ich hab's mit D2007 ausprobiert.

Update: Wie zu erwarten lässt es sich mit Turbo Delphi nicht kompilieren.

[SimplySimon]

Hallo alle zusammen,

habe mich nochmal hingesetzt und die Version überarbeitet.
Es sind neue Funktionen hinzugekommen, einiges wurde verbessert, außerdem sollte jetzt auch
das Problem mit Windows XP gelöst sein.