INSERT INTO SELECT ohne Spaltenliste

[Bummi]

Du willst keinen Verbindugsserver aufbauen und hast die Zieltabellen schon?
Die Insert-SQL's aufzubauen mit Berücksichtigung aller Besonderheiten bzgl. Feldtypen, Codierung etc. wird Dich einige Zeit kosten, warum nicht die billige Variante


ExDataset = Select * from Quelle
Ads= Select * from Ziel

Delphi-Quellcode:

While (not ExDataset.EOF)  do
      begin

      Ads.Append;
      for i:=0 to Ads.Fieldcount-1 do
          begin
          Ads.Fields[i].Assign(ExDataset.FieldByName(Ads.Fields[i].FieldName));
          end;
      ads.Post;
      ExDataset.Next;
      end;

[Alex.G]

Zitat von Bummi:

... warum nicht die billige Variante

Weil es meine Aufgabe ist

[himitsu]

Zitat von Alex.G:

Weil es meine Aufgabe ist

Aufgabe?

Hatte das schonmal wer hier erwähnt`?

[Alex.G]

Zitat von himitsu:

Zitat von Alex.G:

Weil es meine Aufgabe ist

Aufgabe?

Hatte das schonmal wer hier erwähnt`?

Bisher noch nicht.
Ich habe es nun mit:
InsertStr := InsertStr + IfThen(InsertStr <> '', ', ', '') + qryMasterExec.Parameters[i].Name; und
InsertStr := InsertStr + IfThen(InsertStr <> '', ', ', '') + qryMasterExec.Fields[i].Name; probiert. Wenn ich ein Breakpoint setze, sehe ich, dass InsertStr leider nach Ablauf der Schleife immer leer bleibt.

[DeddyH]

Was ist denn mit der Vorgehensweise nach #14 bis #19?

[himitsu]

Und qryMasterExec.Fields[i].FieldName ?

[Sir Rufo]

Ich bin hierfür (mal eben herunter getippt)

Delphi-Quellcode:

procedure CopyADOData( SrcCon, TarCon : TADOConnection; const TableName : string );
var
  SrcData :   TADOTable;
  TarData :   TADOQuery;
  SqlStrFld : string;
  SqlStrPar : string;
  fld :       TField;
begin
  SrcData := TADOTable.Create( nil );
  TarData := TADOQuery.Create( nil );
  try

    SrcData.Connection := SrcCon;
    SrcData.TableName  := TableName;
    SrcData.FieldDefList.Update;

    TarData.Connection := TarCon;

    SqlStrFld := '';
    SqlStrPar := '';

    for fld in SrcData.Fields do
      begin
        if not( SqlStrFld = '' )
        then
          SqlStrFld := SqlStrFld + ', ';
        SqlStrFld := SqlStrFld + fld.FieldName;

        if not( SqlStrPar = '' )
        then
          SqlStrPar := SqlStrPar + ', ';
        SqlStrPar := SqlStrPar + ':' + fld.FieldName;
      end;

    TarData.SQL.Text := 'INSERT INTO ' + TableName + ' ( ' + SqlStrFld + ' ) VALUES ( ' + SqlStrPar + ' )';

    TarData.Prepared := True;
    try

      SrcData.Open;
      try

        while not SrcData.Eof do
        begin
          for fld in SrcData.FieldList do
          begin
            TarData.Parameters.ParamByName(fld.FieldName).Value := fld.Value;
          end;
          TarData.ExecSQL;
          SrcData.Next;
        end;

      finally
        SrcData.Close;
      end;

    finally
      TarData.Prepared := False;
    end;

  finally
    TarData.Free;
    SrcData.Free;
  end;
end;

[Alex.G]

Zitat von himitsu:

Und qryMasterExec.Fields[i].FieldName ?

Das funktioniert!
Eine (hoffentlich) letzte Sache noch:

Delphi-Quellcode:

  qrySlaveExec.SQL.Text := Format('INSERT INTO %s (%s) VALUES(%s)', [TableName, InsertStr, ValueStr]);
  while not qryMasterExec.Eof do begin
    qrySlaveExec.Insert;

Ist bei geschlossener Datenmenge nicht möglich. Ein qrySlaveExec.Open kann ich aber, soweit ich weiß, nur bei einem SELECT nutzen.

[joachimd]

Zitat von Alex.G:

Delphi-Quellcode:

  qrySlaveExec.SQL.Text := Format('INSERT INTO %s (%s) VALUES(%s)', [TableName, InsertStr, ValueStr]);
  while not qryMasterExec.Eof do begin
    qrySlaveExec.Insert;

Ist bei geschlossener Datenmenge nicht möglich.

  qrySlaveExec.ExecSQL;

[Bummi]

zum fertigbasteln:

Delphi-Quellcode:

Function GetTableValueScript(Ads:TAdodataset;const tableName:String;HasIdentity:Boolean):String;
var

  FieldNames:TStringList;
  Values:TStringList;
  i:Integer;
  FieldNamesStr:String;
  Function Prepare(f:TField):String;
    begin
       if f.IsNull then Result := 'NULL'
       else
       Case
         f.DataType of
          ftSmallint, ftInteger, ftWord,ftAutoInc,ftLargeint,
          ftFloat, ftCurrency, ftBCD ,ftFMTBcd,ftLongWord, ftShortint, ftByte, ftExtended ,ftSingle: Result := Stringreplace(f.AsString, ',','.',[]) ;
          ftString,ftWideString,ftGuid : Result := QuotedStr(f.AsString);
          ftDate, ftDateTime, ftTime : Result := QuotedStr(FormatdateTime('yyyymmdd hh:nn:ss.zzz',f.AsDateTime));
          ftBoolean: Result := IntToStr(Integer(f.AsBoolean));
          // to be continued
       End;
    end;
  Function GetValues:String;
    begin
        Result := StringReplace(Values.Text,#13#10,', ',[rfReplaceAll]);
        Result := Copy(Result,1,Length(Result) - 2);
    end;
begin

  FieldNames:=TStringList.Create;
  Values:=TStringList.Create;
  try
  Ads.CommandText := 'Select top 100 * from ' + tablename;
  Ads.Open;
  for I := 0 to Ads.FieldCount -1 do FieldNames.Add('[' + Ads.Fields[i].FieldName + ']');
  FieldNamesStr := StringReplace(FieldNames.Text,#13#10,', ',[rfReplaceAll]);
  FieldNamesStr := Copy(FieldNamesStr,1,Length(FieldNamesStr) - 2);
  while not Ads.Eof do
    begin
      Values.Clear;
      for I := 0 to Ads.FieldCount -1 do Values.Add(Prepare(Ads.Fields[i]));
      Ads.Next;
      Result := Result + 'Insert Into ' + tablename + '(' + FieldNamesStr + ') VALUES (' + GetValues + ')'  + #13#10#13#10;
    end;
  finally
    FieldNames.Free;
    Values.Free;
  end;
  if HasIdentity then
    Result :=  'Set Identity_Insert ' +  tableName +  ' ON' + #13#10
               + Result
               + 'Set Identity_Insert ' +  tableName +  ' OFF' + #13#10

end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  Memo1.Text := GetTableValueScript(ADS,'[Adressen]',true);
end;