SelChange Notifier für TEdit

[Geronimo]

Hallo alle zusammen,

ich stehe mal wieder auf dem Schlauch.

Ich möchte gern die Sichtbarkeit von Buttons in Abhängigkeit von der Markierung in einem TEdit steuern. Hierfür brauche ich einen Notifier,
der mich über Änderungen der Markierung im TEdit benachrichtigt.
Geht das überhaupt? Wenn ja wie?

Für Eure Bemühungen schon mal Danke im Voraus.

Gruß
Geronimo

[mkinzler]

Wie meinst du das?

[Geronimo]

...

ich habe z.B. ein TEdit und einen Button zum Kopieren der Markierung des TEdits, z.B. in die Zwischenablage.
Nun soll der Kopieren-Button nur sichtbar oder enabled sein, wenn im TEdit auch was markiert ist, sonst halt disabled oder nicht sichtbar.

Ich hoffe, ich drücke mich verständlich aus.

Gruß

Geronimo

[dataspider]

Es gibt sicher einfachere Lösungen,

aber hier bieten sich Standard Actions (bzw. eigene) an.
Kannst ja mal in einer ActionList eine Standardaktion (TEditCut z.B.) anlegen und dem Butten zuweisen.

Frank

[webcss]

Ansonsten kannst Du auch in TEdit.OnChange prüfen, ob und wie viele Zeichen im Edit markiert sind und damit den Button steuern.

Delphi-Quellcode:

procedure MyEditOnChange(Sender: TObject)
begin
  myButton.Enabled:= MyEdit.SelLength>3;
end;

[Bummi]

Quick and Dirty, aber vielleicht kannst Du daraus was sauberes bauen

Delphi-Quellcode:

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TEdit=Class(StdCtrls.TEdit)
  private
    public
    procedure DefaultHandler(var Message); override;
  End;
  TForm1 = class(TForm)
    Edit1: TEdit;
  private
    { Private-Deklarationen }
  public
    { Public-Deklarationen }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}


var
 FReentranceProhibit:Boolean;
procedure TEdit.DefaultHandler(var Message);
begin
  inherited;
      if FReentranceProhibit then exit
      else
        begin
          FReentranceProhibit := true;
          Form1.Caption := IntToStr(SelLength);
          FReentranceProhibit := false;
        end;

end;


end.

[Bummi]

so, jetzt nochmal etwas sauberer, sollte man aber in eine eigene Komponente packen

Delphi-Quellcode:

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TEdit=Class(StdCtrls.TEdit)
  private
    FReentranceProhibit:Boolean;
    FOnSelChange:TNotifyEvent;
    FoldSelLength,FOldSelStart:Integer;
    public
    procedure DefaultHandler(var Message); override;
    published
    Property OnSelChange:TNotifyEvent read FOnSelChange write FOnSelChange;
  End;
  TForm1 = class(TForm)
    Edit1: TEdit;
    Edit2: TEdit;
    Button1: TButton;
    procedure FormCreate(Sender: TObject);
  private
    { Private-Deklarationen }
  public

    procedure MySelchange(Sender: TObject);
    { Public-Deklarationen }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}



procedure TEdit.DefaultHandler(var Message);
begin
  inherited;
      if FReentranceProhibit then exit
      else
        begin
          FReentranceProhibit := true;
          try
          if Assigned(FOnSelChange) and ((FOldSelStart<>SelStart) or (FOldSelLEngth<>SelLength)) then
            begin
            FOnSelChange(Self);
            end;
          finally
          FReentranceProhibit := false;
          end;
        end;
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
   Edit1.OnSelChange := MySelchange;
   Edit2.OnSelChange := MySelchange;
end;

procedure TForm1.MySelchange(Sender: TObject);
begin
  Caption := Tedit(Sender).Name+'-' + IntToStr(TEdit(Sender).SelLength) +'-' +  IntToStr(TEdit(Sender).SelStart) ;
end;

end.

[Geronimo]

Hallo,

vielen Dank. Bummis Lösung ist das, was mir vorschebte und
funzt super. Sollte man vielleicht in die Code Bibliothek tun!
Das OnChange-Ereignis, wie von webcss vorgeschlagen, hilft leider nicht, hatte ich schon ausprobiert, da OnChange nur ausgelöst wird,
wenn sich der Inhalt des TEdit ändert.

Trotzdem Dank an Alle.

Gruß

Geronimo