Too stupid to execute and wait

[ChrisE]

Zitat von Luckie:

Funktioniert wunderbar:

Hmm, du mischst aber auch WideString und AnsiString bzw. gibst es nicht explizit an.   ShExecInfo.lpVerb := 'open'; Ich würde es so versuchen (Deine Sourcen angepasst):

Delphi-Quellcode:

uses
  ShellAPI;

procedure ExecAndWait(Filename, Params: string; AHWnd: HWND; WindowState: word = SW_SHOWNORMAL);
var
  ShExecInfo: SHELLEXECUTEINFO;
const
  SEE_MASK_NOASYNC= $100;
begin
  ZeroMemory(@ShExecInfo, SizeOf(ShExecInfo));
  ShExecInfo.Wnd := AHWnd;
  ShExecInfo.cbSize := sizeof(SHELLEXECUTEINFO);
  ShExecInfo.fMask := SEE_MASK_NOCLOSEPROCESS or SEE_MASK_NOASYNC;
  ShExecInfo.lpVerb := 'open';
  ShExecInfo.lpFile := PChar(Filename);
  ShExecInfo.lpParameters := PChar(Params);
  ShExecInfo.lpDirectory := PChar(ExtractFileDir(Filename));
  ShExecInfo.nShow := WindowState;
  if ShellExecuteExW(@ShExecInfo) then
  begin
    WaitForSingleObject(ShExecInfo.hProcess, INFINITE);
    CloseHandle(ShExecInfo.hProcess);
  end
  else
    RaiseLastOSError;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  try
    ExecAndWait('C:\Windows\Notepad.exe', '', Self.Handle);
  except
    on E: Exception do
      ShowMessage(E.Message);
  end;
  ShowMessage('Fertig');
end;

Zitat von QuickAndDirty:

Aber mit meiner setup.exe ist nach dem Splashscreen Schluss.
Warum?

Nutzt du Windows Vista / 7? Dann starte sfx.exe mal mit Adminrechten oder benenne setup.exe um in meinprogramm.exe und probier es nochmal.

Gruß, Chris

[Luckie]

Wo mische ich? Ich habe nur Delphi 7 hier, deshalb habe ich ausdrücklich WideStrings benutzt.

[QuickAndDirty]

Zitat von Luckie:

Wo mische ich? Ich habe nur Delphi 7 hier, deshalb habe ich ausdrücklich WideStrings benutzt.

die windows api ist nicht so einfach mit delphi...
also mit delphi 2007 wäre es ok nur String zu benutzen? weil das schon Widechar ist?


mir wird ungut...

[ChrisE]

Zitat von himitsu:

Zitat von ChrisE:

Das gilt auch für Stringkonstanten wie 'open' . Diesen WideString würdest du an eine Struktur übergeben die für AnsiString gedacht ist. Das wäre ein potenzieller Fehler.

Nicht ganz.
Stringkonstanten haben erstmal keinen Typ.
Übergibt man sie nun an einen AnsiString- oder PAnsiChar-Parameter, wird dafür eine AnsiString-Konstante eingebunden.
Würde man diesen an WideString-, UnicodeString- oder PWideChar-Parameter oder eben eine Variable übergeben, dann wird dafür eine Unicode-Konstante eingebunden.
Werden beide Parameter/Variablen verwendet, werden zwei Konstanten eingebunden (Ansi und Unicode)

Cool, wieder was dazu gelernt - THX

Zitat von Luckie:

Wo mische ich? Ich habe nur Delphi 7 hier, deshalb habe ich ausdrücklich WideStrings benutzt.

Damit ahst du nicht mehr gemischt - sorry

Aber meine Codeanpassung hatte auch nicht eine Fehler Ich habe ShellExecuteExW aufgerufen anstatt ShellExecuteEx.

Ich denke nur, dass man auf explizite WideString bzw. AnsiString-Verwendung verzichten sollte wo es geht. Dann funktioniert der Quelltext unter 2007 und >=2009

Gruß, Chris

[QuickAndDirty]

ja...schön...
der code funktionierte ja ....
in jedem der bisherigen zustände...

nur produziert er eben nen deadlock in einem fall

[ChrisE]

Zitat von QuickAndDirty:

nur produziert er eben nen deadlock in einem fall

Hast du das Probiert?

Zitat von ChrisE:

Nutzt du Windows Vista / 7? Dann starte sfx.exe mal mit Adminrechten oder benenne setup.exe um in meinprogramm.exe und probier es nochmal.

Gruß, Chris

[QuickAndDirty]

PROBLEM GELÖST

Delphi-Quellcode:

function ExecAndWait(Filename, Params: string; WindowState: word = SW_SHOWNORMAL): boolean;
var
  ShExecInfo: SHELLEXECUTEINFO;
  r : Cardinal;
  const
  SEE_MASK_NOASYNC= $100;
begin
  Result := false;
  if Filename = '' then
    exit;
  if not FileExists(FileName) then
  Begin
    ShowMessage('Datei nicht existent!');
    Exit;
  End;
  ZeroMemory(@ShExecInfo, SizeOf(ShExecInfo));
  ShExecInfo.Wnd := application.MainFormHandle; //GetForegroundWindow;
  ShExecInfo.cbSize := sizeof(SHELLEXECUTEINFOA);
  ShExecInfo.fMask := SEE_MASK_NOCLOSEPROCESS or SEE_MASK_NOASYNC;
  ShExecInfo.lpVerb := 'open';
  ShExecInfo.lpFile := PChar(Filename);
  ShExecInfo.lpParameters := PChar(Params);
  ShExecInfo.lpDirectory := PChar(ExtractFileDir(Filename));
  ShExecInfo.nShow := WindowState;
  Result := ShellExecuteEx(@ShExecInfo);


  try
    if Result then
    begin
      repeat
        R := MsgWaitForMultipleObjects(1, ShExecInfo.hProcess, False, INFINITE,QS_ALLINPUT);
        if r <> WAIT_OBJECT_0 then
          Application.ProcessMessages;
      until r = WAIT_OBJECT_0;
    end
    else
      Showmessage('Fehler beim Starten der Anwendung:' + Filename +
                   #13#10'System Fehler: ' + SysErrorMessage(GetLastError));
  finally
    CloseHandle(ShExecInfo.hProcess);
  end;
end;

WaitForSingleObject produziert scheinbar wie vorgesehen einen deadlock wenn der aufgerufen prozess ein neues Fenster erzeugt.
Und die msdn hatte recht...(seltsam) mit MsgWaitForMultipleObjects geht es dann trotzdem.

Delphi-Quellcode:

      repeat
        R := MsgWaitForMultipleObjects(1, ShExecInfo.hProcess, False, INFINITE,QS_ALLINPUT);
        if r <> WAIT_OBJECT_0 then
          Application.ProcessMessages;
      until r = WAIT_OBJECT_0;

Und danke für die Code Verschönerungstips, sieht jetzt auch viel übersichtlicher aus!

[Luckie]

Zitat von QuickAndDirty:

Und danke für die Code Verschönerungstips, sieht jetzt auch viel übersichtlicher aus!

Und warum nutzt du sie nicht und verhunzt den Code wieder? Wozu dieser komische try-finally-Block? Wo erwartest du da eine Exception? Und du hast ja immer noch diese doofe Fehlerbehandlung da drin.

[sirius]

Zitat von QuickAndDirty:

WaitForSingleObject produziert scheinbar wie vorgesehen einen deadlock wenn der aufgerufen prozess ein neues Fenster erzeugt.
Und die msdn hatte recht...(seltsam) mit MsgWaitForMultipleObjects geht es dann trotzdem.

Es funzt, aber keiner weiß warum. Das ist unbefriedigend.

Ich vermute:
Du hast bei Shellexecute dein eigenes WindowHandle angegeben. Anscheinend werden aus deiner setup.exe dahin Messages gesendet o.ä. Und MsgWaitforMultipleObjectes geht auch bei ankommenden Messages raus. Jetzt ist nur die Frage, was für Messages kommen denn da rüber? Kannst die ja mal mit PeekMessage abholen wenn R=Wait_Object_0 + 1 ist.

[QuickAndDirty]

Zitat von ChrisE:

Zitat von Luckie:

Funktioniert wunderbar:

Hmm, du mischst aber auch WideString und AnsiString bzw. gibst es nicht explizit an.   ShExecInfo.lpVerb := 'open'; Ich würde es so versuchen (Deine Sourcen angepasst):

Delphi-Quellcode:

uses
  ShellAPI;

procedure ExecAndWait(Filename, Params: string; AHWnd: HWND; WindowState: word = SW_SHOWNORMAL);
var
  ShExecInfo: SHELLEXECUTEINFO;
const
  SEE_MASK_NOASYNC= $100;
begin
  ZeroMemory(@ShExecInfo, SizeOf(ShExecInfo));
  ShExecInfo.Wnd := AHWnd;
  ShExecInfo.cbSize := sizeof(SHELLEXECUTEINFO);
  ShExecInfo.fMask := SEE_MASK_NOCLOSEPROCESS or SEE_MASK_NOASYNC;
  ShExecInfo.lpVerb := 'open';
  ShExecInfo.lpFile := PChar(Filename);
  ShExecInfo.lpParameters := PChar(Params);
  ShExecInfo.lpDirectory := PChar(ExtractFileDir(Filename));
  ShExecInfo.nShow := WindowState;
  if ShellExecuteExW(@ShExecInfo) then
  begin
    WaitForSingleObject(ShExecInfo.hProcess, INFINITE);
    CloseHandle(ShExecInfo.hProcess);
  end
  else
    RaiseLastOSError;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  try
    ExecAndWait('C:\Windows\Notepad.exe', '', Self.Handle);
  except
    on E: Exception do
      ShowMessage(E.Message);
  end;
  ShowMessage('Fertig');
end;

Zitat von QuickAndDirty:

Aber mit meiner setup.exe ist nach dem Splashscreen Schluss.
Warum?

Nutzt du Windows Vista / 7? Dann starte sfx.exe mal mit Adminrechten oder benenne setup.exe um in meinprogramm.exe und probier es nochmal.

Gruß, Chris

Ich nutze 2000, xp, und 7
über all das selbe Verhalten nur das es bei Windows 7 erst mit Adminrechten überhaupt in den Splashscreen kommt.

Ich testete dioe letzen paar minuten hier auf einer Windows 2000 virtuellen maschiene...