Verwirrung pur

[St0rmhunter]

Hallo Leute,
ich bins mal wieder und bin mal wieder blind.

Das ist der Quellcode den ich in der Schule abgeschrieben habe (beim Lehrer hat er funktioniert), und jetzt funktioniert er bei mir nicht
Hat jemand ne Idee oder is jemand nicht so blind wie ich und findet den Fehler? Es kommt immer der Fehler "Acces Violation" und der Fehler schein in der Zeile zu entstehen, in der ich den Kreis in die Form1 zeichne.

Vielen Dank schonmal =)

Delphi-Quellcode:

unit Unit1; 

{$mode objfpc}{$H+}

interface

uses
  Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs, StdCtrls;

type

  TKreis = class
    x,y,d: Integer;
    constructor create (xx,yy,dd: Integer);
    procedure erscheinen;
    procedure verschwinden;
  end;

  { TForm1 }

  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    Edit1: TEdit;
    Edit2: TEdit;
    Edit3: TEdit;
    Label1: TLabel;
    Label2: TLabel;
    Label3: TLabel;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
  private
    { private declarations }
  public
    { public declarations }
  end; 

var
  Form1: TForm1;
  Kreis: TKreis;

implementation

{$R *.lfm}

constructor TKreis.create (xx,yy,dd: Integer);
begin
  Kreis.x:=xx;
  Kreis.y:=yy;
  Kreis.d:=dd;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  Kreis.create(strtoint(Form1.edit1.text),strtoint(Form1.edit2.text),strtoint(Form1.edit3.text));
  Kreis.erscheinen;
end;

procedure TForm1.Button2Click(Sender: TObject);
begin
  Kreis.verschwinden;
end;

procedure TKreis.verschwinden;
begin
  Form1.refresh;
end;

procedure TKreis.erscheinen;
begin
  Form1.refresh;
  Form1.canvas.Ellipse(Kreis.x,Kreis.y,Kreis.x+Kreis.d,Kreis.y+Kreis.d);
end;

end.

[sirius]

Den constructor so aufrufen (ansonsten wird er als normale Methode aufgerufen und kein Speicher für x,y und d reserviert):
KReis:=TKreis.create(....);

[DeddyH]

Zitat:

Delphi-Quellcode:

constructor TKreis.create (xx,yy,dd: Integer);
begin
  Kreis.x:=xx;
  Kreis.y:=yy;
  Kreis.d:=dd;
end;

Du greifst im Konstruktor auf die globale Variable zu, deren Instanz jetzt gerade eben erzeugt wird? Ersetz hiermal Kreis durch self oder lass es ganz weg. Und

Zitat:

Kreis.create(...)

sollte wohl
Kreis := TKreis.create(...) heißen.

[SirThornberry]

Bitte gibt dem Thema einen aussagekräftigen Titel (so wie es in den Forenregeln steht denen du bei der Anmeldung zugestimmt hast)

[Sir Rufo]

Ein sehr schönes Beispiel für analoge Kopierverluste

Bei genauerer Betrachtung ist diese auch ein Beispiel wie man es niemals machen sollte
Einen schönen Gruß an den Lehrkörper - scheint ein typischer Hohlkörper zu sein

[St0rmhunter]

Ok vielen dank =) ... Ich frage mich nur wieso es bei meinem Lehrer funktioniert hat 0o

[Sir Rufo]

Zitat von St0rmhunter:

Ok vielen dank =) ... Ich frage mich nur wieso es bei meinem Lehrer funktioniert hat 0o

Weil du beim Abschreiben Fehler reingebracht hast?

Hier mal, wie man so etwas besser aufbaut:

Delphi-Quellcode:

unit Unit1; 

{$mode objfpc}{$H+}

interface

uses
  Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs, StdCtrls;

type

  TKreis = class
  private
    fX,fY,fD: Integer;
  public
    constructor create ( aX, aY, aD: Integer );
    procedure erscheinen( aForm : TForm );
    procedure verschwinden( aForm : TForm );
    // Eigenschaften - readonly, weil auf eine externe Veränderung keine Reaktion implementiert ist
    property X : integer read fX;
    property Y : integer read fY;
    property D : integer read fD;
  end;

  { TForm1 }

  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    Edit1: TEdit;
    Edit2: TEdit;
    Edit3: TEdit;
    Label1: TLabel;
    Label2: TLabel;
    Label3: TLabel;
    procedure Button1Click( Sender: TObject );
    procedure Button2Click( Sender: TObject );
  private
    { private declarations }
    fKreis : TKreis;
  public
    { public declarations }
    property Kreis : TKreis read fKreis;
  end; 

var
  Form1: TForm1;
  // globale Variablen gehen ja gar nicht
  // Kreis: TKreis; 

implementation

{$R *.lfm}

{ TForm1 }

procedure TForm1.Button1Click( Sender: TObject );
begin
  // Wenn es eine Instanz von Kreis gibt, dann diese Instanz auch wieder freigeben, sonst Speicherleck!!!
  if Assigned( fKreis ) then
    fKreis.Free;

  // Das Form1.Edit... ist sowas von falsch, denn bei einer weiteren Instanz von TForm1 funktioniert das nicht mehr
  // Was noch gehen würde wäre Self.Edit1.Text
  fKreis := TKreis.Create( StrToInt( Edit1.Text ), StrToInt( Edit2.Text ), StrToInt( Edit3.Text ) );

  // Self ist die Referenz auf die aktuelle Klassen-Instanz und somit an dieser Stelle diese Formular-instanz
  Kreis.erscheinen( Self ); 
end;

procedure TForm1.Button2Click(Sender: TObject);
begin
  // Wenn es eine Instanz Kreis gibt, dann die Methode aufrufen, sonst gibt es Zugriffsverletzungen!!!
  if Assigned( Kreis )
    Kreis.verschwinden( Self );
end;

{ TKreis }

constructor TKreis.create ( aX, aY, aD: Integer );
begin
  inherited Create; // nur zur Vorsicht, falls TObject mal einen speziellen Constructor bekommt
  fX := aX;
  fY := aY;
  fD := aD;
end;

procedure TKreis.verschwinden( aForm : TForm );
begin
  aForm.Refresh;
end;

procedure TKreis.erscheinen( aForm : TForm );
begin
  verschwinden( aForm );
  aForm.Canvas.Ellipse( X, Y, X + D, Y + D );
end;

end.

[Namenloser]

Zitat von Sir Rufo:

Ein sehr schönes Beispiel für analoge Kopierverluste

Bei genauerer Betrachtung ist diese auch ein Beispiel wie man es niemals machen sollte
Einen schönen Gruß an den Lehrkörper - scheint ein typischer Hohlkörper zu sein

Das Beispiel ist kopiert aus dem Buch „Delphi für Kids“ Das Buch ist teilweise nicht unbedingt immer ein Parade-Beispiel für gute Code-/Programm-Architektur, aber dafür sind die Beispiele so simpel gehalten, dass man auch als Anfänger (an die das Buch ja gerichtet ist) die grundlegenden Prinzipien sofort versteht.

[Sir Rufo]

Zitat von NamenLozer:

Zitat von Sir Rufo:

Ein sehr schönes Beispiel für analoge Kopierverluste

Bei genauerer Betrachtung ist diese auch ein Beispiel wie man es niemals machen sollte
Einen schönen Gruß an den Lehrkörper - scheint ein typischer Hohlkörper zu sein

Das Beispiel ist kopiert aus dem Buch „Delphi für Kids“ Das Buch ist teilweise nicht unbedingt immer ein Parade-Beispiel für gute Code-/Programm-Architektur, aber dafür sind die Beispiele so simpel gehalten, dass man auch als Anfänger (an die das Buch ja gerichtet ist) die grundlegenden Prinzipien sofort versteht.

Und dabei auch gleich die schlimmsten Designfehler einprägt als "so geht das also"

[Namenloser]

Zitat von Sir Rufo:

Und dabei auch gleich die schlimmsten Designfehler einprägt als "so geht das also"

Das ist bei mir nicht passiert.