Generics mit abgeleiten Klassen

[backdraft]

Hallo zusammen,

ich probiere mich heute das erste mal an Generics und habe irgendwie ein Verständnisproblem.

Ich habe eine Basisklasse und davon eine Ableitung.
Jetzt möchte ich, dass meine Generic Klasse entweder die Basisklasse nimmt, oder die Ableitung.

Code:

unit MyClass;

interface

type
  TMyBase = class
  private
    FBaseProperty: Integer;
  public
    property BaseProperty: Integer read FBaseProperty write FBaseProperty;
  end;

  TMyExtended = class(TMyBase)
  private
    FExtendedProperty: Integer;
  public
    property ExtendedProperty: Integer read FExtendedProperty write FExtendedProperty;
  end;

  TMyGeneric<T: TMyBase>=class
  private
    FMyItem: T;
  public
    constructor Create;
    property MyItem: T read FMyItem;
  end;

  TMyBaseClass = TMyGeneric<TMyBase>;
  TMyExtendedClass = TMyGeneric<TMyExtended>;

var
  vMyBaseItem: TMyBaseClass;
  vMyExtendedItem: TMyExtendedClass;

implementation

{ TMyGeneric<T> }

constructor TMyGeneric<T>.Create;
begin
  inherited;
  FMyItem := TMyBase(T).Create;
end;

end.

Es knallt an der Stelle

Code:

 TMyExtendedClass = TMyGeneric<TMyExtended>;

E2010 Inkompatible Typen: 'TMyExtended' und 'TMyBase'

Was mache ich denn falsch?

[Uwe Raabe]

Der Fehler liegt im Constructor. Dort wird einer Variablen vom Type T (= TMyExtended) ein TMyBase zugewiesen.

[backdraft]

Ich hasse Delphi, wenn es nicht sagt in welcher Zeile der Fehler ist,
ABER Du hast recht, wenn ich die Zeile auskommentiere gehts...
OK, wie ist der Aufruf denn richtig?
Vielen Dank schonmal für die schnelle Hilfe ...

[himitsu]

Versuch mal FMyItem := T.Create; .

Entweder mußt du T.Crete schreiben oder das FMyItem nochmal nach TMyBase casten, vor der Zuweisung.
(gibt halt ein paar kleine Bugs in diesen Generics )

[backdraft]

Hallo,
klappt leider beides nicht.
Ich bekomm einen Fehlert und stehe auf T.Create

Meldung:
Neue Instanz kann ohne CONSTRUCTOR-Einschränkung in der Typparameterdeklaration nicht erstellt werden

[himitsu]

Laut Warnung will der Compiler sowas haben: TMyGeneric<T: constructor>=class .
k.A. ob man diese beiden Beschränkgen kombinieren kann,

Schön, daß man im XE jetzt auch direkt Typen angeben kann, aber so richtig funktioniert es dann wohl doch noch nicht.

[Uwe Raabe]

Delphi-Quellcode:

  
type
  TMyGeneric<T: constructor, TMyBase> = class
  private
    FMyItem: T;
  public
    constructor Create;
    property MyItem: T read FMyItem;
  end;

constructor TMyGeneric<T>.Create;
begin
  inherited;
  FMyItem := T.Create;
end;

Geschickterweise macht man das TMyBase.Create dann auch noch virtual .

[backdraft]

Hat geklappt,
vielen Dank für die schnelle Hilfe, also da muss man erstmal drauf kommen.
Wo steht sowas?

[Iwo Asnet]

Von C# aus gesehen (von denen Emba wohl hier ein wenig abschreibt) ist das ein wenig logischer.

Und Metaklassen und Konstruktoren sind schon ein Thema für sich.

Unterm Strich: Man muss es einfach wissen oder jemanden kennen, der es weiss.

[Stevie]

Wenn alles irgendwo stehen würde, bräuchtma doch die DP nich

Mir fällt gerade auf... jetzt stehts hier!

Aber mal Spaß beiseite: gerade was die neuen Features wie Generics, RTTI, anonyme Methoden und so Zeugs angeht gibt es keine lückenlose Dokumentation. Da ist man am besten beraten, bestimmte Blogs zu verfolgen und Google und/oder die DP zu Rate zu ziehen. Auch Marco Cantus Delphi Handbücher enthalten einiges an Wissen.